pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.8.4], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_WERROR
  24
  25 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  26
  27 PSPP_CC_FOR_BUILD
  28 PSPP_PERL
  29
  30 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  31 AC_PROVIDE([AM_PO_SUBDIRS])
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 LIBS="$LIBINTL $LIBS"
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LC_PAPER
  39
  40
  41 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  42 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  43
  44 # Support for Cairo and Pango.
  45 AC_ARG_WITH([cairo],
  46   [AS_HELP_STRING(
  47     [--without-cairo],
  48     [Don't build support for charts (using Cairo and Pango);
  49      implies --without-gui])],
  50   [], [with_cairo=yes])
  51 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  52 if test "$with_cairo" != no; then
  53   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  54     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  55      AC_DEFINE([HAVE_CAIRO], 1,
  56        [Define to 1 if Cairo and Pango are available.])],
  57     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  58   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  59   AC_SUBST(XMLLINT)
  60 fi
  61
  62 # Support for GUI.
  63 AC_ARG_WITH([gui],
  64   [AS_HELP_STRING([--without-gui],
  65                   [Don't build the PSPPIRE GUI (using GTK+)])],
  66   [], [with_gui=yes])
  67 AM_CONDITIONAL([HAVE_GUI],
  68                [test "$with_cairo" != no && test "$with_gui" != "no"])
  69 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  70   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  71     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  72
  73   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.24], [],
  74     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.24 or later (or use --without-gui)])])
  75
  76   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
  77     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
  78
  79
  80   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  81     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  82
  83   AC_ARG_VAR([GLIB_GENMARSHAL])
  84   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  85   if test "x$GLIB_GENMARSHAL" = x; then
  86     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  87   fi
  88
  89 fi
  90
  91 gl_NEXT_HEADERS([gtk/gtk.h])
  92
  93 dnl Checks needed for psql reader
  94
  95 dnl The 8.x series postgres tarballs installs with a default prefix of
  96 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  97
  98 dnl If the libpq.so file is in a non standard path, (one which the linker
  99 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 100 dnl However, if the system happens to have more than one version of other
 101 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 102 dnl /usr and /usr/local) then the wrong one may get linked.
 103
 104 dnl To overcome this, we first check for libpq in the standard places, and
 105 dnl only set PG_LDFLAGS if it's not found.
 106
 107
 108 AC_ARG_WITH(
 109   libpq,
 110   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 111 AC_ARG_VAR([PG_CONFIG],
 112            [Full pathname of the pg_config program shipped with Postgresql])
 113 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 114              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 115
 116 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 117   AC_SUBST(PG_CONFIG)
 118   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 119   AC_SUBST(PG_CFLAGS)
 120
 121   AC_CHECK_LIB([pq], [PQexec],
 122      [:],
 123      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 124   AC_SUBST(PG_LDFLAGS)
 125
 126   PG_LIBS=-lpq
 127   AC_SUBST(PG_LIBS)
 128
 129   PKG_CHECK_EXISTS(libssl,
 130         AC_DEFINE([USE_SSL],1,
 131                    [Define to 1 if the openssl library is present.])
 132            ,)
 133
 134   # Now verify that we can actually link against libpq.  If we are
 135   # cross-compiling and picked up a host libpq, or if libpq is just
 136   # badly installed, this will fail.
 137   AC_CACHE_CHECK(
 138     [whether -lpq links successfully],
 139     [pspp_cv_have_libpq],
 140     [save_CPPFLAGS=$CPPFLAGS
 141      save_LIBS=$LIBS
 142      save_LDFLAGS=$LDFLAGS
 143      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 144      LIBS="$PG_LIBS $LIBS"
 145      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 146      AC_LINK_IFELSE(
 147        [AC_LANG_PROGRAM(
 148          [#include <libpq-fe.h>
 149          ], [PQfinish (0);])],
 150        [pspp_cv_have_libpq=yes],
 151        [pspp_cv_have_libpq=no])
 152      CPPFLAGS=$save_CPPFLAGS
 153      LIBS=$save_LIBS
 154      LDFLAGS=$save_LDFLAGS])
 155
 156   if test $pspp_cv_have_libpq = yes; then
 157     PSQL_SUPPORT=yes
 158     AC_DEFINE([PSQL_SUPPORT], [1],
 159       [Define to 1 if building in support for reading from postgres
 160        databases.])
 161   else
 162     PSQL_SUPPORT=no
 163     PG_CONFIG=
 164     PG_CFLAGS=
 165     PG_LDFLAGS=
 166     PG_LIBS=
 167   fi
 168 else
 169   PSQL_SUPPORT=no
 170   pspp_cv_have_libpq=no
 171 fi
 172 AC_SUBST([PSQL_SUPPORT])
 173
 174 dnl Check for libxml2
 175 PKG_CHECK_MODULES(
 176   [LIBXML2], [libxml-2.0],
 177   [HAVE_LIBXML2=yes],
 178   [HAVE_LIBXML2=no
 179    PSPP_OPTIONAL_PREREQ([libxml2])])
 180
 181 dnl Check for zlib.
 182 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 183 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 184
 185 dnl Avoid interference between zlib's crc32() function and gnulib's
 186 dnl crc32() function, which have different signatures.  PSPP calls
 187 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 188 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 189 dnl crc32(), then zlib will call gnulib's version instead of its own,
 190 dnl causing failures.  (This can happen even if zlib isn't detected
 191 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 192 dnl sometimes use zlib themselves.)
 193 AC_DEFINE(
 194   [crc32], [gl_crc32],
 195   [Avoid making zlib call gnulib's crc32() instead of its own.])
 196
 197 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 198 if test $HAVE_LIBXML2 = yes; then
 199   GNM_READ_SUPPORT=yes
 200   ODF_READ_SUPPORT=yes
 201   AC_DEFINE(
 202     [GNM_READ_SUPPORT], [1],
 203     [Define to 1 if building in support for reading Gnumeric files.])
 204   AC_DEFINE(
 205     [ODF_READ_SUPPORT], [1],
 206     [Define to 1 if building in support for reading OpenDocument files.])
 207 else
 208   GNM_READ_SUPPORT=no
 209   ODF_READ_SUPPORT=no
 210 fi
 211 AC_SUBST([GNM_READ_SUPPORT])
 212 AC_SUBST([ODF_READ_SUPPORT])
 213
 214 dnl ODF support requires libxml2 (zlib is optional).
 215 if test $HAVE_LIBXML2 = yes; then
 216   AC_DEFINE(
 217     [ODF_WRITE_SUPPORT], [1],
 218     [Define to 1 if building in support for writing OpenDocument files.])
 219 fi
 220 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 221
 222 AC_ARG_WITH(
 223   gui_tools,
 224   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 225 if test x"$with_gui_tools" = x"yes" ; then
 226         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 227 fi
 228 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 229
 230 AC_ARG_WITH(
 231   [perl-module],
 232   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 233   [case $with_perl_module in # (
 234      yes|no) ;; # (
 235      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 236    esac
 237    WITH_PERL_MODULE=$with_perl_module],
 238   [if test x"$cross_compiling" != x"yes"; then
 239      WITH_PERL_MODULE=yes
 240    else
 241      WITH_PERL_MODULE=no
 242    fi])
 243 AC_SUBST([WITH_PERL_MODULE])
 244 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 245
 246 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 247 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 248                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 249
 250
 251 PSPP_GSL_NEEDS_FGNU89_INLINE
 252
 253 dnl Recent versions of GNU ncurses install the curses header files into
 254 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 255 dnl enables us to discover where they are. Earlier versions don't have
 256 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 257 dnl we'll trust it to find the right information.  Otherwise, we'll
 258 dnl try to discover it ourselves.
 259 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 260 dnl to ncurses8-config !!!
 261 AC_ARG_WITH(
 262   libncurses,
 263   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 264
 265 if test x"$with_libncurses" != x"no" ; then
 266   if test x"$cross_compiling" != x"yes" ; then
 267           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 268   fi
 269   if test x"$NCURSES_CONFIG" = x ; then
 270           AC_SEARCH_LIBS([tgetent], [ncurses],
 271               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 272   else
 273           old_cflags=$CFLAGS
 274           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 275           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 276           CFLAGS=$old_cflags
 277           if test x"$curses_available" = x"yes" ; then
 278            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 279            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 280            AC_SUBST(NCURSES_CFLAGS)
 281            AC_SUBST(NCURSES_LIBS)
 282           fi
 283   fi
 284   if test x"$curses_available" = x"yes" ; then
 285           AC_DEFINE([LIBNCURSES_USABLE], 1,
 286               [Define to 1 if the libncurses is both present and usable.])
 287   fi
 288   AC_CHECK_HEADERS([termcap.h])
 289 fi
 290
 291 PSPP_READLINE
 292
 293 dnl Checks for header files.
 294 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 295
 296 dnl Some systems dont have SIGWINCH
 297 AC_CHECK_DECLS([SIGWINCH], [], [],
 298           [#include <signal.h>
 299           /* NetBSD declares sys_siglist in unistd.h.  */
 300           #ifdef HAVE_UNISTD_H
 301           # include <unistd.h>
 302           #endif
 303           ])
 304
 305
 306 # For gnulib.
 307 gl_INIT
 308
 309 AC_C_INLINE
 310
 311 AC_C_BIGENDIAN
 312
 313 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 314
 315 AC_PROG_LN_S
 316
 317 AC_ARG_ENABLE(
 318   debug,
 319   [AS_HELP_STRING([--enable-debug],
 320                   [Turn on diagnostic features in the program])])
 321 if test x"$enable_debug" = x"yes"  ; then
 322   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 323 fi
 324
 325 # iconv is required
 326 AM_ICONV
 327 if test "$am_cv_func_iconv" != "yes"; then
 328    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 329 fi
 330 LIBS="$LIBICONV $LIBS"
 331
 332 dnl Required by the gnulib 'relocatable-prog' module.
 333 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 334 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 335 RELOCATABLE_STRIP=:
 336
 337 PSPP_CHECK_PREREQS
 338
 339 AC_CONFIG_FILES(
 340   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 341
 342 AC_CONFIG_COMMANDS([doc/dummy], [:])
 343
 344 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 345
 346 AC_OUTPUT
 347 echo "PSPP configured successfully."
 348
 349 dnl configure.ac ends here