pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017, 2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.5.3], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 if test x"$cross_compiling" = x"yes"; then
  32    if test x"$srcdir" = x"."; then
  33       AC_ERROR([Cross compiling must be done out of source.])
  34    fi
  35 fi
  36
  37 AM_PROG_CC_C_O
  38 AC_LIBTOOL_WIN32_DLL
  39 AC_LIBTOOL_DLOPEN
  40 AC_PROG_LIBTOOL
  41 AC_HEADER_TIOCGWINSZ
  42 PKG_PROG_PKG_CONFIG
  43 m4_pattern_forbid([PKG_CHECK_MODULES])
  44 PSPP_CHECK_CLICKSEQUENCE
  45 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  46 PSPP_CHECK_DOT
  47
  48 PSPP_ENABLE_WERROR
  49
  50 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  51 AM_CONDITIONAL(host_is_w32, [case $host_os in mingw*) true;; *) false;; esac] )
  52
  53 PSPP_PERL
  54 PSPP_PYTHON
  55 AC_CHECK_PROGS([TEX], [tex], [no])
  56 AC_SUBST([TEX])
  57 AC_CHECK_PROGS([GWC], [gwc wc], [no])
  58 AC_SUBST([GWC])
  59
  60 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  61 # avoided in GCC 10.x:
  62 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  63 #   cc1: error: function may return address of local variable
  64 CFLAGS="$CFLAGS -DGCC_LINT"
  65
  66 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  67 AC_PROVIDE([AM_PO_SUBDIRS])
  68 AM_GNU_GETTEXT([external], [need-ngettext])
  69
  70 LIBS="$LIBINTL $LIBS"
  71 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  72 if test "x$MSGFMT" = x; then
  73   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  74 fi
  75
  76 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  77 if test "x$XGETTEXT" = x; then
  78   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  79 fi
  80
  81 PSPP_CHECK_XGETTEXT
  82
  83 if test "$pspp_cv_progrecent_xgettext"  != "yes"; then
  84    PSPP_REQUIRED_PREREQ([xgettext version 0.20 or greater])
  85 fi
  86
  87 dnl Checks for libraries.
  88 AC_SYS_LARGEFILE
  89 AC_SEARCH_LIBS([sin], [m])
  90 PSPP_LC_PAPER
  91
  92
  93 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  94 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  95
  96 # Support for Cairo and Pango.
  97 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  98   [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"],
  99   [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later])])
 100
 101 dnl One of the tests uses xmllint.
 102 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 103 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 104   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 105     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 106     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 107    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 108
 109 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 110
 111 # Support for GUI.
 112 AC_ARG_WITH([gui],
 113   [AS_HELP_STRING([--without-gui],
 114                   [Don't build the PSPPIRE GUI (using GTK+)])],
 115   [], [with_gui=yes])
 116 AM_CONDITIONAL([building_gui], [test "$with_gui" != "no"])
 117 if test "$with_gui" != "no"; then
 118   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 119     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 120
 121   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 122     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 123
 124   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 125     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 126
 127   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 128     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 129
 130   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 131     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 132   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 133
 134   AC_ARG_VAR([GLIB_GENMARSHAL])
 135   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 136   if test "x$GLIB_GENMARSHAL" = x; then
 137     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 138   fi
 139
 140   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 141   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 142     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 143   fi
 144
 145 fi
 146
 147 gl_NEXT_HEADERS([gtk/gtk.h])
 148
 149 dnl Checks needed for psql reader
 150
 151 dnl The 8.x series postgres tarballs installs with a default prefix of
 152 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 153
 154 dnl If the libpq.so file is in a non standard path, (one which the linker
 155 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 156 dnl However, if the system happens to have more than one version of other
 157 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 158 dnl /usr and /usr/local) then the wrong one may get linked.
 159
 160 dnl To overcome this, we first check for libpq in the standard places, and
 161 dnl only set PG_LDFLAGS if it's not found.
 162
 163
 164 AC_ARG_WITH(
 165   libpq,
 166   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 167 AC_ARG_VAR([PG_CONFIG],
 168            [Full pathname of the pg_config program shipped with Postgresql])
 169 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 170              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 171
 172 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 173   AC_SUBST(PG_CONFIG)
 174   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 175   AC_SUBST(PG_CFLAGS)
 176
 177   AC_CHECK_LIB([pq], [PQexec],
 178      [:],
 179      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 180   AC_SUBST(PG_LDFLAGS)
 181
 182   PG_LIBS=-lpq
 183   AC_SUBST(PG_LIBS)
 184
 185   PKG_CHECK_EXISTS(libssl,
 186         AC_DEFINE([USE_SSL],1,
 187                    [Define to 1 if the openssl library is present.])
 188            ,)
 189
 190   # Now verify that we can actually link against libpq.  If we are
 191   # cross-compiling and picked up a host libpq, or if libpq is just
 192   # badly installed, this will fail.
 193   AC_CACHE_CHECK(
 194     [whether -lpq links successfully],
 195     [pspp_cv_have_libpq],
 196     [save_CPPFLAGS=$CPPFLAGS
 197      save_LIBS=$LIBS
 198      save_LDFLAGS=$LDFLAGS
 199      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 200      LIBS="$PG_LIBS $LIBS"
 201      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 202      AC_LINK_IFELSE(
 203        [AC_LANG_PROGRAM(
 204          [#include <libpq-fe.h>
 205          ], [PQfinish (0);])],
 206        [pspp_cv_have_libpq=yes],
 207        [pspp_cv_have_libpq=no])
 208      CPPFLAGS=$save_CPPFLAGS
 209      LIBS=$save_LIBS
 210      LDFLAGS=$save_LDFLAGS])
 211
 212   if test $pspp_cv_have_libpq = yes; then
 213     PSQL_SUPPORT=yes
 214     AC_DEFINE([PSQL_SUPPORT], [1],
 215       [Define to 1 if building in support for reading from postgres
 216        databases.])
 217   else
 218     PSQL_SUPPORT=no
 219     PG_CONFIG=
 220     PG_CFLAGS=
 221     PG_LDFLAGS=
 222     PG_LIBS=
 223   fi
 224 else
 225   PSQL_SUPPORT=no
 226   pspp_cv_have_libpq=no
 227 fi
 228 AC_SUBST([PSQL_SUPPORT])
 229
 230 dnl Check for libxml2
 231 PKG_CHECK_MODULES(
 232   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 233
 234 dnl Check for zlib.
 235 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 236 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 237
 238 dnl Avoid interference between zlib's crc32() function and gnulib's
 239 dnl crc32() function, which have different signatures.  PSPP calls
 240 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 241 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 242 dnl crc32(), then zlib will call gnulib's version instead of its own,
 243 dnl causing failures.  (This can happen even if zlib isn't detected
 244 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 245 dnl sometimes use zlib themselves.)
 246 AC_DEFINE(
 247   [crc32], [gl_crc32],
 248   [Avoid making zlib call gnulib's crc32() instead of its own.])
 249
 250 AC_ARG_WITH(
 251   [perl-module],
 252   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 253   [case $with_perl_module in # (
 254      yes|no) ;; # (
 255      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 256    esac
 257    WITH_PERL_MODULE=$with_perl_module],
 258   [if test x"$cross_compiling" != x"yes"; then
 259      WITH_PERL_MODULE=yes
 260    else
 261      WITH_PERL_MODULE=no
 262    fi])
 263 AC_SUBST([WITH_PERL_MODULE])
 264 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 265
 266 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 267 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 268                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 269
 270
 271 PSPP_GSL_NEEDS_FGNU89_INLINE
 272
 273 PSPP_READLINE
 274
 275 dnl Checks for header files.
 276 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 277
 278 dnl Some systems don't have SIGWINCH
 279 AC_CHECK_DECLS([SIGWINCH], [], [],
 280           [#include <signal.h>
 281           /* NetBSD declares sys_siglist in unistd.h.  */
 282           #ifdef HAVE_UNISTD_H
 283           # include <unistd.h>
 284           #endif
 285           ])
 286
 287
 288 # For gnulib.
 289 gl_INIT
 290
 291 AC_C_INLINE
 292
 293 AC_C_BIGENDIAN
 294
 295 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 296
 297 AC_PROG_LN_S
 298
 299 # iconv is required
 300 AM_ICONV
 301 if test "$am_cv_func_iconv" != "yes"; then
 302    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 303 fi
 304 LIBS="$LIBICONV $LIBS"
 305
 306 dnl Required by the gnulib 'relocatable-prog' module.
 307 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 308 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 309 RELOCATABLE_STRIP=:
 310
 311 PSPP_CHECK_PREREQS
 312
 313 dnl The makefile needs to know if we're cross compiling, so that
 314 dnl it can make arrangements to build the documentation examples.
 315 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 316
 317 AC_CONFIG_FILES(
 318   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 319
 320 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 321
 322 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 323
 324 AC_OUTPUT
 325 echo "PSPP configured successfully."
 326
 327 dnl configure.ac ends here