pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017, 2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.5.3], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 if test x"$cross_compiling" = x"yes"; then
  32    if test x"$srcdir" = x"."; then
  33       AC_ERROR([Cross compiling must be done out of source.])
  34    fi
  35 fi
  36
  37 AM_PROG_CC_C_O
  38 AC_LIBTOOL_WIN32_DLL
  39 AC_LIBTOOL_DLOPEN
  40 AC_PROG_LIBTOOL
  41 AC_HEADER_TIOCGWINSZ
  42
  43 AC_CHECK_SIZEOF([ptrdiff_t])
  44 binary_width=`expr 8 '*' $ac_cv_sizeof_ptrdiff_t`
  45 AC_SUBST([binary_width])
  46
  47
  48 PKG_PROG_PKG_CONFIG
  49 m4_pattern_forbid([PKG_CHECK_MODULES])
  50 PSPP_CHECK_CLICKSEQUENCE
  51 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  52 PSPP_CHECK_DOT
  53
  54 PSPP_ENABLE_WERROR
  55
  56 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  57 AM_CONDITIONAL(host_is_w32, [case $host_os in mingw*) true;; *) false;; esac] )
  58
  59 PSPP_PERL
  60 PSPP_PYTHON
  61 AC_CHECK_PROGS([TEX], [tex], [no])
  62 AC_SUBST([TEX])
  63 AC_CHECK_PROGS([GWC], [gwc wc], [no])
  64 AC_SUBST([GWC])
  65
  66 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  67 # avoided in GCC 10.x:
  68 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  69 #   cc1: error: function may return address of local variable
  70 CFLAGS="$CFLAGS -DGCC_LINT"
  71
  72 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  73 AC_PROVIDE([AM_PO_SUBDIRS])
  74 AM_GNU_GETTEXT([external], [need-ngettext])
  75
  76 LIBS="$LIBINTL $LIBS"
  77 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  78 if test "x$MSGFMT" = x; then
  79   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  80 fi
  81
  82 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  83 if test "x$XGETTEXT" = x; then
  84   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  85 fi
  86
  87 PSPP_CHECK_XGETTEXT
  88
  89 if test "$pspp_cv_progrecent_xgettext"  != "yes"; then
  90    PSPP_REQUIRED_PREREQ([xgettext version 0.20 or greater])
  91 fi
  92
  93 dnl Checks for libraries.
  94 AC_SYS_LARGEFILE
  95 AC_SEARCH_LIBS([sin], [m])
  96 PSPP_LC_PAPER
  97
  98
  99 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
 100 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
 101
 102 # Support for Cairo and Pango.
 103 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 104   [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"],
 105   [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later])])
 106
 107 dnl One of the tests uses xmllint.
 108 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 109 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 110   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 111     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 112     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 113    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 114
 115 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 116
 117 # Support for GUI.
 118 AC_ARG_WITH([gui],
 119   [AS_HELP_STRING([--without-gui],
 120                   [Don't build the PSPPIRE GUI (using GTK+)])],
 121   [], [with_gui=yes])
 122 AM_CONDITIONAL([building_gui], [test "$with_gui" != "no"])
 123 if test "$with_gui" != "no"; then
 124   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 125     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 126
 127   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 128     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 129
 130   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 131     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 132
 133   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 134     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 135
 136   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 137     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 138   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 139
 140   AC_ARG_VAR([GLIB_GENMARSHAL])
 141   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 142   if test "x$GLIB_GENMARSHAL" = x; then
 143     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 144   fi
 145
 146   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 147   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 148     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 149   fi
 150
 151 fi
 152
 153 gl_NEXT_HEADERS([gtk/gtk.h])
 154
 155 dnl Checks needed for psql reader
 156
 157 dnl The 8.x series postgres tarballs installs with a default prefix of
 158 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 159
 160 dnl If the libpq.so file is in a non standard path, (one which the linker
 161 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 162 dnl However, if the system happens to have more than one version of other
 163 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 164 dnl /usr and /usr/local) then the wrong one may get linked.
 165
 166 dnl To overcome this, we first check for libpq in the standard places, and
 167 dnl only set PG_LDFLAGS if it's not found.
 168
 169
 170 AC_ARG_WITH(
 171   libpq,
 172   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 173 AC_ARG_VAR([PG_CONFIG],
 174            [Full pathname of the pg_config program shipped with Postgresql])
 175 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 176              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 177
 178 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 179   AC_SUBST(PG_CONFIG)
 180   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 181   AC_SUBST(PG_CFLAGS)
 182
 183   AC_CHECK_LIB([pq], [PQexec],
 184      [:],
 185      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 186   AC_SUBST(PG_LDFLAGS)
 187
 188   PG_LIBS=-lpq
 189   AC_SUBST(PG_LIBS)
 190
 191   PKG_CHECK_EXISTS(libssl,
 192         AC_DEFINE([USE_SSL],1,
 193                    [Define to 1 if the openssl library is present.])
 194            ,)
 195
 196   # Now verify that we can actually link against libpq.  If we are
 197   # cross-compiling and picked up a host libpq, or if libpq is just
 198   # badly installed, this will fail.
 199   AC_CACHE_CHECK(
 200     [whether -lpq links successfully],
 201     [pspp_cv_have_libpq],
 202     [save_CPPFLAGS=$CPPFLAGS
 203      save_LIBS=$LIBS
 204      save_LDFLAGS=$LDFLAGS
 205      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 206      LIBS="$PG_LIBS $LIBS"
 207      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 208      AC_LINK_IFELSE(
 209        [AC_LANG_PROGRAM(
 210          [#include <libpq-fe.h>
 211          ], [PQfinish (0);])],
 212        [pspp_cv_have_libpq=yes],
 213        [pspp_cv_have_libpq=no])
 214      CPPFLAGS=$save_CPPFLAGS
 215      LIBS=$save_LIBS
 216      LDFLAGS=$save_LDFLAGS])
 217
 218   if test $pspp_cv_have_libpq = yes; then
 219     PSQL_SUPPORT=yes
 220     AC_DEFINE([PSQL_SUPPORT], [1],
 221       [Define to 1 if building in support for reading from postgres
 222        databases.])
 223   else
 224     PSQL_SUPPORT=no
 225     PG_CONFIG=
 226     PG_CFLAGS=
 227     PG_LDFLAGS=
 228     PG_LIBS=
 229   fi
 230 else
 231   PSQL_SUPPORT=no
 232   pspp_cv_have_libpq=no
 233 fi
 234 AC_SUBST([PSQL_SUPPORT])
 235
 236 dnl Check for libxml2
 237 PKG_CHECK_MODULES(
 238   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 239
 240 dnl Check for zlib.
 241 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 242 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 243
 244 dnl Avoid interference between zlib's crc32() function and gnulib's
 245 dnl crc32() function, which have different signatures.  PSPP calls
 246 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 247 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 248 dnl crc32(), then zlib will call gnulib's version instead of its own,
 249 dnl causing failures.  (This can happen even if zlib isn't detected
 250 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 251 dnl sometimes use zlib themselves.)
 252 AC_DEFINE(
 253   [crc32], [gl_crc32],
 254   [Avoid making zlib call gnulib's crc32() instead of its own.])
 255
 256 AC_ARG_WITH(
 257   [perl-module],
 258   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 259   [case $with_perl_module in # (
 260      yes|no) ;; # (
 261      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 262    esac
 263    WITH_PERL_MODULE=$with_perl_module],
 264   [if test x"$cross_compiling" != x"yes"; then
 265      WITH_PERL_MODULE=yes
 266    else
 267      WITH_PERL_MODULE=no
 268    fi])
 269 AC_SUBST([WITH_PERL_MODULE])
 270 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 271
 272 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 273 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 274                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 275
 276
 277 PSPP_GSL_NEEDS_FGNU89_INLINE
 278
 279 PSPP_READLINE
 280
 281 dnl Checks for header files.
 282 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 283
 284 dnl Some systems don't have SIGWINCH
 285 AC_CHECK_DECLS([SIGWINCH], [], [],
 286           [#include <signal.h>
 287           /* NetBSD declares sys_siglist in unistd.h.  */
 288           #ifdef HAVE_UNISTD_H
 289           # include <unistd.h>
 290           #endif
 291           ])
 292
 293
 294 # For gnulib.
 295 gl_INIT
 296
 297 AC_C_INLINE
 298
 299 AC_C_BIGENDIAN
 300
 301 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 302
 303 AC_PROG_LN_S
 304
 305 # iconv is required
 306 AM_ICONV
 307 if test "$am_cv_func_iconv" != "yes"; then
 308    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 309 fi
 310 LIBS="$LIBICONV $LIBS"
 311
 312 dnl Required by the gnulib 'relocatable-prog' module.
 313 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 314 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 315 RELOCATABLE_STRIP=:
 316
 317 PSPP_CHECK_PREREQS
 318
 319 dnl The makefile needs to know if we're cross compiling, so that
 320 dnl it can make arrangements to build the documentation examples.
 321 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 322
 323 AC_CONFIG_FILES(
 324   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 325
 326 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 327
 328 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 329
 330 AC_OUTPUT
 331 echo "PSPP configured successfully."
 332
 333 dnl configure.ac ends here