pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.3],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 PSPP_LC_PAPER
  44
  45
  46 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  47 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  48
  49 # Support for Cairo and Pango.
  50 AC_ARG_WITH([cairo],
  51   [AS_HELP_STRING(
  52     [--without-cairo],
  53     [Don't build support for charts (using Cairo and Pango);
  54      implies --without-gui])],
  55   [], [with_cairo=yes])
  56 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  57 if test "$with_cairo" != no; then
  58   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  59     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  60      AC_DEFINE([HAVE_CAIRO], 1,
  61        [Define to 1 if Cairo and Pango are available.])],
  62     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  63 fi
  64
  65 # Support for GUI.
  66 AC_ARG_WITH([gui],
  67   [AS_HELP_STRING([--without-gui],
  68                   [Don't build the PSPPIRE GUI (using GTK+)])],
  69   [], [with_gui=yes])
  70 AM_CONDITIONAL([HAVE_GUI],
  71                [test "$with_cairo" != no && test "$with_gui" != "no"])
  72 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  73   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  74     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  75 fi
  76
  77 dnl Checks needed for psql reader
  78
  79 dnl The 8.x series postgres tarballs installs with a default prefix of
  80 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  81
  82 dnl If the libpq.so file is in a non standard path, (one which the linker
  83 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  84 dnl However, if the system happens to have more than one version of other
  85 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  86 dnl /usr and /usr/local) then the wrong one may get linked.
  87
  88 dnl To overcome this, we first check for libpq in the standard places, and
  89 dnl only set PG_LDFLAGS if it's not found.
  90
  91
  92 AC_ARG_WITH(
  93   libpq,
  94   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  95
  96 if test x"$with_libpq" != x"no" ; then
  97  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  98
  99  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
 100  if test x"$cross_compiling" != x"yes" ; then
 101    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 102  fi
 103  if test -n "$PG_CONFIG" ; then
 104    AC_SUBST(PG_CONFIG)
 105    AC_DEFINE([PSQL_SUPPORT], 1,
 106    [Define to 1 if building in support for reading from postgres databases.])
 107    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 108    AC_SUBST(PG_CFLAGS)
 109
 110    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 111       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 112    fi
 113    AC_SUBST(PG_LDFLAGS)
 114
 115    PG_LIBS=-lpq
 116    AC_SUBST(PG_LIBS)
 117    PKG_CHECK_EXISTS(libssl,
 118          AC_DEFINE([USE_SSL],1,
 119                     [Define to 1 if the openssl library is present.])
 120             ,)
 121  fi
 122 fi
 123 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 124
 125 dnl Checks needed for Gnumeric reader
 126 gnm_support=yes;
 127 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 128                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 129 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 130 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 131
 132 if test x"$gnm_support" = x"yes" ; then
 133    AC_DEFINE([GNM_SUPPORT], 1,
 134    [Define to 1 if building in support for reading Gnumeric files.])
 135 fi
 136 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 137
 138 AC_ARG_WITH(
 139   gui_tools,
 140   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 141 if test x"$with_gui_tools" = x"yes" ; then
 142         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 143 fi
 144 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 145
 146 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 147
 148 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 149 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 150 PSPP_GSL_NEEDS_FGNU89_INLINE
 151
 152 dnl Recent versions of GNU ncurses install the curses header files into
 153 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 154 dnl enables us to discover where they are. Earlier versions don't have
 155 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 156 dnl we'll trust it to find the right information.  Otherwise, we'll
 157 dnl try to discover it ourselves.
 158 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 159 dnl to ncurses8-config !!!
 160 AC_ARG_WITH(
 161   libncurses,
 162   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 163
 164 if test x"$with_libncurses" != x"no" ; then
 165   if test x"$cross_compiling" != x"yes" ; then
 166           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 167   fi
 168   if test x"$NCURSES_CONFIG" = x ; then
 169           AC_SEARCH_LIBS([tgetent], [ncurses],
 170               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 171   else
 172           old_cflags=$CFLAGS
 173           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 174           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 175           CFLAGS=$old_cflags
 176           if test x"$curses_available" = x"yes" ; then
 177            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 178            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 179            AC_SUBST(NCURSES_CFLAGS)
 180            AC_SUBST(NCURSES_LIBS)
 181           fi
 182   fi
 183   if test x"$curses_available" = x"yes" ; then
 184           AC_DEFINE([LIBNCURSES_USABLE], 1,
 185               [Define to 1 if the libncurses is both present and usable.])
 186   fi
 187   AC_CHECK_HEADERS([termcap.h])
 188 fi
 189
 190 PSPP_READLINE
 191
 192 dnl Checks for header files.
 193 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 194
 195 # For gnulib.
 196 gl_INIT
 197
 198 AC_C_INLINE
 199
 200 AC_CHECK_SIZEOF(double)
 201
 202 AC_C_BIGENDIAN
 203
 204 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 205
 206 AC_PROG_LN_S
 207
 208 AC_ARG_ENABLE(
 209   debug,
 210   [AS_HELP_STRING([--enable-debug],
 211                   [Turn on diagnostic features in the program])])
 212 if test x"$enable_debug" = x"yes"  ; then
 213   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 214 fi
 215
 216 # iconv is required
 217 if test "$am_cv_func_iconv" != "yes"; then
 218    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 219 fi
 220
 221 dnl Required by the gnulib 'relocatable-prog' module.
 222 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 223 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 224 RELOCATABLE_STRIP=:
 225
 226 PSPP_CHECK_PREREQS
 227
 228 AC_CONFIG_FILES([Makefile gl/Makefile])
 229
 230 AC_OUTPUT
 231 echo "PSPP configured successfully."
 232
 233 dnl configure.ac ends here