pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LIBPLOT
  40 PSPP_LC_PAPER
  41 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  42
  43
  44 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  45 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  46
  47
  48 AC_ARG_WITH(
  49   gui,
  50   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  51
  52 required_gtk_version=2.12
  53
  54 if test x"$with_gui" != x"no" ; then
  55   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  56     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  57 fi
  58 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  59
  60
  61 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango pangocairo],
  62    [HAVE_CAIRO=yes
  63     CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  64     LIBS="$LIBPLOT_LIBS $LIBS"
  65     AC_DEFINE([HAVE_CAIRO], 1,
  66               [Define to 1 if Cairo and Pango are available.])],
  67    [HAVE_CAIRO=no
  68     PSPP_OPTIONAL_PREREQ([cairo 1.5 or later])])
  69 AM_CONDITIONAL([HAVE_CAIRO], [test $HAVE_CAIRO = yes])
  70
  71 dnl Checks needed for psql reader
  72
  73 dnl The 8.x series postgres tarballs installs with a default prefix of
  74 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  75
  76 dnl If the libpq.so file is in a non standard path, (one which the linker
  77 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  78 dnl However, if the system happens to have more than one version of other
  79 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  80 dnl /usr and /usr/local) then the wrong one may get linked.
  81
  82 dnl To overcome this, we first check for libpq in the standard places, and
  83 dnl only set PG_LDFLAGS if it's not found.
  84
  85
  86 AC_ARG_WITH(
  87   libpq,
  88   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  89
  90 if test x"$with_libpq" != x"no" ; then
  91  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  92
  93  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  94  if test x"$cross_compiling" != x"yes" ; then
  95    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  96  fi
  97  if test -n "$PG_CONFIG" ; then
  98    AC_SUBST(PG_CONFIG)
  99    AC_DEFINE([PSQL_SUPPORT], 1,
 100    [Define to 1 if building in support for reading from postgres databases.])
 101    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 102    AC_SUBST(PG_CFLAGS)
 103
 104    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 105       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 106    fi
 107    AC_SUBST(PG_LDFLAGS)
 108
 109    PG_LIBS=-lpq
 110    AC_SUBST(PG_LIBS)
 111    PKG_CHECK_EXISTS(libssl,
 112          AC_DEFINE([USE_SSL],1,
 113                     [Define to 1 if the openssl library is present.])
 114             ,)
 115  fi
 116 fi
 117 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 118
 119 dnl Checks needed for gnumeric reader
 120 gnm_support=yes;
 121 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 122                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 123 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 124 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 125
 126 if test x"$gnm_support" = x"yes" ; then
 127    AC_DEFINE([GNM_SUPPORT], 1,
 128    [Define to 1 if building in support for reading Gnumeric files.])
 129 fi
 130 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 131
 132 AC_ARG_WITH(
 133   gui_tools,
 134   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 135 if test x"$with_gui_tools" = x"yes" ; then
 136         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 137 fi
 138 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 139
 140 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 141
 142 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 143 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 144 PSPP_GSL_NEEDS_FGNU89_INLINE
 145
 146 dnl Recent versions of GNU ncurses install the curses header files into
 147 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 148 dnl enables us to discover where they are. Earlier versions don't have
 149 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 150 dnl we'll trust it to find the right information.  Otherwise, we'll
 151 dnl try to discover it ourselves.
 152 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 153 dnl to ncurses8-config !!!
 154 AC_ARG_WITH(
 155   libncurses,
 156   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 157
 158 if test x"$with_libncurses" != x"no" ; then
 159   if test x"$cross_compiling" != x"yes" ; then
 160           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 161   fi
 162   if test x"$NCURSES_CONFIG" = x ; then
 163           AC_SEARCH_LIBS([tgetent], [ncurses],
 164               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 165   else
 166           old_cflags=$CFLAGS
 167           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 168           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 169           CFLAGS=$old_cflags
 170           if test x"$curses_available" = x"yes" ; then
 171            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 172            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 173            AC_SUBST(NCURSES_CFLAGS)
 174            AC_SUBST(NCURSES_LIBS)
 175           fi
 176   fi
 177   if test x"$curses_available" = x"yes" ; then
 178           AC_DEFINE([LIBNCURSES_USABLE], 1,
 179               [Define to 1 if the libncurses is both present and usable.])
 180   fi
 181   AC_CHECK_HEADERS([termcap.h])
 182 fi
 183
 184 PSPP_READLINE
 185
 186 dnl Checks for header files.
 187 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 188
 189 # For gnulib.
 190 gl_INIT
 191
 192 AC_C_INLINE
 193
 194 AC_CHECK_SIZEOF(double)
 195
 196 AC_C_BIGENDIAN
 197
 198 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 199
 200 AC_PROG_LN_S
 201
 202 AC_ARG_ENABLE(
 203   debug,
 204   [AS_HELP_STRING([--enable-debug],
 205                   [Turn on diagnostic features in the program])])
 206 if test x"$enable_debug" = x"yes"  ; then
 207   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 208 fi
 209
 210 # iconv is required
 211 if test "$am_cv_func_iconv" != "yes"; then
 212    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 213 fi
 214
 215 PSPP_CHECK_PREREQS
 216
 217 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 218
 219 AC_OUTPUT
 220 echo "PSPP configured successfully."
 221
 222 dnl configure.ac ends here