pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.8], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  36 AC_PROVIDE([AM_PO_SUBDIRS])
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 LIBS="$LIBINTL $LIBS"
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 PSPP_LC_PAPER
  44
  45
  46 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  47 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  48
  49 # Support for Cairo and Pango.
  50 AC_ARG_WITH([cairo],
  51   [AS_HELP_STRING(
  52     [--without-cairo],
  53     [Don't build support for charts (using Cairo and Pango);
  54      implies --without-gui])],
  55   [], [with_cairo=yes])
  56 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  57 if test "$with_cairo" != no; then
  58   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  59     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  60      AC_DEFINE([HAVE_CAIRO], 1,
  61        [Define to 1 if Cairo and Pango are available.])],
  62     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  63   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  64   AC_SUBST(XMLLINT)
  65 fi
  66
  67 # Support for GUI.
  68 AC_ARG_WITH([gui],
  69   [AS_HELP_STRING([--without-gui],
  70                   [Don't build the PSPPIRE GUI (using GTK+)])],
  71   [], [with_gui=yes])
  72 AM_CONDITIONAL([HAVE_GUI],
  73                [test "$with_cairo" != no && test "$with_gui" != "no"])
  74 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  75   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  76     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  77
  78   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  79     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  80
  81   AC_ARG_VAR([GLIB_GENMARSHAL])
  82   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  83   if test "x$GLIB_GENMARSHAL" = x; then
  84     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  85   fi
  86
  87   gl_NEXT_HEADERS([gtk/gtk.h])
  88 fi
  89
  90 dnl Checks needed for psql reader
  91
  92 dnl The 8.x series postgres tarballs installs with a default prefix of
  93 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  94
  95 dnl If the libpq.so file is in a non standard path, (one which the linker
  96 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  97 dnl However, if the system happens to have more than one version of other
  98 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  99 dnl /usr and /usr/local) then the wrong one may get linked.
 100
 101 dnl To overcome this, we first check for libpq in the standard places, and
 102 dnl only set PG_LDFLAGS if it's not found.
 103
 104
 105 AC_ARG_WITH(
 106   libpq,
 107   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 108 AC_ARG_VAR([PG_CONFIG],
 109            [Full pathname of the pg_config program shipped with Postgresql])
 110 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 111              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 112
 113 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 114   AC_SUBST(PG_CONFIG)
 115   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 116   AC_SUBST(PG_CFLAGS)
 117
 118   AC_CHECK_LIB([pq], [PQexec],
 119      [:],
 120      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 121   AC_SUBST(PG_LDFLAGS)
 122
 123   PG_LIBS=-lpq
 124   AC_SUBST(PG_LIBS)
 125
 126   PKG_CHECK_EXISTS(libssl,
 127         AC_DEFINE([USE_SSL],1,
 128                    [Define to 1 if the openssl library is present.])
 129            ,)
 130
 131   # Now verify that we can actually link against libpq.  If we are
 132   # cross-compiling and picked up a host libpq, or if libpq is just
 133   # badly installed, this will fail.
 134   AC_CACHE_CHECK(
 135     [whether -lpq links successfully],
 136     [pspp_cv_have_libpq],
 137     [save_CPPFLAGS=$CPPFLAGS
 138      save_LIBS=$LIBS
 139      save_LDFLAGS=$LDFLAGS
 140      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 141      LIBS="$PG_LIBS $LIBS"
 142      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 143      AC_LINK_IFELSE(
 144        [AC_LANG_PROGRAM(
 145          [#include <libpq-fe.h>
 146          ], [PQfinish (0);])],
 147        [pspp_cv_have_libpq=yes],
 148        [pspp_cv_have_libpq=no])
 149      CPPFLAGS=$save_CPPFLAGS
 150      LIBS=$save_LIBS
 151      LDFLAGS=$save_LDFLAGS])
 152
 153   if test $pspp_cv_have_libpq = yes; then
 154     PSQL_SUPPORT=yes
 155     AC_DEFINE([PSQL_SUPPORT], [1],
 156       [Define to 1 if building in support for reading from postgres
 157        databases.])
 158   else
 159     PSQL_SUPPORT=no
 160     PG_CONFIG=
 161     PG_CFLAGS=
 162     PG_LDFLAGS=
 163     PG_LIBS=
 164   fi
 165 else
 166   PSQL_SUPPORT=no
 167   pspp_cv_have_libpq=no
 168 fi
 169 AC_SUBST([PSQL_SUPPORT])
 170
 171 dnl Check for libxml2
 172 PKG_CHECK_MODULES(
 173   [LIBXML2], [libxml-2.0],
 174   [HAVE_LIBXML2=yes],
 175   [HAVE_LIBXML2=no
 176    PSPP_OPTIONAL_PREREQ([libxml2])])
 177
 178 dnl Check for zlib.
 179 AC_SEARCH_LIBS(
 180   [gzopen], [z],
 181   [HAVE_ZLIB=yes],
 182   [HAVE_ZLIB=no
 183    PSPP_OPTIONAL_PREREQ([zlib])])
 184 AC_CHECK_HEADERS(
 185   [zlib.h],
 186   [],
 187   [HAVE_ZLIB=no
 188    PSPP_OPTIONAL_PREREQ([zlib])])
 189
 190 dnl Avoid interference between zlib's crc32() function and gnulib's
 191 dnl crc32() function, which have different signatures.  PSPP calls
 192 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 193 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 194 dnl crc32(), then zlib will call gnulib's version instead of its own,
 195 dnl causing failures.  (This can happen even if zlib isn't detected
 196 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 197 dnl sometimes use zlib themselves.)
 198 AC_DEFINE(
 199   [crc32], [gl_crc32],
 200   [Avoid making zlib call gnulib's crc32() instead of its own.])
 201
 202 dnl Gnumeric support requires libxml2 and zlib.
 203 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 204   GNM_SUPPORT=yes
 205   AC_DEFINE(
 206     [GNM_SUPPORT], [1],
 207     [Define to 1 if building in support for reading Gnumeric files.])
 208 else
 209   GNM_SUPPORT=no
 210 fi
 211 AC_SUBST([GNM_SUPPORT])
 212
 213 dnl ODT support requires libxml2.
 214 if test $HAVE_LIBXML2 = yes; then
 215   AC_DEFINE(
 216     [ODT_SUPPORT], [1],
 217     [Define to 1 if building in support for writing ODT files.])
 218 fi
 219 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 220
 221 AC_ARG_WITH(
 222   gui_tools,
 223   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 224 if test x"$with_gui_tools" = x"yes" ; then
 225         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 226 fi
 227 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 228
 229 AC_ARG_WITH(
 230   [perl-module],
 231   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 232   [case $with_perl_module in # (
 233      yes|no) ;; # (
 234      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 235    esac
 236    WITH_PERL_MODULE=$with_perl_module],
 237   [if test x"$cross_compiling" != x"yes"; then
 238      WITH_PERL_MODULE=yes
 239    else
 240      WITH_PERL_MODULE=no
 241    fi])
 242 AC_SUBST([WITH_PERL_MODULE])
 243 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 244
 245 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 246 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 247                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 248
 249
 250 PSPP_GSL_NEEDS_FGNU89_INLINE
 251
 252 dnl Recent versions of GNU ncurses install the curses header files into
 253 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 254 dnl enables us to discover where they are. Earlier versions don't have
 255 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 256 dnl we'll trust it to find the right information.  Otherwise, we'll
 257 dnl try to discover it ourselves.
 258 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 259 dnl to ncurses8-config !!!
 260 AC_ARG_WITH(
 261   libncurses,
 262   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 263
 264 if test x"$with_libncurses" != x"no" ; then
 265   if test x"$cross_compiling" != x"yes" ; then
 266           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 267   fi
 268   if test x"$NCURSES_CONFIG" = x ; then
 269           AC_SEARCH_LIBS([tgetent], [ncurses],
 270               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 271   else
 272           old_cflags=$CFLAGS
 273           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 274           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 275           CFLAGS=$old_cflags
 276           if test x"$curses_available" = x"yes" ; then
 277            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 278            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 279            AC_SUBST(NCURSES_CFLAGS)
 280            AC_SUBST(NCURSES_LIBS)
 281           fi
 282   fi
 283   if test x"$curses_available" = x"yes" ; then
 284           AC_DEFINE([LIBNCURSES_USABLE], 1,
 285               [Define to 1 if the libncurses is both present and usable.])
 286   fi
 287   AC_CHECK_HEADERS([termcap.h])
 288 fi
 289
 290 PSPP_READLINE
 291
 292 dnl Checks for header files.
 293 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 294
 295 dnl Some systems dont have SIGWINCH
 296 AC_CHECK_DECLS([SIGWINCH], [], [],
 297           [#include <signal.h>
 298           /* NetBSD declares sys_siglist in unistd.h.  */
 299           #ifdef HAVE_UNISTD_H
 300           # include <unistd.h>
 301           #endif
 302           ])
 303
 304
 305 # For gnulib.
 306 gl_INIT
 307
 308 AC_C_INLINE
 309
 310 AC_CHECK_SIZEOF([size_t])
 311 SIZEOF_SIZE_T=$ac_cv_sizeof_size_t
 312 AC_SUBST([SIZEOF_SIZE_T])
 313
 314 AC_C_BIGENDIAN
 315
 316 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 317
 318 AC_PROG_LN_S
 319
 320 AC_ARG_ENABLE(
 321   debug,
 322   [AS_HELP_STRING([--enable-debug],
 323                   [Turn on diagnostic features in the program])])
 324 if test x"$enable_debug" = x"yes"  ; then
 325   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 326 fi
 327
 328 # iconv is required
 329 AM_ICONV
 330 if test "$am_cv_func_iconv" != "yes"; then
 331    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 332 fi
 333 LIBS="$LIBICONV $LIBS"
 334
 335 dnl Required by the gnulib 'relocatable-prog' module.
 336 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 337 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 338 RELOCATABLE_STRIP=:
 339
 340 PSPP_CHECK_PREREQS
 341
 342 AC_CONFIG_FILES(
 343   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 344
 345 AC_OUTPUT
 346 echo "PSPP configured successfully."
 347
 348 dnl configure.ac ends here