pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.3],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64 fi
  65
  66 # Support for GUI.
  67 AC_ARG_WITH([gui],
  68   [AS_HELP_STRING([--without-gui],
  69                   [Don't build the PSPPIRE GUI (using GTK+)])],
  70   [], [with_gui=yes])
  71 AM_CONDITIONAL([HAVE_GUI],
  72                [test "$with_cairo" != no && test "$with_gui" != "no"])
  73 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  74   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  75     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  76 fi
  77
  78 dnl Checks needed for psql reader
  79
  80 dnl The 8.x series postgres tarballs installs with a default prefix of
  81 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  82
  83 dnl If the libpq.so file is in a non standard path, (one which the linker
  84 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  85 dnl However, if the system happens to have more than one version of other
  86 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  87 dnl /usr and /usr/local) then the wrong one may get linked.
  88
  89 dnl To overcome this, we first check for libpq in the standard places, and
  90 dnl only set PG_LDFLAGS if it's not found.
  91
  92
  93 AC_ARG_WITH(
  94   libpq,
  95   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  96
  97 if test x"$with_libpq" != x"no" ; then
  98  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  99
 100  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
 101  if test x"$cross_compiling" != x"yes" ; then
 102    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 103  fi
 104  if test -n "$PG_CONFIG" ; then
 105    AC_SUBST(PG_CONFIG)
 106    AC_DEFINE([PSQL_SUPPORT], 1,
 107    [Define to 1 if building in support for reading from postgres databases.])
 108    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 109    AC_SUBST(PG_CFLAGS)
 110
 111    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 112       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 113    fi
 114    AC_SUBST(PG_LDFLAGS)
 115
 116    PG_LIBS=-lpq
 117    AC_SUBST(PG_LIBS)
 118    PKG_CHECK_EXISTS(libssl,
 119          AC_DEFINE([USE_SSL],1,
 120                     [Define to 1 if the openssl library is present.])
 121             ,)
 122  fi
 123 fi
 124 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 125
 126 dnl Checks needed for Gnumeric reader
 127 gnm_support=yes;
 128 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 129                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 130 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 131 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 132
 133 if test x"$gnm_support" = x"yes" ; then
 134    AC_DEFINE([GNM_SUPPORT], 1,
 135    [Define to 1 if building in support for reading Gnumeric files.])
 136 fi
 137 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 138
 139 AC_ARG_WITH(
 140   gui_tools,
 141   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 142 if test x"$with_gui_tools" = x"yes" ; then
 143         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 144 fi
 145 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 146
 147 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 148
 149 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 150 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 151 PSPP_GSL_NEEDS_FGNU89_INLINE
 152
 153 dnl Recent versions of GNU ncurses install the curses header files into
 154 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 155 dnl enables us to discover where they are. Earlier versions don't have
 156 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 157 dnl we'll trust it to find the right information.  Otherwise, we'll
 158 dnl try to discover it ourselves.
 159 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 160 dnl to ncurses8-config !!!
 161 AC_ARG_WITH(
 162   libncurses,
 163   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 164
 165 if test x"$with_libncurses" != x"no" ; then
 166   if test x"$cross_compiling" != x"yes" ; then
 167           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 168   fi
 169   if test x"$NCURSES_CONFIG" = x ; then
 170           AC_SEARCH_LIBS([tgetent], [ncurses],
 171               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 172   else
 173           old_cflags=$CFLAGS
 174           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 175           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 176           CFLAGS=$old_cflags
 177           if test x"$curses_available" = x"yes" ; then
 178            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 179            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 180            AC_SUBST(NCURSES_CFLAGS)
 181            AC_SUBST(NCURSES_LIBS)
 182           fi
 183   fi
 184   if test x"$curses_available" = x"yes" ; then
 185           AC_DEFINE([LIBNCURSES_USABLE], 1,
 186               [Define to 1 if the libncurses is both present and usable.])
 187   fi
 188   AC_CHECK_HEADERS([termcap.h])
 189 fi
 190
 191 PSPP_READLINE
 192
 193 dnl Checks for header files.
 194 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 195
 196 # For gnulib.
 197 gl_INIT
 198
 199 AC_C_INLINE
 200
 201 AC_CHECK_SIZEOF(double)
 202
 203 AC_C_BIGENDIAN
 204
 205 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 206
 207 AC_PROG_LN_S
 208
 209 AC_ARG_ENABLE(
 210   debug,
 211   [AS_HELP_STRING([--enable-debug],
 212                   [Turn on diagnostic features in the program])])
 213 if test x"$enable_debug" = x"yes"  ; then
 214   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 215 fi
 216
 217 # iconv is required
 218 if test "$am_cv_func_iconv" != "yes"; then
 219    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 220 fi
 221
 222 dnl Required by the gnulib 'relocatable-prog' module.
 223 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 224 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 225 RELOCATABLE_STRIP=:
 226
 227 PSPP_CHECK_PREREQS
 228
 229 AC_CONFIG_FILES([Makefile gl/Makefile])
 230
 231 AC_OUTPUT
 232 echo "PSPP configured successfully."
 233
 234 dnl configure.ac ends here