pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.63)
  21 AC_INIT([GNU PSPP], [1.3.0], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  40 PSPP_CHECK_DOT
  41
  42 PSPP_ENABLE_WERROR
  43
  44 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  45
  46 PSPP_CC_FOR_BUILD
  47 PSPP_PERL
  48 PSPP_PYTHON
  49
  50 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  51 AC_PROVIDE([AM_PO_SUBDIRS])
  52 AM_GNU_GETTEXT([external], [need-ngettext])
  53 LIBS="$LIBINTL $LIBS"
  54 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  55 if test "x$MSGFMT" = x; then
  56   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  57 fi
  58
  59 AC_CHECK_HEADERS([sys/resource.h])
  60
  61
  62 dnl Checks for libraries.
  63 AC_SYS_LARGEFILE
  64 AC_SEARCH_LIBS([sin], [m])
  65 PSPP_LC_PAPER
  66
  67
  68 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  69 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  70
  71 # Support for Cairo and Pango.
  72 AC_ARG_WITH([cairo],
  73   [AS_HELP_STRING(
  74     [--without-cairo],
  75     [Don't build support for charts (using Cairo and Pango);
  76      implies --without-gui])],
  77   [], [with_cairo=yes])
  78 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  79 if test "$with_cairo" != no; then
  80   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  81     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  82      AC_DEFINE([HAVE_CAIRO], 1,
  83        [Define to 1 if Cairo and Pango are available.])],
  84     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  85 fi
  86
  87 dnl One of the tests uses xmllint.
  88 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  89 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  90   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  91     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  92     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  93    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  94
  95 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  96
  97 # Support for GUI.
  98 AC_ARG_WITH([gui],
  99   [AS_HELP_STRING([--without-gui],
 100                   [Don't build the PSPPIRE GUI (using GTK+)])],
 101   [], [with_gui=yes])
 102 AM_CONDITIONAL([HAVE_GUI],
 103                [test "$with_cairo" != no && test "$with_gui" != "no"])
 104 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 105   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 106     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 107
 108   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 109     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 110
 111   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 112     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 113
 114   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 115     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 116
 117   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.4], [],
 118     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.4 (or use --without-gui)])])
 119
 120   AC_ARG_VAR([GLIB_GENMARSHAL])
 121   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 122   if test "x$GLIB_GENMARSHAL" = x; then
 123     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 124   fi
 125
 126   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 127   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 128     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 129   fi
 130
 131 fi
 132
 133 gl_NEXT_HEADERS([gtk/gtk.h])
 134
 135 dnl Checks needed for psql reader
 136
 137 dnl The 8.x series postgres tarballs installs with a default prefix of
 138 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 139
 140 dnl If the libpq.so file is in a non standard path, (one which the linker
 141 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 142 dnl However, if the system happens to have more than one version of other
 143 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 144 dnl /usr and /usr/local) then the wrong one may get linked.
 145
 146 dnl To overcome this, we first check for libpq in the standard places, and
 147 dnl only set PG_LDFLAGS if it's not found.
 148
 149
 150 AC_ARG_WITH(
 151   libpq,
 152   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 153 AC_ARG_VAR([PG_CONFIG],
 154            [Full pathname of the pg_config program shipped with Postgresql])
 155 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 156              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 157
 158 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 159   AC_SUBST(PG_CONFIG)
 160   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 161   AC_SUBST(PG_CFLAGS)
 162
 163   AC_CHECK_LIB([pq], [PQexec],
 164      [:],
 165      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 166   AC_SUBST(PG_LDFLAGS)
 167
 168   PG_LIBS=-lpq
 169   AC_SUBST(PG_LIBS)
 170
 171   PKG_CHECK_EXISTS(libssl,
 172         AC_DEFINE([USE_SSL],1,
 173                    [Define to 1 if the openssl library is present.])
 174            ,)
 175
 176   # Now verify that we can actually link against libpq.  If we are
 177   # cross-compiling and picked up a host libpq, or if libpq is just
 178   # badly installed, this will fail.
 179   AC_CACHE_CHECK(
 180     [whether -lpq links successfully],
 181     [pspp_cv_have_libpq],
 182     [save_CPPFLAGS=$CPPFLAGS
 183      save_LIBS=$LIBS
 184      save_LDFLAGS=$LDFLAGS
 185      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 186      LIBS="$PG_LIBS $LIBS"
 187      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 188      AC_LINK_IFELSE(
 189        [AC_LANG_PROGRAM(
 190          [#include <libpq-fe.h>
 191          ], [PQfinish (0);])],
 192        [pspp_cv_have_libpq=yes],
 193        [pspp_cv_have_libpq=no])
 194      CPPFLAGS=$save_CPPFLAGS
 195      LIBS=$save_LIBS
 196      LDFLAGS=$save_LDFLAGS])
 197
 198   if test $pspp_cv_have_libpq = yes; then
 199     PSQL_SUPPORT=yes
 200     AC_DEFINE([PSQL_SUPPORT], [1],
 201       [Define to 1 if building in support for reading from postgres
 202        databases.])
 203   else
 204     PSQL_SUPPORT=no
 205     PG_CONFIG=
 206     PG_CFLAGS=
 207     PG_LDFLAGS=
 208     PG_LIBS=
 209   fi
 210 else
 211   PSQL_SUPPORT=no
 212   pspp_cv_have_libpq=no
 213 fi
 214 AC_SUBST([PSQL_SUPPORT])
 215
 216 dnl Check for libxml2
 217 PKG_CHECK_MODULES(
 218   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 219
 220 dnl Check for zlib.
 221 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 222 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 223
 224 dnl Avoid interference between zlib's crc32() function and gnulib's
 225 dnl crc32() function, which have different signatures.  PSPP calls
 226 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 227 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 228 dnl crc32(), then zlib will call gnulib's version instead of its own,
 229 dnl causing failures.  (This can happen even if zlib isn't detected
 230 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 231 dnl sometimes use zlib themselves.)
 232 AC_DEFINE(
 233   [crc32], [gl_crc32],
 234   [Avoid making zlib call gnulib's crc32() instead of its own.])
 235
 236 AC_ARG_WITH(
 237   gui_tools,
 238   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 239 if test x"$with_gui_tools" = x"yes" ; then
 240         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 241 fi
 242 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 243
 244 AC_ARG_WITH(
 245   [perl-module],
 246   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 247   [case $with_perl_module in # (
 248      yes|no) ;; # (
 249      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 250    esac
 251    WITH_PERL_MODULE=$with_perl_module],
 252   [if test x"$cross_compiling" != x"yes"; then
 253      WITH_PERL_MODULE=yes
 254    else
 255      WITH_PERL_MODULE=no
 256    fi])
 257 AC_SUBST([WITH_PERL_MODULE])
 258 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 259
 260 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 261 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 262                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 263
 264
 265 PSPP_GSL_NEEDS_FGNU89_INLINE
 266
 267 PSPP_READLINE
 268
 269 dnl Checks for header files.
 270 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 271
 272 dnl Some systems don't have SIGWINCH
 273 AC_CHECK_DECLS([SIGWINCH], [], [],
 274           [#include <signal.h>
 275           /* NetBSD declares sys_siglist in unistd.h.  */
 276           #ifdef HAVE_UNISTD_H
 277           # include <unistd.h>
 278           #endif
 279           ])
 280
 281
 282 # For gnulib.
 283 gl_INIT
 284
 285 AC_C_INLINE
 286
 287 AC_C_BIGENDIAN
 288
 289 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 290
 291 AC_PROG_LN_S
 292
 293 AC_ARG_ENABLE(
 294   debug,
 295   [AS_HELP_STRING([--enable-debug],
 296                   [Turn on diagnostic features in the program])])
 297 if test x"$enable_debug" = x"yes"  ; then
 298   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 299 fi
 300
 301 # iconv is required
 302 AM_ICONV
 303 if test "$am_cv_func_iconv" != "yes"; then
 304    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 305 fi
 306 LIBS="$LIBICONV $LIBS"
 307
 308 dnl Required by the gnulib 'relocatable-prog' module.
 309 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 310 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 311 RELOCATABLE_STRIP=:
 312
 313 PSPP_CHECK_PREREQS
 314
 315 AC_CONFIG_FILES(
 316   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 317
 318 AC_CONFIG_COMMANDS([doc/dummy], [:])
 319
 320 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 321
 322 AC_OUTPUT
 323 echo "PSPP configured successfully."
 324
 325 dnl configure.ac ends here