pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.6], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Internationalization macros.
  36 AC_PROVIDE([AM_PO_SUBDIRS])     # PSPP provides its own po/ support.
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 AM_GNU_GETTEXT_VERSION([0.17])
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  77     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  78
  79   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  80     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  81
  82   AC_ARG_VAR([GLIB_GENMARSHAL])
  83   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  84   if test "x$GLIB_GENMARSHAL" = x; then
  85     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  86   fi
  87 fi
  88
  89 dnl Checks needed for psql reader
  90
  91 dnl The 8.x series postgres tarballs installs with a default prefix of
  92 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  93
  94 dnl If the libpq.so file is in a non standard path, (one which the linker
  95 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  96 dnl However, if the system happens to have more than one version of other
  97 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  98 dnl /usr and /usr/local) then the wrong one may get linked.
  99
 100 dnl To overcome this, we first check for libpq in the standard places, and
 101 dnl only set PG_LDFLAGS if it's not found.
 102
 103
 104 AC_ARG_WITH(
 105   libpq,
 106   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 107 AC_ARG_VAR([PG_CONFIG],
 108            [Full pathname of the pg_config program shipped with Postgresql])
 109 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 110              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 111
 112 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 113   AC_SUBST(PG_CONFIG)
 114   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 115   AC_SUBST(PG_CFLAGS)
 116
 117   AC_CHECK_LIB([pq], [PQexec],
 118      [:],
 119      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 120   AC_SUBST(PG_LDFLAGS)
 121
 122   PG_LIBS=-lpq
 123   AC_SUBST(PG_LIBS)
 124
 125   PKG_CHECK_EXISTS(libssl,
 126         AC_DEFINE([USE_SSL],1,
 127                    [Define to 1 if the openssl library is present.])
 128            ,)
 129
 130   # Now verify that we can actually link against libpq.  If we are
 131   # cross-compiling and picked up a host libpq, or if libpq is just
 132   # badly installed, this will fail.
 133   AC_CACHE_CHECK(
 134     [whether -lpq links successfully],
 135     [pspp_cv_have_libpq],
 136     [save_CPPFLAGS=$CPPFLAGS
 137      save_LIBS=$LIBS
 138      save_LDFLAGS=$LDFLAGS
 139      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 140      LIBS="$PG_LIBS $LIBS"
 141      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 142      AC_LINK_IFELSE(
 143        [AC_LANG_PROGRAM(
 144          [#include <libpq-fe.h>
 145          ], [PQfinish (0);])],
 146        [pspp_cv_have_libpq=yes],
 147        [pspp_cv_have_libpq=no])
 148      CPPFLAGS=$save_CPPFLAGS
 149      LIBS=$save_LIBS
 150      LDFLAGS=$save_LDFLAGS])
 151
 152   if test $pspp_cv_have_libpq = yes; then
 153     PSQL_SUPPORT=yes
 154     AC_DEFINE([PSQL_SUPPORT], [1],
 155       [Define to 1 if building in support for reading from postgres
 156        databases.])
 157   else
 158     PSQL_SUPPORT=no
 159     PG_CONFIG=
 160     PG_CFLAGS=
 161     PG_LDFLAGS=
 162     PG_LIBS=
 163   fi
 164 else
 165   PSQL_SUPPORT=no
 166   pspp_cv_have_libpq=no
 167 fi
 168 AC_SUBST([PSQL_SUPPORT])
 169
 170 dnl Check for libxml2
 171 PKG_CHECK_MODULES(
 172   [LIBXML2], [libxml-2.0],
 173   [HAVE_LIBXML2=yes],
 174   [HAVE_LIBXML2=no
 175    PSPP_OPTIONAL_PREREQ([libxml2])])
 176
 177 dnl Check for zlib.
 178 AC_SEARCH_LIBS(
 179   [gzopen], [z],
 180   [HAVE_ZLIB=yes],
 181   [HAVE_ZLIB=no
 182    PSPP_OPTIONAL_PREREQ([zlib])])
 183 AC_CHECK_HEADERS(
 184   [zlib.h],
 185   [],
 186   [HAVE_ZLIB=no
 187    PSPP_OPTIONAL_PREREQ([zlib])])
 188
 189 dnl Avoid interference between zlib's crc32() function and gnulib's
 190 dnl crc32() function, which have different signatures.  PSPP calls
 191 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 192 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 193 dnl crc32(), then zlib will call gnulib's version instead of its own,
 194 dnl causing failures.  (This can happen even if zlib isn't detected
 195 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 196 dnl sometimes use zlib themselves.)
 197 AC_DEFINE(
 198   [crc32], [gl_crc32],
 199   [Avoid making zlib call gnulib's crc32() instead of its own.])
 200
 201 dnl Gnumeric support requires libxml2 and zlib.
 202 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 203   GNM_SUPPORT=yes
 204   AC_DEFINE(
 205     [GNM_SUPPORT], [1],
 206     [Define to 1 if building in support for reading Gnumeric files.])
 207 else
 208   GNM_SUPPORT=no
 209 fi
 210 AC_SUBST([GNM_SUPPORT])
 211
 212 dnl ODT support requires libxml2.
 213 if test $HAVE_LIBXML2 = yes; then
 214   AC_DEFINE(
 215     [ODT_SUPPORT], [1],
 216     [Define to 1 if building in support for writing ODT files.])
 217 fi
 218 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 219
 220 AC_ARG_WITH(
 221   gui_tools,
 222   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 223 if test x"$with_gui_tools" = x"yes" ; then
 224         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 225 fi
 226 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 227
 228 AC_ARG_WITH(
 229   [perl-module],
 230   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 231   [case $with_perl_module in # (
 232      yes|no) ;; # (
 233      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 234    esac
 235    WITH_PERL_MODULE=$with_perl_module],
 236   [if test x"$cross_compiling" != x"yes"; then
 237      WITH_PERL_MODULE=yes
 238    else
 239      WITH_PERL_MODULE=no
 240    fi])
 241 AC_SUBST([WITH_PERL_MODULE])
 242 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 243
 244 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 245 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 246                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 247
 248
 249 PSPP_GSL_NEEDS_FGNU89_INLINE
 250
 251 dnl Recent versions of GNU ncurses install the curses header files into
 252 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 253 dnl enables us to discover where they are. Earlier versions don't have
 254 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 255 dnl we'll trust it to find the right information.  Otherwise, we'll
 256 dnl try to discover it ourselves.
 257 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 258 dnl to ncurses8-config !!!
 259 AC_ARG_WITH(
 260   libncurses,
 261   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 262
 263 if test x"$with_libncurses" != x"no" ; then
 264   if test x"$cross_compiling" != x"yes" ; then
 265           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 266   fi
 267   if test x"$NCURSES_CONFIG" = x ; then
 268           AC_SEARCH_LIBS([tgetent], [ncurses],
 269               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 270   else
 271           old_cflags=$CFLAGS
 272           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 273           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 274           CFLAGS=$old_cflags
 275           if test x"$curses_available" = x"yes" ; then
 276            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 277            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 278            AC_SUBST(NCURSES_CFLAGS)
 279            AC_SUBST(NCURSES_LIBS)
 280           fi
 281   fi
 282   if test x"$curses_available" = x"yes" ; then
 283           AC_DEFINE([LIBNCURSES_USABLE], 1,
 284               [Define to 1 if the libncurses is both present and usable.])
 285   fi
 286   AC_CHECK_HEADERS([termcap.h])
 287 fi
 288
 289 PSPP_READLINE
 290
 291 dnl Checks for header files.
 292 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 293
 294 # For gnulib.
 295 gl_INIT
 296
 297 AC_C_INLINE
 298
 299 AC_CHECK_SIZEOF(double)
 300
 301 AC_C_BIGENDIAN
 302
 303 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 304
 305 AC_PROG_LN_S
 306
 307 AC_ARG_ENABLE(
 308   debug,
 309   [AS_HELP_STRING([--enable-debug],
 310                   [Turn on diagnostic features in the program])])
 311 if test x"$enable_debug" = x"yes"  ; then
 312   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 313 fi
 314
 315 # iconv is required
 316 if test "$am_cv_func_iconv" != "yes"; then
 317    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 318 fi
 319
 320 dnl Required by the gnulib 'relocatable-prog' module.
 321 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 322 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 323 RELOCATABLE_STRIP=:
 324
 325 PSPP_CHECK_PREREQS
 326
 327 AC_CONFIG_FILES(
 328   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 329
 330 AC_OUTPUT
 331 echo "PSPP configured successfully."
 332
 333 dnl configure.ac ends here