pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.5.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  40 PSPP_CHECK_DOT
  41
  42 PSPP_ENABLE_WERROR
  43
  44 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  45
  46 PSPP_CC_FOR_BUILD
  47 PSPP_PERL
  48 PSPP_PYTHON
  49 AC_CHECK_PROGS([TEX], [tex], [no])
  50 AC_SUBST([TEX])
  51
  52 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  53 # avoided in GCC 10.x:
  54 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  55 #   cc1: error: function may return address of local variable
  56 CFLAGS="$CFLAGS -DGCC_LINT"
  57
  58 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  59 AC_PROVIDE([AM_PO_SUBDIRS])
  60 AM_GNU_GETTEXT([external], [need-ngettext])
  61 LIBS="$LIBINTL $LIBS"
  62 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  63 if test "x$MSGFMT" = x; then
  64   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  65 fi
  66
  67 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  68 if test "x$XGETTEXT" = x; then
  69   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  70 fi
  71 dnl appstream required for metainfo.its
  72 dnl if metainfo.its is not there, then the following small
  73 dnl file will not produce an outputfile
  74 $as_echo '<?xml version="1.0" encoding="UTF-8"?>' > test.metainfo.xml.in
  75 $as_echo '<component type="desktop">' >> test.metainfo.xml.in
  76 $as_echo '<name>Hallo</name>' >> test.metainfo.xml.in
  77 $as_echo '</component>' >> test.metainfo.xml.in
  78 xgettext -o mifc.po test.metainfo.xml.in
  79 if ! test -f ./mifc.po  ; then
  80   PSPP_OPTIONAL_PREREQ([org.fsf.metainfo.xml will not be translated. Install gettext >=0.20 or appstream.])
  81 fi
  82 rm -f mifc.po test.metainfo.xml.in
  83
  84 dnl Checks for libraries.
  85 AC_SYS_LARGEFILE
  86 AC_SEARCH_LIBS([sin], [m])
  87 PSPP_LC_PAPER
  88
  89
  90 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  91 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  92
  93 # Support for Cairo and Pango.
  94 AC_ARG_WITH([cairo],
  95   [AS_HELP_STRING(
  96     [--without-cairo],
  97     [Don't build support for charts (using Cairo and Pango);
  98      implies --without-gui])],
  99   [], [with_cairo=yes])
 100 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
 101 if test "$with_cairo" != no; then
 102   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 103     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
 104      AC_DEFINE([HAVE_CAIRO], 1,
 105        [Define to 1 if Cairo and Pango are available.])],
 106     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
 107 fi
 108
 109 dnl One of the tests uses xmllint.
 110 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 111 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 112   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 113     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 114     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 115    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 116
 117 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 118
 119 # Support for GUI.
 120 AC_ARG_WITH([gui],
 121   [AS_HELP_STRING([--without-gui],
 122                   [Don't build the PSPPIRE GUI (using GTK+)])],
 123   [], [with_gui=yes])
 124 AM_CONDITIONAL([building_gui],
 125                [test "$with_cairo" != no && test "$with_gui" != "no"])
 126 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 127   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 128     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 129
 130   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 131     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 132
 133   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 134     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 135
 136   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 137     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 138
 139   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 140     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 141   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 142
 143   PKG_CHECK_MODULES([LIBRSVG], [librsvg-2.0 >= 2.44],
 144     [AC_DEFINE([HAVE_RSVG], 1, [Define to 1 if librsvg is available])],
 145     [PSPP_OPTIONAL_PREREQ([librsvg >= 2.44 required for high dpi Copy and Paste])])
 146
 147   AC_ARG_VAR([GLIB_GENMARSHAL])
 148   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 149   if test "x$GLIB_GENMARSHAL" = x; then
 150     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 151   fi
 152
 153   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 154   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 155     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 156   fi
 157
 158 fi
 159
 160 gl_NEXT_HEADERS([gtk/gtk.h])
 161
 162 dnl Checks needed for psql reader
 163
 164 dnl The 8.x series postgres tarballs installs with a default prefix of
 165 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 166
 167 dnl If the libpq.so file is in a non standard path, (one which the linker
 168 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 169 dnl However, if the system happens to have more than one version of other
 170 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 171 dnl /usr and /usr/local) then the wrong one may get linked.
 172
 173 dnl To overcome this, we first check for libpq in the standard places, and
 174 dnl only set PG_LDFLAGS if it's not found.
 175
 176
 177 AC_ARG_WITH(
 178   libpq,
 179   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 180 AC_ARG_VAR([PG_CONFIG],
 181            [Full pathname of the pg_config program shipped with Postgresql])
 182 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 183              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 184
 185 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 186   AC_SUBST(PG_CONFIG)
 187   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 188   AC_SUBST(PG_CFLAGS)
 189
 190   AC_CHECK_LIB([pq], [PQexec],
 191      [:],
 192      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 193   AC_SUBST(PG_LDFLAGS)
 194
 195   PG_LIBS=-lpq
 196   AC_SUBST(PG_LIBS)
 197
 198   PKG_CHECK_EXISTS(libssl,
 199         AC_DEFINE([USE_SSL],1,
 200                    [Define to 1 if the openssl library is present.])
 201            ,)
 202
 203   # Now verify that we can actually link against libpq.  If we are
 204   # cross-compiling and picked up a host libpq, or if libpq is just
 205   # badly installed, this will fail.
 206   AC_CACHE_CHECK(
 207     [whether -lpq links successfully],
 208     [pspp_cv_have_libpq],
 209     [save_CPPFLAGS=$CPPFLAGS
 210      save_LIBS=$LIBS
 211      save_LDFLAGS=$LDFLAGS
 212      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 213      LIBS="$PG_LIBS $LIBS"
 214      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 215      AC_LINK_IFELSE(
 216        [AC_LANG_PROGRAM(
 217          [#include <libpq-fe.h>
 218          ], [PQfinish (0);])],
 219        [pspp_cv_have_libpq=yes],
 220        [pspp_cv_have_libpq=no])
 221      CPPFLAGS=$save_CPPFLAGS
 222      LIBS=$save_LIBS
 223      LDFLAGS=$save_LDFLAGS])
 224
 225   if test $pspp_cv_have_libpq = yes; then
 226     PSQL_SUPPORT=yes
 227     AC_DEFINE([PSQL_SUPPORT], [1],
 228       [Define to 1 if building in support for reading from postgres
 229        databases.])
 230   else
 231     PSQL_SUPPORT=no
 232     PG_CONFIG=
 233     PG_CFLAGS=
 234     PG_LDFLAGS=
 235     PG_LIBS=
 236   fi
 237 else
 238   PSQL_SUPPORT=no
 239   pspp_cv_have_libpq=no
 240 fi
 241 AC_SUBST([PSQL_SUPPORT])
 242
 243 dnl Check for libxml2
 244 PKG_CHECK_MODULES(
 245   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 246
 247 dnl Check for zlib.
 248 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 249 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 250
 251 dnl Avoid interference between zlib's crc32() function and gnulib's
 252 dnl crc32() function, which have different signatures.  PSPP calls
 253 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 254 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 255 dnl crc32(), then zlib will call gnulib's version instead of its own,
 256 dnl causing failures.  (This can happen even if zlib isn't detected
 257 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 258 dnl sometimes use zlib themselves.)
 259 AC_DEFINE(
 260   [crc32], [gl_crc32],
 261   [Avoid making zlib call gnulib's crc32() instead of its own.])
 262
 263 AC_ARG_WITH(
 264   [perl-module],
 265   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 266   [case $with_perl_module in # (
 267      yes|no) ;; # (
 268      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 269    esac
 270    WITH_PERL_MODULE=$with_perl_module],
 271   [if test x"$cross_compiling" != x"yes"; then
 272      WITH_PERL_MODULE=yes
 273    else
 274      WITH_PERL_MODULE=no
 275    fi])
 276 AC_SUBST([WITH_PERL_MODULE])
 277 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 278
 279 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 280 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 281                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 282
 283
 284 PSPP_GSL_NEEDS_FGNU89_INLINE
 285
 286 PSPP_READLINE
 287
 288 dnl Checks for header files.
 289 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 290
 291 dnl Some systems don't have SIGWINCH
 292 AC_CHECK_DECLS([SIGWINCH], [], [],
 293           [#include <signal.h>
 294           /* NetBSD declares sys_siglist in unistd.h.  */
 295           #ifdef HAVE_UNISTD_H
 296           # include <unistd.h>
 297           #endif
 298           ])
 299
 300
 301 # For gnulib.
 302 gl_INIT
 303
 304 AC_C_INLINE
 305
 306 AC_C_BIGENDIAN
 307
 308 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 309
 310 AC_PROG_LN_S
 311
 312 # iconv is required
 313 AM_ICONV
 314 if test "$am_cv_func_iconv" != "yes"; then
 315    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 316 fi
 317 LIBS="$LIBICONV $LIBS"
 318
 319 dnl Required by the gnulib 'relocatable-prog' module.
 320 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 321 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 322 RELOCATABLE_STRIP=:
 323
 324 PSPP_CHECK_PREREQS
 325
 326 AC_CONFIG_FILES(
 327   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 328
 329 AC_CONFIG_COMMANDS([doc/examples/dummy], [:])
 330
 331 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 332
 333 AC_OUTPUT
 334 echo "PSPP configured successfully."
 335
 336 dnl configure.ac ends here