pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.3],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  77     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  78 fi
  79
  80 dnl Checks needed for psql reader
  81
  82 dnl The 8.x series postgres tarballs installs with a default prefix of
  83 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  84
  85 dnl If the libpq.so file is in a non standard path, (one which the linker
  86 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  87 dnl However, if the system happens to have more than one version of other
  88 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  89 dnl /usr and /usr/local) then the wrong one may get linked.
  90
  91 dnl To overcome this, we first check for libpq in the standard places, and
  92 dnl only set PG_LDFLAGS if it's not found.
  93
  94
  95 AC_ARG_WITH(
  96   libpq,
  97   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  98
  99 if test x"$with_libpq" != x"no" ; then
 100  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
 101
 102  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
 103  if test x"$cross_compiling" != x"yes" ; then
 104    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 105  fi
 106  if test -n "$PG_CONFIG" ; then
 107    AC_SUBST(PG_CONFIG)
 108    AC_DEFINE([PSQL_SUPPORT], 1,
 109    [Define to 1 if building in support for reading from postgres databases.])
 110    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 111    AC_SUBST(PG_CFLAGS)
 112
 113    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 114       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 115    fi
 116    AC_SUBST(PG_LDFLAGS)
 117
 118    PG_LIBS=-lpq
 119    AC_SUBST(PG_LIBS)
 120    PKG_CHECK_EXISTS(libssl,
 121          AC_DEFINE([USE_SSL],1,
 122                     [Define to 1 if the openssl library is present.])
 123             ,)
 124  fi
 125 fi
 126 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 127
 128 dnl Checks needed for Gnumeric reader
 129 gnm_support=yes;
 130 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 131                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 132 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 133 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 134
 135 if test x"$gnm_support" = x"yes" ; then
 136    AC_DEFINE([GNM_SUPPORT], 1,
 137    [Define to 1 if building in support for reading Gnumeric files.])
 138 fi
 139 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 140
 141 AC_ARG_WITH(
 142   gui_tools,
 143   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 144 if test x"$with_gui_tools" = x"yes" ; then
 145         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 146 fi
 147 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 148
 149 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 150
 151 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 152 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 153 PSPP_GSL_NEEDS_FGNU89_INLINE
 154
 155 dnl Recent versions of GNU ncurses install the curses header files into
 156 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 157 dnl enables us to discover where they are. Earlier versions don't have
 158 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 159 dnl we'll trust it to find the right information.  Otherwise, we'll
 160 dnl try to discover it ourselves.
 161 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 162 dnl to ncurses8-config !!!
 163 AC_ARG_WITH(
 164   libncurses,
 165   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 166
 167 if test x"$with_libncurses" != x"no" ; then
 168   if test x"$cross_compiling" != x"yes" ; then
 169           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 170   fi
 171   if test x"$NCURSES_CONFIG" = x ; then
 172           AC_SEARCH_LIBS([tgetent], [ncurses],
 173               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 174   else
 175           old_cflags=$CFLAGS
 176           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 177           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 178           CFLAGS=$old_cflags
 179           if test x"$curses_available" = x"yes" ; then
 180            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 181            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 182            AC_SUBST(NCURSES_CFLAGS)
 183            AC_SUBST(NCURSES_LIBS)
 184           fi
 185   fi
 186   if test x"$curses_available" = x"yes" ; then
 187           AC_DEFINE([LIBNCURSES_USABLE], 1,
 188               [Define to 1 if the libncurses is both present and usable.])
 189   fi
 190   AC_CHECK_HEADERS([termcap.h])
 191 fi
 192
 193 PSPP_READLINE
 194
 195 dnl Checks for header files.
 196 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 197
 198 # For gnulib.
 199 gl_INIT
 200
 201 AC_C_INLINE
 202
 203 AC_CHECK_SIZEOF(double)
 204
 205 AC_C_BIGENDIAN
 206
 207 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 208
 209 AC_PROG_LN_S
 210
 211 AC_ARG_ENABLE(
 212   debug,
 213   [AS_HELP_STRING([--enable-debug],
 214                   [Turn on diagnostic features in the program])])
 215 if test x"$enable_debug" = x"yes"  ; then
 216   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 217 fi
 218
 219 # iconv is required
 220 if test "$am_cv_func_iconv" != "yes"; then
 221    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 222 fi
 223
 224 dnl Required by the gnulib 'relocatable-prog' module.
 225 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 226 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 227 RELOCATABLE_STRIP=:
 228
 229 PSPP_CHECK_PREREQS
 230
 231 AC_CONFIG_FILES([Makefile gl/Makefile])
 232
 233 AC_OUTPUT
 234 echo "PSPP configured successfully."
 235
 236 dnl configure.ac ends here