pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.5.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  40 PSPP_CHECK_DOT
  41
  42 PSPP_ENABLE_WERROR
  43
  44 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  45
  46 PSPP_CC_FOR_BUILD
  47 PSPP_PERL
  48 PSPP_PYTHON
  49 AC_CHECK_PROGS([TEX], [tex], [no])
  50 AC_SUBST([TEX])
  51 AC_CHECK_PROGS([GWC], [gwc wc], [no])
  52 AC_SUBST([GWC])
  53
  54 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  55 # avoided in GCC 10.x:
  56 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  57 #   cc1: error: function may return address of local variable
  58 CFLAGS="$CFLAGS -DGCC_LINT"
  59
  60 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  61 AC_PROVIDE([AM_PO_SUBDIRS])
  62 AM_GNU_GETTEXT([external], [need-ngettext])
  63 LIBS="$LIBINTL $LIBS"
  64 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  65 if test "x$MSGFMT" = x; then
  66   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  67 fi
  68
  69 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  70 if test "x$XGETTEXT" = x; then
  71   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  72 fi
  73 dnl appstream required for metainfo.its
  74 dnl if metainfo.its is not there, then the following small
  75 dnl file will not produce an outputfile
  76 $as_echo '<?xml version="1.0" encoding="UTF-8"?>' > test.metainfo.xml.in
  77 $as_echo '<component type="desktop">' >> test.metainfo.xml.in
  78 $as_echo '<name>Hallo</name>' >> test.metainfo.xml.in
  79 $as_echo '</component>' >> test.metainfo.xml.in
  80 xgettext -o mifc.po test.metainfo.xml.in
  81 if ! test -f ./mifc.po  ; then
  82   PSPP_OPTIONAL_PREREQ([org.fsf.metainfo.xml will not be translated. Install gettext >=0.20 or appstream.])
  83 fi
  84 rm -f mifc.po test.metainfo.xml.in
  85
  86 dnl Checks for libraries.
  87 AC_SYS_LARGEFILE
  88 AC_SEARCH_LIBS([sin], [m])
  89 PSPP_LC_PAPER
  90
  91
  92 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  93 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  94
  95 # Support for Cairo and Pango.
  96 AC_ARG_WITH([cairo],
  97   [AS_HELP_STRING(
  98     [--without-cairo],
  99     [Don't build support for charts (using Cairo and Pango);
 100      implies --without-gui])],
 101   [], [with_cairo=yes])
 102 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
 103 if test "$with_cairo" != no; then
 104   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 105     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
 106      AC_DEFINE([HAVE_CAIRO], 1,
 107        [Define to 1 if Cairo and Pango are available.])],
 108     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
 109 fi
 110
 111 dnl One of the tests uses xmllint.
 112 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 113 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 114   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 115     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 116     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 117    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 118
 119 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 120
 121 # Support for GUI.
 122 AC_ARG_WITH([gui],
 123   [AS_HELP_STRING([--without-gui],
 124                   [Don't build the PSPPIRE GUI (using GTK+)])],
 125   [], [with_gui=yes])
 126 AM_CONDITIONAL([building_gui],
 127                [test "$with_cairo" != no && test "$with_gui" != "no"])
 128 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 129   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 130     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 131
 132   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 133     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 134
 135   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 136     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 137
 138   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 139     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 140
 141   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 142     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 143   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 144
 145   AC_ARG_VAR([GLIB_GENMARSHAL])
 146   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 147   if test "x$GLIB_GENMARSHAL" = x; then
 148     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 149   fi
 150
 151   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 152   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 153     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 154   fi
 155
 156 fi
 157
 158 gl_NEXT_HEADERS([gtk/gtk.h])
 159
 160 dnl Checks needed for psql reader
 161
 162 dnl The 8.x series postgres tarballs installs with a default prefix of
 163 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 164
 165 dnl If the libpq.so file is in a non standard path, (one which the linker
 166 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 167 dnl However, if the system happens to have more than one version of other
 168 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 169 dnl /usr and /usr/local) then the wrong one may get linked.
 170
 171 dnl To overcome this, we first check for libpq in the standard places, and
 172 dnl only set PG_LDFLAGS if it's not found.
 173
 174
 175 AC_ARG_WITH(
 176   libpq,
 177   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 178 AC_ARG_VAR([PG_CONFIG],
 179            [Full pathname of the pg_config program shipped with Postgresql])
 180 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 181              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 182
 183 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 184   AC_SUBST(PG_CONFIG)
 185   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 186   AC_SUBST(PG_CFLAGS)
 187
 188   AC_CHECK_LIB([pq], [PQexec],
 189      [:],
 190      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 191   AC_SUBST(PG_LDFLAGS)
 192
 193   PG_LIBS=-lpq
 194   AC_SUBST(PG_LIBS)
 195
 196   PKG_CHECK_EXISTS(libssl,
 197         AC_DEFINE([USE_SSL],1,
 198                    [Define to 1 if the openssl library is present.])
 199            ,)
 200
 201   # Now verify that we can actually link against libpq.  If we are
 202   # cross-compiling and picked up a host libpq, or if libpq is just
 203   # badly installed, this will fail.
 204   AC_CACHE_CHECK(
 205     [whether -lpq links successfully],
 206     [pspp_cv_have_libpq],
 207     [save_CPPFLAGS=$CPPFLAGS
 208      save_LIBS=$LIBS
 209      save_LDFLAGS=$LDFLAGS
 210      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 211      LIBS="$PG_LIBS $LIBS"
 212      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 213      AC_LINK_IFELSE(
 214        [AC_LANG_PROGRAM(
 215          [#include <libpq-fe.h>
 216          ], [PQfinish (0);])],
 217        [pspp_cv_have_libpq=yes],
 218        [pspp_cv_have_libpq=no])
 219      CPPFLAGS=$save_CPPFLAGS
 220      LIBS=$save_LIBS
 221      LDFLAGS=$save_LDFLAGS])
 222
 223   if test $pspp_cv_have_libpq = yes; then
 224     PSQL_SUPPORT=yes
 225     AC_DEFINE([PSQL_SUPPORT], [1],
 226       [Define to 1 if building in support for reading from postgres
 227        databases.])
 228   else
 229     PSQL_SUPPORT=no
 230     PG_CONFIG=
 231     PG_CFLAGS=
 232     PG_LDFLAGS=
 233     PG_LIBS=
 234   fi
 235 else
 236   PSQL_SUPPORT=no
 237   pspp_cv_have_libpq=no
 238 fi
 239 AC_SUBST([PSQL_SUPPORT])
 240
 241 dnl Check for libxml2
 242 PKG_CHECK_MODULES(
 243   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 244
 245 dnl Check for zlib.
 246 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 247 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 248
 249 dnl Avoid interference between zlib's crc32() function and gnulib's
 250 dnl crc32() function, which have different signatures.  PSPP calls
 251 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 252 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 253 dnl crc32(), then zlib will call gnulib's version instead of its own,
 254 dnl causing failures.  (This can happen even if zlib isn't detected
 255 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 256 dnl sometimes use zlib themselves.)
 257 AC_DEFINE(
 258   [crc32], [gl_crc32],
 259   [Avoid making zlib call gnulib's crc32() instead of its own.])
 260
 261 AC_ARG_WITH(
 262   [perl-module],
 263   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 264   [case $with_perl_module in # (
 265      yes|no) ;; # (
 266      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 267    esac
 268    WITH_PERL_MODULE=$with_perl_module],
 269   [if test x"$cross_compiling" != x"yes"; then
 270      WITH_PERL_MODULE=yes
 271    else
 272      WITH_PERL_MODULE=no
 273    fi])
 274 AC_SUBST([WITH_PERL_MODULE])
 275 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 276
 277 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 278 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 279                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 280
 281
 282 PSPP_GSL_NEEDS_FGNU89_INLINE
 283
 284 PSPP_READLINE
 285
 286 dnl Checks for header files.
 287 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 288
 289 dnl Some systems don't have SIGWINCH
 290 AC_CHECK_DECLS([SIGWINCH], [], [],
 291           [#include <signal.h>
 292           /* NetBSD declares sys_siglist in unistd.h.  */
 293           #ifdef HAVE_UNISTD_H
 294           # include <unistd.h>
 295           #endif
 296           ])
 297
 298
 299 # For gnulib.
 300 gl_INIT
 301
 302 AC_C_INLINE
 303
 304 AC_C_BIGENDIAN
 305
 306 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 307
 308 AC_PROG_LN_S
 309
 310 # iconv is required
 311 AM_ICONV
 312 if test "$am_cv_func_iconv" != "yes"; then
 313    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 314 fi
 315 LIBS="$LIBICONV $LIBS"
 316
 317 dnl Required by the gnulib 'relocatable-prog' module.
 318 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 319 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 320 RELOCATABLE_STRIP=:
 321
 322 PSPP_CHECK_PREREQS
 323
 324 dnl The makefile needs to know if we're cross compiling, so that
 325 dnl it can make arrangements to build the documentation examples.
 326 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 327
 328 AC_CONFIG_FILES(
 329   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 330
 331 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 332
 333 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 334
 335 AC_OUTPUT
 336 echo "PSPP configured successfully."
 337
 338 dnl configure.ac ends here