pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.8.0], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  24 PSPP_ENABLE_WERROR
  25
  26 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  27
  28 PSPP_CC_FOR_BUILD
  29 PSPP_PERL
  30
  31 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  32 AC_PROVIDE([AM_PO_SUBDIRS])
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 LIBS="$LIBINTL $LIBS"
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LC_PAPER
  40
  41
  42 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  43 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  44
  45 # Support for Cairo and Pango.
  46 AC_ARG_WITH([cairo],
  47   [AS_HELP_STRING(
  48     [--without-cairo],
  49     [Don't build support for charts (using Cairo and Pango);
  50      implies --without-gui])],
  51   [], [with_cairo=yes])
  52 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  53 if test "$with_cairo" != no; then
  54   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  55     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  56      AC_DEFINE([HAVE_CAIRO], 1,
  57        [Define to 1 if Cairo and Pango are available.])],
  58     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  59   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  60   AC_SUBST(XMLLINT)
  61 fi
  62
  63 # Support for GUI.
  64 AC_ARG_WITH([gui],
  65   [AS_HELP_STRING([--without-gui],
  66                   [Don't build the PSPPIRE GUI (using GTK+)])],
  67   [], [with_gui=yes])
  68 AM_CONDITIONAL([HAVE_GUI],
  69                [test "$with_cairo" != no && test "$with_gui" != "no"])
  70 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  71   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  72     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  73
  74   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  75     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  76
  77   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  78     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  79
  80   AC_ARG_VAR([GLIB_GENMARSHAL])
  81   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  82   if test "x$GLIB_GENMARSHAL" = x; then
  83     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  84   fi
  85
  86 fi
  87
  88 gl_NEXT_HEADERS([gtk/gtk.h])
  89
  90 dnl Checks needed for psql reader
  91
  92 dnl The 8.x series postgres tarballs installs with a default prefix of
  93 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  94
  95 dnl If the libpq.so file is in a non standard path, (one which the linker
  96 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  97 dnl However, if the system happens to have more than one version of other
  98 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  99 dnl /usr and /usr/local) then the wrong one may get linked.
 100
 101 dnl To overcome this, we first check for libpq in the standard places, and
 102 dnl only set PG_LDFLAGS if it's not found.
 103
 104
 105 AC_ARG_WITH(
 106   libpq,
 107   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 108 AC_ARG_VAR([PG_CONFIG],
 109            [Full pathname of the pg_config program shipped with Postgresql])
 110 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 111              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 112
 113 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 114   AC_SUBST(PG_CONFIG)
 115   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 116   AC_SUBST(PG_CFLAGS)
 117
 118   AC_CHECK_LIB([pq], [PQexec],
 119      [:],
 120      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 121   AC_SUBST(PG_LDFLAGS)
 122
 123   PG_LIBS=-lpq
 124   AC_SUBST(PG_LIBS)
 125
 126   PKG_CHECK_EXISTS(libssl,
 127         AC_DEFINE([USE_SSL],1,
 128                    [Define to 1 if the openssl library is present.])
 129            ,)
 130
 131   # Now verify that we can actually link against libpq.  If we are
 132   # cross-compiling and picked up a host libpq, or if libpq is just
 133   # badly installed, this will fail.
 134   AC_CACHE_CHECK(
 135     [whether -lpq links successfully],
 136     [pspp_cv_have_libpq],
 137     [save_CPPFLAGS=$CPPFLAGS
 138      save_LIBS=$LIBS
 139      save_LDFLAGS=$LDFLAGS
 140      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 141      LIBS="$PG_LIBS $LIBS"
 142      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 143      AC_LINK_IFELSE(
 144        [AC_LANG_PROGRAM(
 145          [#include <libpq-fe.h>
 146          ], [PQfinish (0);])],
 147        [pspp_cv_have_libpq=yes],
 148        [pspp_cv_have_libpq=no])
 149      CPPFLAGS=$save_CPPFLAGS
 150      LIBS=$save_LIBS
 151      LDFLAGS=$save_LDFLAGS])
 152
 153   if test $pspp_cv_have_libpq = yes; then
 154     PSQL_SUPPORT=yes
 155     AC_DEFINE([PSQL_SUPPORT], [1],
 156       [Define to 1 if building in support for reading from postgres
 157        databases.])
 158   else
 159     PSQL_SUPPORT=no
 160     PG_CONFIG=
 161     PG_CFLAGS=
 162     PG_LDFLAGS=
 163     PG_LIBS=
 164   fi
 165 else
 166   PSQL_SUPPORT=no
 167   pspp_cv_have_libpq=no
 168 fi
 169 AC_SUBST([PSQL_SUPPORT])
 170
 171 dnl Check for libxml2
 172 PKG_CHECK_MODULES(
 173   [LIBXML2], [libxml-2.0],
 174   [HAVE_LIBXML2=yes],
 175   [HAVE_LIBXML2=no
 176    PSPP_OPTIONAL_PREREQ([libxml2])])
 177
 178 dnl Check for zlib.
 179 AC_SEARCH_LIBS(
 180   [gzopen], [z],
 181   [HAVE_ZLIB=yes],
 182   [HAVE_ZLIB=no
 183    PSPP_OPTIONAL_PREREQ([zlib])])
 184 AC_CHECK_HEADERS(
 185   [zlib.h],
 186   [],
 187   [HAVE_ZLIB=no
 188    PSPP_OPTIONAL_PREREQ([zlib])])
 189
 190 dnl Avoid interference between zlib's crc32() function and gnulib's
 191 dnl crc32() function, which have different signatures.  PSPP calls
 192 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 193 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 194 dnl crc32(), then zlib will call gnulib's version instead of its own,
 195 dnl causing failures.  (This can happen even if zlib isn't detected
 196 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 197 dnl sometimes use zlib themselves.)
 198 AC_DEFINE(
 199   [crc32], [gl_crc32],
 200   [Avoid making zlib call gnulib's crc32() instead of its own.])
 201
 202 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 203 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 204   GNM_SUPPORT=yes
 205   ODF_READ_SUPPORT=yes
 206   AC_DEFINE(
 207     [GNM_SUPPORT], [1],
 208     [Define to 1 if building in support for reading Gnumeric files.])
 209   AC_DEFINE(
 210     [ODF_READ_SUPPORT], [1],
 211     [Define to 1 if building in support for reading OpenDocument files.])
 212 else
 213   GNM_SUPPORT=no
 214   ODF_READ_SUPPORT=no
 215 fi
 216 AC_SUBST([GNM_SUPPORT])
 217 AC_SUBST([ODF_READ_SUPPORT])
 218
 219 dnl ODF support requires libxml2 (zlib is optional).
 220 if test $HAVE_LIBXML2 = yes; then
 221   AC_DEFINE(
 222     [ODF_WRITE_SUPPORT], [1],
 223     [Define to 1 if building in support for writing OpenDocument files.])
 224 fi
 225 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 226
 227 AC_ARG_WITH(
 228   gui_tools,
 229   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 230 if test x"$with_gui_tools" = x"yes" ; then
 231         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 232 fi
 233 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 234
 235 AC_ARG_WITH(
 236   [perl-module],
 237   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 238   [case $with_perl_module in # (
 239      yes|no) ;; # (
 240      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 241    esac
 242    WITH_PERL_MODULE=$with_perl_module],
 243   [if test x"$cross_compiling" != x"yes"; then
 244      WITH_PERL_MODULE=yes
 245    else
 246      WITH_PERL_MODULE=no
 247    fi])
 248 AC_SUBST([WITH_PERL_MODULE])
 249 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 250
 251 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 252 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 253                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 254
 255
 256 PSPP_GSL_NEEDS_FGNU89_INLINE
 257
 258 dnl Recent versions of GNU ncurses install the curses header files into
 259 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 260 dnl enables us to discover where they are. Earlier versions don't have
 261 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 262 dnl we'll trust it to find the right information.  Otherwise, we'll
 263 dnl try to discover it ourselves.
 264 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 265 dnl to ncurses8-config !!!
 266 AC_ARG_WITH(
 267   libncurses,
 268   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 269
 270 if test x"$with_libncurses" != x"no" ; then
 271   if test x"$cross_compiling" != x"yes" ; then
 272           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 273   fi
 274   if test x"$NCURSES_CONFIG" = x ; then
 275           AC_SEARCH_LIBS([tgetent], [ncurses],
 276               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 277   else
 278           old_cflags=$CFLAGS
 279           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 280           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 281           CFLAGS=$old_cflags
 282           if test x"$curses_available" = x"yes" ; then
 283            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 284            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 285            AC_SUBST(NCURSES_CFLAGS)
 286            AC_SUBST(NCURSES_LIBS)
 287           fi
 288   fi
 289   if test x"$curses_available" = x"yes" ; then
 290           AC_DEFINE([LIBNCURSES_USABLE], 1,
 291               [Define to 1 if the libncurses is both present and usable.])
 292   fi
 293   AC_CHECK_HEADERS([termcap.h])
 294 fi
 295
 296 PSPP_READLINE
 297
 298 dnl Checks for header files.
 299 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 300
 301 dnl Some systems dont have SIGWINCH
 302 AC_CHECK_DECLS([SIGWINCH], [], [],
 303           [#include <signal.h>
 304           /* NetBSD declares sys_siglist in unistd.h.  */
 305           #ifdef HAVE_UNISTD_H
 306           # include <unistd.h>
 307           #endif
 308           ])
 309
 310
 311 # For gnulib.
 312 gl_INIT
 313
 314 AC_C_INLINE
 315
 316 AC_CHECK_SIZEOF([size_t])
 317 SIZEOF_SIZE_T=$ac_cv_sizeof_size_t
 318 AC_SUBST([SIZEOF_SIZE_T])
 319
 320 AC_C_BIGENDIAN
 321
 322 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 323
 324 AC_PROG_LN_S
 325
 326 AC_ARG_ENABLE(
 327   debug,
 328   [AS_HELP_STRING([--enable-debug],
 329                   [Turn on diagnostic features in the program])])
 330 if test x"$enable_debug" = x"yes"  ; then
 331   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 332 fi
 333
 334 # iconv is required
 335 AM_ICONV
 336 if test "$am_cv_func_iconv" != "yes"; then
 337    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 338 fi
 339 LIBS="$LIBICONV $LIBS"
 340
 341 dnl Required by the gnulib 'relocatable-prog' module.
 342 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 343 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 344 RELOCATABLE_STRIP=:
 345
 346 PSPP_CHECK_PREREQS
 347
 348 AC_CONFIG_FILES(
 349   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 350
 351 AC_OUTPUT
 352 echo "PSPP configured successfully."
 353
 354 dnl configure.ac ends here