pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.8.6], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_WERROR
  24
  25 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  26
  27 PSPP_CC_FOR_BUILD
  28 PSPP_PERL
  29
  30 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  31 AC_PROVIDE([AM_PO_SUBDIRS])
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 LIBS="$LIBINTL $LIBS"
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LC_PAPER
  39
  40
  41 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  42 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  43
  44 # Support for Cairo and Pango.
  45 AC_ARG_WITH([cairo],
  46   [AS_HELP_STRING(
  47     [--without-cairo],
  48     [Don't build support for charts (using Cairo and Pango);
  49      implies --without-gui])],
  50   [], [with_cairo=yes])
  51 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  52 if test "$with_cairo" != no; then
  53   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  54     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  55      AC_DEFINE([HAVE_CAIRO], 1,
  56        [Define to 1 if Cairo and Pango are available.])],
  57     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  58   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  59   AC_SUBST(XMLLINT)
  60 fi
  61
  62 # Support for GUI.
  63 AC_ARG_WITH([gui],
  64   [AS_HELP_STRING([--without-gui],
  65                   [Don't build the PSPPIRE GUI (using GTK+)])],
  66   [], [with_gui=yes])
  67 AM_CONDITIONAL([HAVE_GUI],
  68                [test "$with_cairo" != no && test "$with_gui" != "no"])
  69 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  70   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  71     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  72
  73   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.2], [],
  74     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.4.2 or later (or use --without-gui)])])
  75
  76   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
  77     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
  78
  79   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
  80     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
  81
  82   AC_ARG_VAR([GLIB_GENMARSHAL])
  83   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  84   if test "x$GLIB_GENMARSHAL" = x; then
  85     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  86   fi
  87
  88 fi
  89
  90 gl_NEXT_HEADERS([gtk/gtk.h])
  91
  92 dnl Checks needed for psql reader
  93
  94 dnl The 8.x series postgres tarballs installs with a default prefix of
  95 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  96
  97 dnl If the libpq.so file is in a non standard path, (one which the linker
  98 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  99 dnl However, if the system happens to have more than one version of other
 100 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 101 dnl /usr and /usr/local) then the wrong one may get linked.
 102
 103 dnl To overcome this, we first check for libpq in the standard places, and
 104 dnl only set PG_LDFLAGS if it's not found.
 105
 106
 107 AC_ARG_WITH(
 108   libpq,
 109   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 110 AC_ARG_VAR([PG_CONFIG],
 111            [Full pathname of the pg_config program shipped with Postgresql])
 112 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 113              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 114
 115 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 116   AC_SUBST(PG_CONFIG)
 117   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 118   AC_SUBST(PG_CFLAGS)
 119
 120   AC_CHECK_LIB([pq], [PQexec],
 121      [:],
 122      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 123   AC_SUBST(PG_LDFLAGS)
 124
 125   PG_LIBS=-lpq
 126   AC_SUBST(PG_LIBS)
 127
 128   PKG_CHECK_EXISTS(libssl,
 129         AC_DEFINE([USE_SSL],1,
 130                    [Define to 1 if the openssl library is present.])
 131            ,)
 132
 133   # Now verify that we can actually link against libpq.  If we are
 134   # cross-compiling and picked up a host libpq, or if libpq is just
 135   # badly installed, this will fail.
 136   AC_CACHE_CHECK(
 137     [whether -lpq links successfully],
 138     [pspp_cv_have_libpq],
 139     [save_CPPFLAGS=$CPPFLAGS
 140      save_LIBS=$LIBS
 141      save_LDFLAGS=$LDFLAGS
 142      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 143      LIBS="$PG_LIBS $LIBS"
 144      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 145      AC_LINK_IFELSE(
 146        [AC_LANG_PROGRAM(
 147          [#include <libpq-fe.h>
 148          ], [PQfinish (0);])],
 149        [pspp_cv_have_libpq=yes],
 150        [pspp_cv_have_libpq=no])
 151      CPPFLAGS=$save_CPPFLAGS
 152      LIBS=$save_LIBS
 153      LDFLAGS=$save_LDFLAGS])
 154
 155   if test $pspp_cv_have_libpq = yes; then
 156     PSQL_SUPPORT=yes
 157     AC_DEFINE([PSQL_SUPPORT], [1],
 158       [Define to 1 if building in support for reading from postgres
 159        databases.])
 160   else
 161     PSQL_SUPPORT=no
 162     PG_CONFIG=
 163     PG_CFLAGS=
 164     PG_LDFLAGS=
 165     PG_LIBS=
 166   fi
 167 else
 168   PSQL_SUPPORT=no
 169   pspp_cv_have_libpq=no
 170 fi
 171 AC_SUBST([PSQL_SUPPORT])
 172
 173 dnl Check for libxml2
 174 PKG_CHECK_MODULES(
 175   [LIBXML2], [libxml-2.0],
 176   [HAVE_LIBXML2=yes],
 177   [HAVE_LIBXML2=no
 178    PSPP_OPTIONAL_PREREQ([libxml2])])
 179
 180 dnl Check for zlib.
 181 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 182 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 183
 184 dnl Avoid interference between zlib's crc32() function and gnulib's
 185 dnl crc32() function, which have different signatures.  PSPP calls
 186 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 187 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 188 dnl crc32(), then zlib will call gnulib's version instead of its own,
 189 dnl causing failures.  (This can happen even if zlib isn't detected
 190 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 191 dnl sometimes use zlib themselves.)
 192 AC_DEFINE(
 193   [crc32], [gl_crc32],
 194   [Avoid making zlib call gnulib's crc32() instead of its own.])
 195
 196 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 197 if test $HAVE_LIBXML2 = yes; then
 198   GNM_READ_SUPPORT=yes
 199   ODF_READ_SUPPORT=yes
 200   AC_DEFINE(
 201     [GNM_READ_SUPPORT], [1],
 202     [Define to 1 if building in support for reading Gnumeric files.])
 203   AC_DEFINE(
 204     [ODF_READ_SUPPORT], [1],
 205     [Define to 1 if building in support for reading OpenDocument files.])
 206 else
 207   GNM_READ_SUPPORT=no
 208   ODF_READ_SUPPORT=no
 209 fi
 210 AC_SUBST([GNM_READ_SUPPORT])
 211 AC_SUBST([ODF_READ_SUPPORT])
 212
 213 dnl ODF support requires libxml2 (zlib is optional).
 214 if test $HAVE_LIBXML2 = yes; then
 215   AC_DEFINE(
 216     [ODF_WRITE_SUPPORT], [1],
 217     [Define to 1 if building in support for writing OpenDocument files.])
 218 fi
 219 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 220
 221 AC_ARG_WITH(
 222   gui_tools,
 223   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 224 if test x"$with_gui_tools" = x"yes" ; then
 225         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 226 fi
 227 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 228
 229 AC_ARG_WITH(
 230   [perl-module],
 231   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 232   [case $with_perl_module in # (
 233      yes|no) ;; # (
 234      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 235    esac
 236    WITH_PERL_MODULE=$with_perl_module],
 237   [if test x"$cross_compiling" != x"yes"; then
 238      WITH_PERL_MODULE=yes
 239    else
 240      WITH_PERL_MODULE=no
 241    fi])
 242 AC_SUBST([WITH_PERL_MODULE])
 243 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 244
 245 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 246 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 247                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 248
 249
 250 PSPP_GSL_NEEDS_FGNU89_INLINE
 251
 252 dnl Recent versions of GNU ncurses install the curses header files into
 253 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 254 dnl enables us to discover where they are. Earlier versions don't have
 255 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 256 dnl we'll trust it to find the right information.  Otherwise, we'll
 257 dnl try to discover it ourselves.
 258 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 259 dnl to ncurses8-config !!!
 260 AC_ARG_WITH(
 261   libncurses,
 262   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 263
 264 if test x"$with_libncurses" != x"no" ; then
 265   if test x"$cross_compiling" != x"yes" ; then
 266           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 267   fi
 268   if test x"$NCURSES_CONFIG" = x ; then
 269           AC_SEARCH_LIBS([tgetent], [ncurses],
 270               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 271   else
 272           old_cflags=$CFLAGS
 273           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 274           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 275           CFLAGS=$old_cflags
 276           if test x"$curses_available" = x"yes" ; then
 277            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 278            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 279            AC_SUBST(NCURSES_CFLAGS)
 280            AC_SUBST(NCURSES_LIBS)
 281           fi
 282   fi
 283   if test x"$curses_available" = x"yes" ; then
 284           AC_DEFINE([LIBNCURSES_USABLE], 1,
 285               [Define to 1 if the libncurses is both present and usable.])
 286   fi
 287   AC_CHECK_HEADERS([termcap.h])
 288 fi
 289
 290 PSPP_READLINE
 291
 292 dnl Checks for header files.
 293 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 294
 295 dnl Some systems dont have SIGWINCH
 296 AC_CHECK_DECLS([SIGWINCH], [], [],
 297           [#include <signal.h>
 298           /* NetBSD declares sys_siglist in unistd.h.  */
 299           #ifdef HAVE_UNISTD_H
 300           # include <unistd.h>
 301           #endif
 302           ])
 303
 304
 305 # For gnulib.
 306 gl_INIT
 307
 308 AC_C_INLINE
 309
 310 AC_C_BIGENDIAN
 311
 312 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 313
 314 AC_PROG_LN_S
 315
 316 AC_ARG_ENABLE(
 317   debug,
 318   [AS_HELP_STRING([--enable-debug],
 319                   [Turn on diagnostic features in the program])])
 320 if test x"$enable_debug" = x"yes"  ; then
 321   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 322 fi
 323
 324 # iconv is required
 325 AM_ICONV
 326 if test "$am_cv_func_iconv" != "yes"; then
 327    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 328 fi
 329 LIBS="$LIBICONV $LIBS"
 330
 331 dnl Required by the gnulib 'relocatable-prog' module.
 332 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 333 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 334 RELOCATABLE_STRIP=:
 335
 336 PSPP_CHECK_PREREQS
 337
 338 AC_CONFIG_FILES(
 339   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 340
 341 AC_CONFIG_COMMANDS([doc/dummy], [:])
 342
 343 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 344
 345 AC_OUTPUT
 346 echo "PSPP configured successfully."
 347
 348 dnl configure.ac ends here