pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.8], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 AC_ARG_ENABLE(
  24   anachronistic-dependencies,
  25   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  26                   [Attempt to allow building against older versions of dependent libraries])])
  27
  28 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  29
  30 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  31
  32 PSPP_CC_FOR_BUILD
  33 PSPP_PERL
  34
  35 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  36 AC_PROVIDE([AM_PO_SUBDIRS])
  37 AM_GNU_GETTEXT([external], [need-ngettext])
  38 LIBS="$LIBINTL $LIBS"
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 PSPP_LC_PAPER
  44
  45
  46 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  47 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  48
  49 # Support for Cairo and Pango.
  50 AC_ARG_WITH([cairo],
  51   [AS_HELP_STRING(
  52     [--without-cairo],
  53     [Don't build support for charts (using Cairo and Pango);
  54      implies --without-gui])],
  55   [], [with_cairo=yes])
  56 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  57 if test "$with_cairo" != no; then
  58   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  59     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  60      AC_DEFINE([HAVE_CAIRO], 1,
  61        [Define to 1 if Cairo and Pango are available.])],
  62     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  63   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  64   AC_SUBST(XMLLINT)
  65 fi
  66
  67 # Support for GUI.
  68 AC_ARG_WITH([gui],
  69   [AS_HELP_STRING([--without-gui],
  70                   [Don't build the PSPPIRE GUI (using GTK+)])],
  71   [], [with_gui=yes])
  72 AM_CONDITIONAL([HAVE_GUI],
  73                [test "$with_cairo" != no && test "$with_gui" != "no"])
  74 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  75   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.16], [],
  76     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.16 or later (or use --without-gui)])])
  77
  78   AC_ARG_VAR([GLIB_GENMARSHAL])
  79   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  80   if test "x$GLIB_GENMARSHAL" = x; then
  81     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  82   fi
  83
  84   gl_NEXT_HEADERS([gtk/gtk.h])
  85 fi
  86
  87 dnl Checks needed for psql reader
  88
  89 dnl The 8.x series postgres tarballs installs with a default prefix of
  90 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  91
  92 dnl If the libpq.so file is in a non standard path, (one which the linker
  93 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  94 dnl However, if the system happens to have more than one version of other
  95 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  96 dnl /usr and /usr/local) then the wrong one may get linked.
  97
  98 dnl To overcome this, we first check for libpq in the standard places, and
  99 dnl only set PG_LDFLAGS if it's not found.
 100
 101
 102 AC_ARG_WITH(
 103   libpq,
 104   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 105 AC_ARG_VAR([PG_CONFIG],
 106            [Full pathname of the pg_config program shipped with Postgresql])
 107 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 108              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 109
 110 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 111   AC_SUBST(PG_CONFIG)
 112   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 113   AC_SUBST(PG_CFLAGS)
 114
 115   AC_CHECK_LIB([pq], [PQexec],
 116      [:],
 117      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 118   AC_SUBST(PG_LDFLAGS)
 119
 120   PG_LIBS=-lpq
 121   AC_SUBST(PG_LIBS)
 122
 123   PKG_CHECK_EXISTS(libssl,
 124         AC_DEFINE([USE_SSL],1,
 125                    [Define to 1 if the openssl library is present.])
 126            ,)
 127
 128   # Now verify that we can actually link against libpq.  If we are
 129   # cross-compiling and picked up a host libpq, or if libpq is just
 130   # badly installed, this will fail.
 131   AC_CACHE_CHECK(
 132     [whether -lpq links successfully],
 133     [pspp_cv_have_libpq],
 134     [save_CPPFLAGS=$CPPFLAGS
 135      save_LIBS=$LIBS
 136      save_LDFLAGS=$LDFLAGS
 137      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 138      LIBS="$PG_LIBS $LIBS"
 139      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 140      AC_LINK_IFELSE(
 141        [AC_LANG_PROGRAM(
 142          [#include <libpq-fe.h>
 143          ], [PQfinish (0);])],
 144        [pspp_cv_have_libpq=yes],
 145        [pspp_cv_have_libpq=no])
 146      CPPFLAGS=$save_CPPFLAGS
 147      LIBS=$save_LIBS
 148      LDFLAGS=$save_LDFLAGS])
 149
 150   if test $pspp_cv_have_libpq = yes; then
 151     PSQL_SUPPORT=yes
 152     AC_DEFINE([PSQL_SUPPORT], [1],
 153       [Define to 1 if building in support for reading from postgres
 154        databases.])
 155   else
 156     PSQL_SUPPORT=no
 157     PG_CONFIG=
 158     PG_CFLAGS=
 159     PG_LDFLAGS=
 160     PG_LIBS=
 161   fi
 162 else
 163   PSQL_SUPPORT=no
 164   pspp_cv_have_libpq=no
 165 fi
 166 AC_SUBST([PSQL_SUPPORT])
 167
 168 dnl Check for libxml2
 169 PKG_CHECK_MODULES(
 170   [LIBXML2], [libxml-2.0],
 171   [HAVE_LIBXML2=yes],
 172   [HAVE_LIBXML2=no
 173    PSPP_OPTIONAL_PREREQ([libxml2])])
 174
 175 dnl Check for zlib.
 176 AC_SEARCH_LIBS(
 177   [gzopen], [z],
 178   [HAVE_ZLIB=yes],
 179   [HAVE_ZLIB=no
 180    PSPP_OPTIONAL_PREREQ([zlib])])
 181 AC_CHECK_HEADERS(
 182   [zlib.h],
 183   [],
 184   [HAVE_ZLIB=no
 185    PSPP_OPTIONAL_PREREQ([zlib])])
 186
 187 dnl Avoid interference between zlib's crc32() function and gnulib's
 188 dnl crc32() function, which have different signatures.  PSPP calls
 189 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 190 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 191 dnl crc32(), then zlib will call gnulib's version instead of its own,
 192 dnl causing failures.  (This can happen even if zlib isn't detected
 193 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 194 dnl sometimes use zlib themselves.)
 195 AC_DEFINE(
 196   [crc32], [gl_crc32],
 197   [Avoid making zlib call gnulib's crc32() instead of its own.])
 198
 199 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 200 if test $HAVE_LIBXML2 = yes && test $HAVE_ZLIB = yes; then
 201   GNM_SUPPORT=yes
 202   ODF_READ_SUPPORT=yes
 203   AC_DEFINE(
 204     [GNM_SUPPORT], [1],
 205     [Define to 1 if building in support for reading Gnumeric files.])
 206   AC_DEFINE(
 207     [ODF_READ_SUPPORT], [1],
 208     [Define to 1 if building in support for reading OpenDocument files.])
 209 else
 210   GNM_SUPPORT=no
 211   ODF_READ_SUPPORT=no
 212 fi
 213 AC_SUBST([GNM_SUPPORT])
 214 AC_SUBST([ODF_READ_SUPPORT])
 215
 216 dnl ODF support requires libxml2 (zlib is optional).
 217 if test $HAVE_LIBXML2 = yes; then
 218   AC_DEFINE(
 219     [ODF_WRITE_SUPPORT], [1],
 220     [Define to 1 if building in support for writing OpenDocument files.])
 221 fi
 222 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 223
 224 AC_ARG_WITH(
 225   gui_tools,
 226   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 227 if test x"$with_gui_tools" = x"yes" ; then
 228         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 229 fi
 230 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 231
 232 AC_ARG_WITH(
 233   [perl-module],
 234   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 235   [case $with_perl_module in # (
 236      yes|no) ;; # (
 237      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 238    esac
 239    WITH_PERL_MODULE=$with_perl_module],
 240   [if test x"$cross_compiling" != x"yes"; then
 241      WITH_PERL_MODULE=yes
 242    else
 243      WITH_PERL_MODULE=no
 244    fi])
 245 AC_SUBST([WITH_PERL_MODULE])
 246 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 247
 248 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 249 PKG_CHECK_MODULES([GSL], [gsl >= 1.12], [],
 250                          AC_SEARCH_LIBS([gsl_linalg_cholesky_invert], [gsl],,[PSPP_REQUIRED_PREREQ([gsl 2.0 version 1.12 or later])]))
 251
 252
 253 PSPP_GSL_NEEDS_FGNU89_INLINE
 254
 255 dnl Recent versions of GNU ncurses install the curses header files into
 256 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 257 dnl enables us to discover where they are. Earlier versions don't have
 258 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 259 dnl we'll trust it to find the right information.  Otherwise, we'll
 260 dnl try to discover it ourselves.
 261 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 262 dnl to ncurses8-config !!!
 263 AC_ARG_WITH(
 264   libncurses,
 265   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 266
 267 if test x"$with_libncurses" != x"no" ; then
 268   if test x"$cross_compiling" != x"yes" ; then
 269           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 270   fi
 271   if test x"$NCURSES_CONFIG" = x ; then
 272           AC_SEARCH_LIBS([tgetent], [ncurses],
 273               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 274   else
 275           old_cflags=$CFLAGS
 276           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 277           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 278           CFLAGS=$old_cflags
 279           if test x"$curses_available" = x"yes" ; then
 280            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 281            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 282            AC_SUBST(NCURSES_CFLAGS)
 283            AC_SUBST(NCURSES_LIBS)
 284           fi
 285   fi
 286   if test x"$curses_available" = x"yes" ; then
 287           AC_DEFINE([LIBNCURSES_USABLE], 1,
 288               [Define to 1 if the libncurses is both present and usable.])
 289   fi
 290   AC_CHECK_HEADERS([termcap.h])
 291 fi
 292
 293 PSPP_READLINE
 294
 295 dnl Checks for header files.
 296 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 297
 298 dnl Some systems dont have SIGWINCH
 299 AC_CHECK_DECLS([SIGWINCH], [], [],
 300           [#include <signal.h>
 301           /* NetBSD declares sys_siglist in unistd.h.  */
 302           #ifdef HAVE_UNISTD_H
 303           # include <unistd.h>
 304           #endif
 305           ])
 306
 307
 308 # For gnulib.
 309 gl_INIT
 310
 311 AC_C_INLINE
 312
 313 AC_CHECK_SIZEOF([size_t])
 314 SIZEOF_SIZE_T=$ac_cv_sizeof_size_t
 315 AC_SUBST([SIZEOF_SIZE_T])
 316
 317 AC_C_BIGENDIAN
 318
 319 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 320
 321 AC_PROG_LN_S
 322
 323 AC_ARG_ENABLE(
 324   debug,
 325   [AS_HELP_STRING([--enable-debug],
 326                   [Turn on diagnostic features in the program])])
 327 if test x"$enable_debug" = x"yes"  ; then
 328   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 329 fi
 330
 331 # iconv is required
 332 AM_ICONV
 333 if test "$am_cv_func_iconv" != "yes"; then
 334    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 335 fi
 336 LIBS="$LIBICONV $LIBS"
 337
 338 dnl Required by the gnulib 'relocatable-prog' module.
 339 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 340 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 341 RELOCATABLE_STRIP=:
 342
 343 PSPP_CHECK_PREREQS
 344
 345 AC_CONFIG_FILES(
 346   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 347
 348 AC_OUTPUT
 349 echo "PSPP configured successfully."
 350
 351 dnl configure.ac ends here