pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.5], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Internationalization macros.
  36 AC_PROVIDE([AM_PO_SUBDIRS])     # PSPP provides its own po/ support.
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 AM_GNU_GETTEXT_VERSION([0.17])
  39 if test -n "$LIBINTL"; then
  40   AC_DEFINE([DEPENDS_ON_LIBINTL], [1],
  41     [Define to 1 if libintl is a separate library, not integrated into libc])
  42 fi
  43
  44 dnl Checks for libraries.
  45 AC_SYS_LARGEFILE
  46 AC_SEARCH_LIBS([sin], [m])
  47 AC_SEARCH_LIBS([dcgettext], [intl])
  48 PSPP_LC_PAPER
  49
  50
  51 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  52 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  53
  54 # Support for Cairo and Pango.
  55 AC_ARG_WITH([cairo],
  56   [AS_HELP_STRING(
  57     [--without-cairo],
  58     [Don't build support for charts (using Cairo and Pango);
  59      implies --without-gui])],
  60   [], [with_cairo=yes])
  61 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  62 if test "$with_cairo" != no; then
  63   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  64     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  65      AC_DEFINE([HAVE_CAIRO], 1,
  66        [Define to 1 if Cairo and Pango are available.])],
  67     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  68   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  69   AC_SUBST(XMLLINT)
  70 fi
  71
  72 # Support for GUI.
  73 AC_ARG_WITH([gui],
  74   [AS_HELP_STRING([--without-gui],
  75                   [Don't build the PSPPIRE GUI (using GTK+)])],
  76   [], [with_gui=yes])
  77 AM_CONDITIONAL([HAVE_GUI],
  78                [test "$with_cairo" != no && test "$with_gui" != "no"])
  79 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  80   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  81     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  82
  83   AC_ARG_VAR([GLIB_GENMARSHAL])
  84   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  85   if test "x$GLIB_GENMARSHAL" = x; then
  86     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  87   fi
  88 fi
  89
  90 dnl Checks needed for psql reader
  91
  92 dnl The 8.x series postgres tarballs installs with a default prefix of
  93 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  94
  95 dnl If the libpq.so file is in a non standard path, (one which the linker
  96 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  97 dnl However, if the system happens to have more than one version of other
  98 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  99 dnl /usr and /usr/local) then the wrong one may get linked.
 100
 101 dnl To overcome this, we first check for libpq in the standard places, and
 102 dnl only set PG_LDFLAGS if it's not found.
 103
 104
 105 AC_ARG_WITH(
 106   libpq,
 107   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 108 AC_ARG_VAR([PG_CONFIG],
 109            [Full pathname of the pg_config program shipped with Postgresql])
 110 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 111              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 112
 113 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 114   AC_SUBST(PG_CONFIG)
 115   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 116   AC_SUBST(PG_CFLAGS)
 117
 118   AC_CHECK_LIB([pq], [PQexec],
 119      [:],
 120      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 121   AC_SUBST(PG_LDFLAGS)
 122
 123   PG_LIBS=-lpq
 124   AC_SUBST(PG_LIBS)
 125
 126   PKG_CHECK_EXISTS(libssl,
 127         AC_DEFINE([USE_SSL],1,
 128                    [Define to 1 if the openssl library is present.])
 129            ,)
 130
 131   # Now verify that we can actually link against libpq.  If we are
 132   # cross-compiling and picked up a host libpq, or if libpq is just
 133   # badly installed, this will fail.
 134   AC_CACHE_CHECK(
 135     [whether -lpq links successfully],
 136     [pspp_cv_have_libpq],
 137     [save_CPPFLAGS=$CPPFLAGS
 138      save_LIBS=$LIBS
 139      save_LDFLAGS=$LDFLAGS
 140      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 141      LIBS="$PG_LIBS $LIBS"
 142      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 143      AC_LINK_IFELSE(
 144        [AC_LANG_PROGRAM(
 145          [#include <libpq-fe.h>
 146          ], [PQfinish (0);])],
 147        [pspp_cv_have_libpq=yes],
 148        [pspp_cv_have_libpq=no])
 149      CPPFLAGS=$save_CPPFLAGS
 150      LIBS=$save_LIBS
 151      LDFLAGS=$save_LDFLAGS])
 152
 153   if test $pspp_cv_have_libpq = yes; then
 154     AC_DEFINE([PSQL_SUPPORT], [1],
 155       [Define to 1 if building in support for reading from postgres
 156        databases.])
 157   else
 158     PG_CONFIG=
 159     PG_CFLAGS=
 160     PG_LDFLAGS=
 161     PG_LIBS=
 162   fi
 163 else
 164   pspp_cv_have_libpq=no
 165 fi
 166 AM_CONDITIONAL(PSQL_SUPPORT, test $pspp_cv_have_libpq = yes)
 167
 168 dnl Check for libxml2
 169 PKG_CHECK_MODULES(
 170   [LIBXML2], [libxml-2.0],
 171   [HAVE_LIBXML2=yes],
 172   [HAVE_LIBXML2=no
 173    PSPP_OPTIONAL_PREREQ([libxml2])])
 174
 175 dnl Check for zlib.
 176 AC_SEARCH_LIBS(
 177   [gzopen], [z],
 178   [HAVE_ZLIB=yes],
 179   [HAVE_ZLIB=no
 180    PSPP_OPTIONAL_PREREQ([zlib])])
 181 AC_CHECK_HEADERS(
 182   [zlib.h],
 183   [],
 184   [HAVE_ZLIB=no
 185    PSPP_OPTIONAL_PREREQ([zlib])])
 186
 187 dnl Avoid interference between zlib's crc32() function and gnulib's
 188 dnl crc32() function, which have different signatures.  PSPP calls
 189 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 190 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 191 dnl crc32(), then zlib will call gnulib's version instead of its own,
 192 dnl causing failures.  (This can happen even if zlib isn't detected
 193 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 194 dnl sometimes use zlib themselves.)
 195 AC_DEFINE(
 196   [crc32], [gl_crc32],
 197   [Avoid making zlib call gnulib's crc32() instead of its own.])
 198
 199 dnl Gnumeric support requires libxml2 and zlib.
 200 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 201   GNM_SUPPORT=yes
 202   AC_DEFINE(
 203     [GNM_SUPPORT], [1],
 204     [Define to 1 if building in support for reading Gnumeric files.])
 205 else
 206   GNM_SUPPORT=no
 207 fi
 208 AM_CONDITIONAL([GNM_SUPPORT], [test $GNM_SUPPORT = yes])
 209
 210 dnl ODT support requires libxml2.
 211 if test $HAVE_LIBXML2 = yes; then
 212   AC_DEFINE(
 213     [ODT_SUPPORT], [1],
 214     [Define to 1 if building in support for writing ODT files.])
 215 fi
 216 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 217
 218 AC_ARG_WITH(
 219   gui_tools,
 220   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 221 if test x"$with_gui_tools" = x"yes" ; then
 222         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 223 fi
 224 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 225
 226 AC_ARG_WITH(
 227   [perl-module],
 228   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 229   [case $with_perl_module in # (
 230      yes|no) ;; # (
 231      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 232    esac
 233    WITH_PERL_MODULE=$with_perl_module],
 234   [if test x"$cross_compiling" != x"yes"; then
 235      WITH_PERL_MODULE=yes
 236    else
 237      WITH_PERL_MODULE=no
 238    fi])
 239 AC_SUBST([WITH_PERL_MODULE])
 240 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 241
 242 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 243 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [], [PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])])
 244
 245 PSPP_GSL_NEEDS_FGNU89_INLINE
 246
 247 dnl Recent versions of GNU ncurses install the curses header files into
 248 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 249 dnl enables us to discover where they are. Earlier versions don't have
 250 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 251 dnl we'll trust it to find the right information.  Otherwise, we'll
 252 dnl try to discover it ourselves.
 253 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 254 dnl to ncurses8-config !!!
 255 AC_ARG_WITH(
 256   libncurses,
 257   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 258
 259 if test x"$with_libncurses" != x"no" ; then
 260   if test x"$cross_compiling" != x"yes" ; then
 261           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 262   fi
 263   if test x"$NCURSES_CONFIG" = x ; then
 264           AC_SEARCH_LIBS([tgetent], [ncurses],
 265               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 266   else
 267           old_cflags=$CFLAGS
 268           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 269           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 270           CFLAGS=$old_cflags
 271           if test x"$curses_available" = x"yes" ; then
 272            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 273            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 274            AC_SUBST(NCURSES_CFLAGS)
 275            AC_SUBST(NCURSES_LIBS)
 276           fi
 277   fi
 278   if test x"$curses_available" = x"yes" ; then
 279           AC_DEFINE([LIBNCURSES_USABLE], 1,
 280               [Define to 1 if the libncurses is both present and usable.])
 281   fi
 282   AC_CHECK_HEADERS([termcap.h])
 283 fi
 284
 285 PSPP_READLINE
 286
 287 dnl Checks for header files.
 288 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 289
 290 # For gnulib.
 291 gl_INIT
 292
 293 AC_C_INLINE
 294
 295 AC_CHECK_SIZEOF(double)
 296
 297 AC_C_BIGENDIAN
 298
 299 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 300
 301 AC_PROG_LN_S
 302
 303 AC_ARG_ENABLE(
 304   debug,
 305   [AS_HELP_STRING([--enable-debug],
 306                   [Turn on diagnostic features in the program])])
 307 if test x"$enable_debug" = x"yes"  ; then
 308   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 309 fi
 310
 311 # iconv is required
 312 if test "$am_cv_func_iconv" != "yes"; then
 313    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 314 fi
 315
 316 dnl Required by the gnulib 'relocatable-prog' module.
 317 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 318 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 319 RELOCATABLE_STRIP=:
 320
 321 PSPP_CHECK_PREREQS
 322
 323 AC_CONFIG_FILES(
 324   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 325
 326 AC_OUTPUT
 327 echo "PSPP configured successfully."
 328
 329 dnl configure.ac ends here