pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.4], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_TESTDIR([tests])
   8 AM_INIT_AUTOMAKE
   9
  10 dnl Checks for programs.
  11 AC_GNU_SOURCE
  12 AC_PROG_CC
  13 gl_EARLY
  14 AM_PROG_CC_C_O
  15 AC_LIBTOOL_WIN32_DLL
  16 AC_LIBTOOL_DLOPEN
  17 AC_PROG_LIBTOOL
  18 PKG_PROG_PKG_CONFIG
  19 m4_pattern_forbid([PKG_CHECK_MODULES])
  20 PSPP_CHECK_CLICKSEQUENCE
  21
  22 AC_ARG_ENABLE(
  23   anachronistic-dependencies,
  24   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  25                   [Attempt to allow building against older versions of dependent libraries])])
  26
  27 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  28
  29 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  30
  31 PSPP_CC_FOR_BUILD
  32 PSPP_PERL
  33
  34 dnl Internationalization macros.
  35 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  36 if  test x"$enable_nls" != x"no"  ; then
  37  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  38 fi
  39
  40
  41 dnl Checks for libraries.
  42 AC_SYS_LARGEFILE
  43 AC_SEARCH_LIBS([sin], [m])
  44 AC_SEARCH_LIBS([dcgettext], [intl])
  45 PSPP_LC_PAPER
  46
  47
  48 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  49 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  50
  51 # Support for Cairo and Pango.
  52 AC_ARG_WITH([cairo],
  53   [AS_HELP_STRING(
  54     [--without-cairo],
  55     [Don't build support for charts (using Cairo and Pango);
  56      implies --without-gui])],
  57   [], [with_cairo=yes])
  58 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  59 if test "$with_cairo" != no; then
  60   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  61     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  62      AC_DEFINE([HAVE_CAIRO], 1,
  63        [Define to 1 if Cairo and Pango are available.])],
  64     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  65   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  66   AC_SUBST(XMLLINT)
  67 fi
  68
  69 # Support for GUI.
  70 AC_ARG_WITH([gui],
  71   [AS_HELP_STRING([--without-gui],
  72                   [Don't build the PSPPIRE GUI (using GTK+)])],
  73   [], [with_gui=yes])
  74 AM_CONDITIONAL([HAVE_GUI],
  75                [test "$with_cairo" != no && test "$with_gui" != "no"])
  76 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  77   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  78     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  79
  80   AC_ARG_VAR([GLIB_GENMARSHAL])
  81   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  82   if test "x$GLIB_GENMARSHAL" = x; then
  83     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  84   fi
  85 fi
  86
  87 dnl Checks needed for psql reader
  88
  89 dnl The 8.x series postgres tarballs installs with a default prefix of
  90 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  91
  92 dnl If the libpq.so file is in a non standard path, (one which the linker
  93 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  94 dnl However, if the system happens to have more than one version of other
  95 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  96 dnl /usr and /usr/local) then the wrong one may get linked.
  97
  98 dnl To overcome this, we first check for libpq in the standard places, and
  99 dnl only set PG_LDFLAGS if it's not found.
 100
 101
 102 AC_ARG_WITH(
 103   libpq,
 104   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 105
 106 if test x"$with_libpq" != x"no" ; then
 107  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
 108
 109  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
 110  if test x"$cross_compiling" != x"yes" ; then
 111    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 112  fi
 113  if test -n "$PG_CONFIG" ; then
 114    AC_SUBST(PG_CONFIG)
 115    AC_DEFINE([PSQL_SUPPORT], 1,
 116    [Define to 1 if building in support for reading from postgres databases.])
 117    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 118    AC_SUBST(PG_CFLAGS)
 119
 120    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 121       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 122    fi
 123    AC_SUBST(PG_LDFLAGS)
 124
 125    PG_LIBS=-lpq
 126    AC_SUBST(PG_LIBS)
 127    PKG_CHECK_EXISTS(libssl,
 128          AC_DEFINE([USE_SSL],1,
 129                     [Define to 1 if the openssl library is present.])
 130             ,)
 131  fi
 132 fi
 133 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 134
 135 dnl Check for libxml2
 136 PKG_CHECK_MODULES(
 137   [LIBXML2], [libxml-2.0],
 138   [HAVE_LIBXML2=yes],
 139   [HAVE_LIBXML2=no
 140    PSPP_OPTIONAL_PREREQ([libxml2])])
 141
 142 dnl Check for zlib.
 143 AC_SEARCH_LIBS(
 144   [gzopen], [z],
 145   [HAVE_ZLIB=yes],
 146   [HAVE_ZLIB=no
 147    PSPP_OPTIONAL_PREREQ([zlib])])
 148 AC_CHECK_HEADERS(
 149   [zlib.h],
 150   [],
 151   [HAVE_ZLIB=no
 152    PSPP_OPTIONAL_PREREQ([zlib])])
 153
 154 dnl Avoid interference between zlib's crc32() function and gnulib's
 155 dnl crc32() function, which have different signatures.  PSPP calls
 156 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 157 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 158 dnl crc32(), then zlib will call gnulib's version instead of its own,
 159 dnl causing failures.  (This can happen even if zlib isn't detected
 160 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 161 dnl sometimes use zlib themselves.)
 162 AC_DEFINE(
 163   [crc32], [gl_crc32],
 164   [Avoid making zlib call gnulib's crc32() instead of its own.])
 165
 166 dnl Gnumeric support requires libxml2 and zlib.
 167 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 168   GNM_SUPPORT=yes
 169   AC_DEFINE(
 170     [GNM_SUPPORT], [1],
 171     [Define to 1 if building in support for reading Gnumeric files.])
 172 else
 173   GNM_SUPPORT=no
 174 fi
 175 AM_CONDITIONAL([GNM_SUPPORT], [test $GNM_SUPPORT = yes])
 176
 177 dnl ODT support requires libxml2.
 178 if test $HAVE_LIBXML2 = yes; then
 179   AC_DEFINE(
 180     [ODT_SUPPORT], [1],
 181     [Define to 1 if building in support for writing ODT files.])
 182 fi
 183 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 184
 185 AC_ARG_WITH(
 186   gui_tools,
 187   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 188 if test x"$with_gui_tools" = x"yes" ; then
 189         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 190 fi
 191 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 192
 193 if test x"$cross_compiling" != x"yes"; then
 194    WITH_PERL_MODULE=yes
 195 else
 196    WITH_PERL_MODULE=no
 197 fi
 198 AC_SUBST([WITH_PERL_MODULE])
 199 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 200
 201 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 202 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 203 PSPP_GSL_NEEDS_FGNU89_INLINE
 204
 205 dnl Recent versions of GNU ncurses install the curses header files into
 206 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 207 dnl enables us to discover where they are. Earlier versions don't have
 208 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 209 dnl we'll trust it to find the right information.  Otherwise, we'll
 210 dnl try to discover it ourselves.
 211 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 212 dnl to ncurses8-config !!!
 213 AC_ARG_WITH(
 214   libncurses,
 215   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 216
 217 if test x"$with_libncurses" != x"no" ; then
 218   if test x"$cross_compiling" != x"yes" ; then
 219           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 220   fi
 221   if test x"$NCURSES_CONFIG" = x ; then
 222           AC_SEARCH_LIBS([tgetent], [ncurses],
 223               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 224   else
 225           old_cflags=$CFLAGS
 226           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 227           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 228           CFLAGS=$old_cflags
 229           if test x"$curses_available" = x"yes" ; then
 230            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 231            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 232            AC_SUBST(NCURSES_CFLAGS)
 233            AC_SUBST(NCURSES_LIBS)
 234           fi
 235   fi
 236   if test x"$curses_available" = x"yes" ; then
 237           AC_DEFINE([LIBNCURSES_USABLE], 1,
 238               [Define to 1 if the libncurses is both present and usable.])
 239   fi
 240   AC_CHECK_HEADERS([termcap.h])
 241 fi
 242
 243 PSPP_READLINE
 244
 245 dnl Checks for header files.
 246 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 247
 248 # For gnulib.
 249 gl_INIT
 250
 251 AC_C_INLINE
 252
 253 AC_CHECK_SIZEOF(double)
 254
 255 AC_C_BIGENDIAN
 256
 257 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 258
 259 AC_PROG_LN_S
 260
 261 AC_ARG_ENABLE(
 262   debug,
 263   [AS_HELP_STRING([--enable-debug],
 264                   [Turn on diagnostic features in the program])])
 265 if test x"$enable_debug" = x"yes"  ; then
 266   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 267 fi
 268
 269 # iconv is required
 270 if test "$am_cv_func_iconv" != "yes"; then
 271    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 272 fi
 273
 274 dnl Required by the gnulib 'relocatable-prog' module.
 275 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 276 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 277 RELOCATABLE_STRIP=:
 278
 279 PSPP_CHECK_PREREQS
 280
 281 AC_CONFIG_FILES([Makefile gl/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 282
 283 AC_OUTPUT
 284 echo "PSPP configured successfully."
 285
 286 dnl configure.ac ends here