pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.63)
  21 AC_INIT([GNU PSPP], [1.5.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  40 PSPP_CHECK_DOT
  41
  42 PSPP_ENABLE_WERROR
  43
  44 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  45
  46 PSPP_CC_FOR_BUILD
  47 PSPP_PERL
  48 PSPP_PYTHON
  49
  50 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  51 # avoided in GCC 10.x:
  52 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  53 #   cc1: error: function may return address of local variable
  54 CFLAGS="$CFLAGS -DGCC_LINT"
  55
  56 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  57 AC_PROVIDE([AM_PO_SUBDIRS])
  58 AM_GNU_GETTEXT([external], [need-ngettext])
  59 LIBS="$LIBINTL $LIBS"
  60 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  61 if test "x$MSGFMT" = x; then
  62   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  63 fi
  64
  65 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  66 if test "x$XGETTEXT" = x; then
  67   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  68 fi
  69 dnl appstream required for metainfo.its
  70 dnl if metainfo.its is not there, then the following small
  71 dnl file will not produce an outputfile
  72 $as_echo '<?xml version="1.0" encoding="UTF-8"?>' > test.metainfo.xml.in
  73 $as_echo '<component type="desktop">' >> test.metainfo.xml.in
  74 $as_echo '<name>Hallo</name>' >> test.metainfo.xml.in
  75 $as_echo '</component>' >> test.metainfo.xml.in
  76 xgettext -o mifc.po test.metainfo.xml.in
  77 if ! test -f ./mifc.po  ; then
  78   PSPP_OPTIONAL_PREREQ([org.fsf.metainfo.xml will not be translated. Install gettext >=0.20 or appstream.])
  79 fi
  80 rm -f mifc.po test.metainfo.xml.in
  81
  82 dnl Checks for libraries.
  83 AC_SYS_LARGEFILE
  84 AC_SEARCH_LIBS([sin], [m])
  85 PSPP_LC_PAPER
  86
  87
  88 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  89 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  90
  91 # Support for Cairo and Pango.
  92 AC_ARG_WITH([cairo],
  93   [AS_HELP_STRING(
  94     [--without-cairo],
  95     [Don't build support for charts (using Cairo and Pango);
  96      implies --without-gui])],
  97   [], [with_cairo=yes])
  98 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  99 if test "$with_cairo" != no; then
 100   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 101     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
 102      AC_DEFINE([HAVE_CAIRO], 1,
 103        [Define to 1 if Cairo and Pango are available.])],
 104     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
 105 fi
 106
 107 dnl One of the tests uses xmllint.
 108 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 109 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 110   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 111     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 112     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 113    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 114
 115 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 116
 117 # Support for GUI.
 118 AC_ARG_WITH([gui],
 119   [AS_HELP_STRING([--without-gui],
 120                   [Don't build the PSPPIRE GUI (using GTK+)])],
 121   [], [with_gui=yes])
 122 AM_CONDITIONAL([building_gui],
 123                [test "$with_cairo" != no && test "$with_gui" != "no"])
 124 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 125   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 126     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 127
 128   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 129     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 130
 131   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 132     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 133
 134   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 135     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 136
 137   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 138     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 139
 140   PKG_CHECK_MODULES([LIBRSVG], [librsvg-2.0 >= 2.44],
 141     [AC_DEFINE([HAVE_RSVG], 1, [Define to 1 if librsvg is available])],
 142     [PSPP_OPTIONAL_PREREQ([librsvg >= 2.44 required for high dpi Copy and Paste])])
 143
 144   AC_ARG_VAR([GLIB_GENMARSHAL])
 145   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 146   if test "x$GLIB_GENMARSHAL" = x; then
 147     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 148   fi
 149
 150   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 151   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 152     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 153   fi
 154
 155 fi
 156
 157 gl_NEXT_HEADERS([gtk/gtk.h])
 158
 159 dnl Checks needed for psql reader
 160
 161 dnl The 8.x series postgres tarballs installs with a default prefix of
 162 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 163
 164 dnl If the libpq.so file is in a non standard path, (one which the linker
 165 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 166 dnl However, if the system happens to have more than one version of other
 167 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 168 dnl /usr and /usr/local) then the wrong one may get linked.
 169
 170 dnl To overcome this, we first check for libpq in the standard places, and
 171 dnl only set PG_LDFLAGS if it's not found.
 172
 173
 174 AC_ARG_WITH(
 175   libpq,
 176   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 177 AC_ARG_VAR([PG_CONFIG],
 178            [Full pathname of the pg_config program shipped with Postgresql])
 179 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 180              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 181
 182 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 183   AC_SUBST(PG_CONFIG)
 184   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 185   AC_SUBST(PG_CFLAGS)
 186
 187   AC_CHECK_LIB([pq], [PQexec],
 188      [:],
 189      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 190   AC_SUBST(PG_LDFLAGS)
 191
 192   PG_LIBS=-lpq
 193   AC_SUBST(PG_LIBS)
 194
 195   PKG_CHECK_EXISTS(libssl,
 196         AC_DEFINE([USE_SSL],1,
 197                    [Define to 1 if the openssl library is present.])
 198            ,)
 199
 200   # Now verify that we can actually link against libpq.  If we are
 201   # cross-compiling and picked up a host libpq, or if libpq is just
 202   # badly installed, this will fail.
 203   AC_CACHE_CHECK(
 204     [whether -lpq links successfully],
 205     [pspp_cv_have_libpq],
 206     [save_CPPFLAGS=$CPPFLAGS
 207      save_LIBS=$LIBS
 208      save_LDFLAGS=$LDFLAGS
 209      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 210      LIBS="$PG_LIBS $LIBS"
 211      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 212      AC_LINK_IFELSE(
 213        [AC_LANG_PROGRAM(
 214          [#include <libpq-fe.h>
 215          ], [PQfinish (0);])],
 216        [pspp_cv_have_libpq=yes],
 217        [pspp_cv_have_libpq=no])
 218      CPPFLAGS=$save_CPPFLAGS
 219      LIBS=$save_LIBS
 220      LDFLAGS=$save_LDFLAGS])
 221
 222   if test $pspp_cv_have_libpq = yes; then
 223     PSQL_SUPPORT=yes
 224     AC_DEFINE([PSQL_SUPPORT], [1],
 225       [Define to 1 if building in support for reading from postgres
 226        databases.])
 227   else
 228     PSQL_SUPPORT=no
 229     PG_CONFIG=
 230     PG_CFLAGS=
 231     PG_LDFLAGS=
 232     PG_LIBS=
 233   fi
 234 else
 235   PSQL_SUPPORT=no
 236   pspp_cv_have_libpq=no
 237 fi
 238 AC_SUBST([PSQL_SUPPORT])
 239
 240 dnl Check for libxml2
 241 PKG_CHECK_MODULES(
 242   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 243
 244 dnl Check for zlib.
 245 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 246 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 247
 248 dnl Avoid interference between zlib's crc32() function and gnulib's
 249 dnl crc32() function, which have different signatures.  PSPP calls
 250 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 251 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 252 dnl crc32(), then zlib will call gnulib's version instead of its own,
 253 dnl causing failures.  (This can happen even if zlib isn't detected
 254 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 255 dnl sometimes use zlib themselves.)
 256 AC_DEFINE(
 257   [crc32], [gl_crc32],
 258   [Avoid making zlib call gnulib's crc32() instead of its own.])
 259
 260 AC_ARG_WITH(
 261   [perl-module],
 262   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 263   [case $with_perl_module in # (
 264      yes|no) ;; # (
 265      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 266    esac
 267    WITH_PERL_MODULE=$with_perl_module],
 268   [if test x"$cross_compiling" != x"yes"; then
 269      WITH_PERL_MODULE=yes
 270    else
 271      WITH_PERL_MODULE=no
 272    fi])
 273 AC_SUBST([WITH_PERL_MODULE])
 274 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 275
 276 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 277 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 278                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 279
 280
 281 PSPP_GSL_NEEDS_FGNU89_INLINE
 282
 283 PSPP_READLINE
 284
 285 dnl Checks for header files.
 286 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 287
 288 dnl Some systems don't have SIGWINCH
 289 AC_CHECK_DECLS([SIGWINCH], [], [],
 290           [#include <signal.h>
 291           /* NetBSD declares sys_siglist in unistd.h.  */
 292           #ifdef HAVE_UNISTD_H
 293           # include <unistd.h>
 294           #endif
 295           ])
 296
 297
 298 # For gnulib.
 299 gl_INIT
 300
 301 AC_C_INLINE
 302
 303 AC_C_BIGENDIAN
 304
 305 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 306
 307 AC_PROG_LN_S
 308
 309 # iconv is required
 310 AM_ICONV
 311 if test "$am_cv_func_iconv" != "yes"; then
 312    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 313 fi
 314 LIBS="$LIBICONV $LIBS"
 315
 316 dnl Required by the gnulib 'relocatable-prog' module.
 317 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 318 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 319 RELOCATABLE_STRIP=:
 320
 321 PSPP_CHECK_PREREQS
 322
 323 AC_CONFIG_FILES(
 324   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 325
 326 AC_CONFIG_COMMANDS([doc/dummy], [:])
 327
 328 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 329
 330 AC_OUTPUT
 331 echo "PSPP configured successfully."
 332
 333 dnl configure.ac ends here