pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.5], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Internationalization macros.
  36 AC_PROVIDE([AM_PO_SUBDIRS])     # PSPP provides its own po/ support.
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 AM_GNU_GETTEXT_VERSION([0.17])
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LC_PAPER
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50 # Support for Cairo and Pango.
  51 AC_ARG_WITH([cairo],
  52   [AS_HELP_STRING(
  53     [--without-cairo],
  54     [Don't build support for charts (using Cairo and Pango);
  55      implies --without-gui])],
  56   [], [with_cairo=yes])
  57 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  58 if test "$with_cairo" != no; then
  59   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  60     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  61      AC_DEFINE([HAVE_CAIRO], 1,
  62        [Define to 1 if Cairo and Pango are available.])],
  63     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  64   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  65   AC_SUBST(XMLLINT)
  66 fi
  67
  68 # Support for GUI.
  69 AC_ARG_WITH([gui],
  70   [AS_HELP_STRING([--without-gui],
  71                   [Don't build the PSPPIRE GUI (using GTK+)])],
  72   [], [with_gui=yes])
  73 AM_CONDITIONAL([HAVE_GUI],
  74                [test "$with_cairo" != no && test "$with_gui" != "no"])
  75 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  76   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  77     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  78
  79   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2])
  80
  81   AC_ARG_VAR([GLIB_GENMARSHAL])
  82   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  83   if test "x$GLIB_GENMARSHAL" = x; then
  84     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  85   fi
  86 fi
  87
  88 dnl Checks needed for psql reader
  89
  90 dnl The 8.x series postgres tarballs installs with a default prefix of
  91 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  92
  93 dnl If the libpq.so file is in a non standard path, (one which the linker
  94 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  95 dnl However, if the system happens to have more than one version of other
  96 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  97 dnl /usr and /usr/local) then the wrong one may get linked.
  98
  99 dnl To overcome this, we first check for libpq in the standard places, and
 100 dnl only set PG_LDFLAGS if it's not found.
 101
 102
 103 AC_ARG_WITH(
 104   libpq,
 105   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 106 AC_ARG_VAR([PG_CONFIG],
 107            [Full pathname of the pg_config program shipped with Postgresql])
 108 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 109              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 110
 111 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 112   AC_SUBST(PG_CONFIG)
 113   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 114   AC_SUBST(PG_CFLAGS)
 115
 116   AC_CHECK_LIB([pq], [PQexec],
 117      [:],
 118      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 119   AC_SUBST(PG_LDFLAGS)
 120
 121   PG_LIBS=-lpq
 122   AC_SUBST(PG_LIBS)
 123
 124   PKG_CHECK_EXISTS(libssl,
 125         AC_DEFINE([USE_SSL],1,
 126                    [Define to 1 if the openssl library is present.])
 127            ,)
 128
 129   # Now verify that we can actually link against libpq.  If we are
 130   # cross-compiling and picked up a host libpq, or if libpq is just
 131   # badly installed, this will fail.
 132   AC_CACHE_CHECK(
 133     [whether -lpq links successfully],
 134     [pspp_cv_have_libpq],
 135     [save_CPPFLAGS=$CPPFLAGS
 136      save_LIBS=$LIBS
 137      save_LDFLAGS=$LDFLAGS
 138      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 139      LIBS="$PG_LIBS $LIBS"
 140      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 141      AC_LINK_IFELSE(
 142        [AC_LANG_PROGRAM(
 143          [#include <libpq-fe.h>
 144          ], [PQfinish (0);])],
 145        [pspp_cv_have_libpq=yes],
 146        [pspp_cv_have_libpq=no])
 147      CPPFLAGS=$save_CPPFLAGS
 148      LIBS=$save_LIBS
 149      LDFLAGS=$save_LDFLAGS])
 150
 151   if test $pspp_cv_have_libpq = yes; then
 152     AC_DEFINE([PSQL_SUPPORT], [1],
 153       [Define to 1 if building in support for reading from postgres
 154        databases.])
 155   else
 156     PG_CONFIG=
 157     PG_CFLAGS=
 158     PG_LDFLAGS=
 159     PG_LIBS=
 160   fi
 161 else
 162   pspp_cv_have_libpq=no
 163 fi
 164 AM_CONDITIONAL(PSQL_SUPPORT, test $pspp_cv_have_libpq = yes)
 165
 166 dnl Check for libxml2
 167 PKG_CHECK_MODULES(
 168   [LIBXML2], [libxml-2.0],
 169   [HAVE_LIBXML2=yes],
 170   [HAVE_LIBXML2=no
 171    PSPP_OPTIONAL_PREREQ([libxml2])])
 172
 173 dnl Check for zlib.
 174 AC_SEARCH_LIBS(
 175   [gzopen], [z],
 176   [HAVE_ZLIB=yes],
 177   [HAVE_ZLIB=no
 178    PSPP_OPTIONAL_PREREQ([zlib])])
 179 AC_CHECK_HEADERS(
 180   [zlib.h],
 181   [],
 182   [HAVE_ZLIB=no
 183    PSPP_OPTIONAL_PREREQ([zlib])])
 184
 185 dnl Avoid interference between zlib's crc32() function and gnulib's
 186 dnl crc32() function, which have different signatures.  PSPP calls
 187 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 188 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 189 dnl crc32(), then zlib will call gnulib's version instead of its own,
 190 dnl causing failures.  (This can happen even if zlib isn't detected
 191 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 192 dnl sometimes use zlib themselves.)
 193 AC_DEFINE(
 194   [crc32], [gl_crc32],
 195   [Avoid making zlib call gnulib's crc32() instead of its own.])
 196
 197 dnl Gnumeric support requires libxml2 and zlib.
 198 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 199   GNM_SUPPORT=yes
 200   AC_DEFINE(
 201     [GNM_SUPPORT], [1],
 202     [Define to 1 if building in support for reading Gnumeric files.])
 203 else
 204   GNM_SUPPORT=no
 205 fi
 206 AM_CONDITIONAL([GNM_SUPPORT], [test $GNM_SUPPORT = yes])
 207
 208 dnl ODT support requires libxml2.
 209 if test $HAVE_LIBXML2 = yes; then
 210   AC_DEFINE(
 211     [ODT_SUPPORT], [1],
 212     [Define to 1 if building in support for writing ODT files.])
 213 fi
 214 AM_CONDITIONAL([ODT_SUPPORT], [test $HAVE_LIBXML2 = yes])
 215
 216 AC_ARG_WITH(
 217   gui_tools,
 218   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 219 if test x"$with_gui_tools" = x"yes" ; then
 220         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 221 fi
 222 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 223
 224 AC_ARG_WITH(
 225   [perl-module],
 226   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 227   [case $with_perl_module in # (
 228      yes|no) ;; # (
 229      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 230    esac
 231    WITH_PERL_MODULE=$with_perl_module],
 232   [if test x"$cross_compiling" != x"yes"; then
 233      WITH_PERL_MODULE=yes
 234    else
 235      WITH_PERL_MODULE=no
 236    fi])
 237 AC_SUBST([WITH_PERL_MODULE])
 238 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 239
 240 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 241 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [], [PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])])
 242
 243 PSPP_GSL_NEEDS_FGNU89_INLINE
 244
 245 dnl Recent versions of GNU ncurses install the curses header files into
 246 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 247 dnl enables us to discover where they are. Earlier versions don't have
 248 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 249 dnl we'll trust it to find the right information.  Otherwise, we'll
 250 dnl try to discover it ourselves.
 251 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 252 dnl to ncurses8-config !!!
 253 AC_ARG_WITH(
 254   libncurses,
 255   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 256
 257 if test x"$with_libncurses" != x"no" ; then
 258   if test x"$cross_compiling" != x"yes" ; then
 259           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 260   fi
 261   if test x"$NCURSES_CONFIG" = x ; then
 262           AC_SEARCH_LIBS([tgetent], [ncurses],
 263               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 264   else
 265           old_cflags=$CFLAGS
 266           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 267           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 268           CFLAGS=$old_cflags
 269           if test x"$curses_available" = x"yes" ; then
 270            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 271            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 272            AC_SUBST(NCURSES_CFLAGS)
 273            AC_SUBST(NCURSES_LIBS)
 274           fi
 275   fi
 276   if test x"$curses_available" = x"yes" ; then
 277           AC_DEFINE([LIBNCURSES_USABLE], 1,
 278               [Define to 1 if the libncurses is both present and usable.])
 279   fi
 280   AC_CHECK_HEADERS([termcap.h])
 281 fi
 282
 283 PSPP_READLINE
 284
 285 dnl Checks for header files.
 286 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 287
 288 # For gnulib.
 289 gl_INIT
 290
 291 AC_C_INLINE
 292
 293 AC_CHECK_SIZEOF(double)
 294
 295 AC_C_BIGENDIAN
 296
 297 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 298
 299 AC_PROG_LN_S
 300
 301 AC_ARG_ENABLE(
 302   debug,
 303   [AS_HELP_STRING([--enable-debug],
 304                   [Turn on diagnostic features in the program])])
 305 if test x"$enable_debug" = x"yes"  ; then
 306   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 307 fi
 308
 309 # iconv is required
 310 if test "$am_cv_func_iconv" != "yes"; then
 311    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 312 fi
 313
 314 dnl Required by the gnulib 'relocatable-prog' module.
 315 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 316 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 317 RELOCATABLE_STRIP=:
 318
 319 PSPP_CHECK_PREREQS
 320
 321 AC_CONFIG_FILES(
 322   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 323
 324 AC_OUTPUT
 325 echo "PSPP configured successfully."
 326
 327 dnl configure.ac ends here