pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.3],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LC_PAPER
  40
  41
  42 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  43 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  44
  45 # Support for Cairo and Pango.
  46 AC_ARG_WITH([cairo],
  47   [AS_HELP_STRING(
  48     [--without-cairo],
  49     [Don't build support for charts (using Cairo and Pango);
  50      implies --without-gui])],
  51   [], [with_cairo=yes])
  52 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  53 if test "$with_cairo" != no; then
  54   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  55     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  56      AC_DEFINE([HAVE_CAIRO], 1,
  57        [Define to 1 if Cairo and Pango are available.])],
  58     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  59 fi
  60
  61 # Support for GUI.
  62 AC_ARG_WITH([gui],
  63   [AS_HELP_STRING([--without-gui],
  64                   [Don't build the PSPPIRE GUI (using GTK+)])],
  65   [], [with_gui=yes])
  66 AM_CONDITIONAL([HAVE_GUI],
  67                [test "$with_cairo" != no && test "$with_gui" != "no"])
  68 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  69   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  70     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  71 fi
  72
  73 dnl Checks needed for psql reader
  74
  75 dnl The 8.x series postgres tarballs installs with a default prefix of
  76 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  77
  78 dnl If the libpq.so file is in a non standard path, (one which the linker
  79 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  80 dnl However, if the system happens to have more than one version of other
  81 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  82 dnl /usr and /usr/local) then the wrong one may get linked.
  83
  84 dnl To overcome this, we first check for libpq in the standard places, and
  85 dnl only set PG_LDFLAGS if it's not found.
  86
  87
  88 AC_ARG_WITH(
  89   libpq,
  90   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  91
  92 if test x"$with_libpq" != x"no" ; then
  93  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  94
  95  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  96  if test x"$cross_compiling" != x"yes" ; then
  97    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  98  fi
  99  if test -n "$PG_CONFIG" ; then
 100    AC_SUBST(PG_CONFIG)
 101    AC_DEFINE([PSQL_SUPPORT], 1,
 102    [Define to 1 if building in support for reading from postgres databases.])
 103    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 104    AC_SUBST(PG_CFLAGS)
 105
 106    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 107       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 108    fi
 109    AC_SUBST(PG_LDFLAGS)
 110
 111    PG_LIBS=-lpq
 112    AC_SUBST(PG_LIBS)
 113    PKG_CHECK_EXISTS(libssl,
 114          AC_DEFINE([USE_SSL],1,
 115                     [Define to 1 if the openssl library is present.])
 116             ,)
 117  fi
 118 fi
 119 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 120
 121 dnl Checks needed for gnumeric reader
 122 gnm_support=yes;
 123 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 124                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 125 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 126 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 127
 128 if test x"$gnm_support" = x"yes" ; then
 129    AC_DEFINE([GNM_SUPPORT], 1,
 130    [Define to 1 if building in support for reading Gnumeric files.])
 131 fi
 132 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 133
 134 AC_ARG_WITH(
 135   gui_tools,
 136   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 137 if test x"$with_gui_tools" = x"yes" ; then
 138         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 139 fi
 140 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 141
 142 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 143
 144 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 145 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 146 PSPP_GSL_NEEDS_FGNU89_INLINE
 147
 148 dnl Recent versions of GNU ncurses install the curses header files into
 149 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 150 dnl enables us to discover where they are. Earlier versions don't have
 151 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 152 dnl we'll trust it to find the right information.  Otherwise, we'll
 153 dnl try to discover it ourselves.
 154 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 155 dnl to ncurses8-config !!!
 156 AC_ARG_WITH(
 157   libncurses,
 158   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 159
 160 if test x"$with_libncurses" != x"no" ; then
 161   if test x"$cross_compiling" != x"yes" ; then
 162           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 163   fi
 164   if test x"$NCURSES_CONFIG" = x ; then
 165           AC_SEARCH_LIBS([tgetent], [ncurses],
 166               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 167   else
 168           old_cflags=$CFLAGS
 169           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 170           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 171           CFLAGS=$old_cflags
 172           if test x"$curses_available" = x"yes" ; then
 173            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 174            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 175            AC_SUBST(NCURSES_CFLAGS)
 176            AC_SUBST(NCURSES_LIBS)
 177           fi
 178   fi
 179   if test x"$curses_available" = x"yes" ; then
 180           AC_DEFINE([LIBNCURSES_USABLE], 1,
 181               [Define to 1 if the libncurses is both present and usable.])
 182   fi
 183   AC_CHECK_HEADERS([termcap.h])
 184 fi
 185
 186 PSPP_READLINE
 187
 188 dnl Checks for header files.
 189 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 190
 191 # For gnulib.
 192 gl_INIT
 193
 194 AC_C_INLINE
 195
 196 AC_CHECK_SIZEOF(double)
 197
 198 AC_C_BIGENDIAN
 199
 200 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 201
 202 AC_PROG_LN_S
 203
 204 AC_ARG_ENABLE(
 205   debug,
 206   [AS_HELP_STRING([--enable-debug],
 207                   [Turn on diagnostic features in the program])])
 208 if test x"$enable_debug" = x"yes"  ; then
 209   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 210 fi
 211
 212 # iconv is required
 213 if test "$am_cv_func_iconv" != "yes"; then
 214    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 215 fi
 216
 217 PSPP_CHECK_PREREQS
 218
 219 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 220
 221 AC_OUTPUT
 222 echo "PSPP configured successfully."
 223
 224 dnl configure.ac ends here