pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LIBPLOT
  40 PSPP_LC_PAPER
  41
  42
  43 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  44 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  45
  46
  47 AC_ARG_WITH(
  48   gui,
  49   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  50
  51 required_gtk_version=2.12
  52
  53 if test x"$with_gui" != x"no" ; then
  54   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  55     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  56 fi
  57 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  58
  59
  60 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango pangocairo],
  61    [HAVE_CAIRO=yes
  62     CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  63     LIBS="$LIBPLOT_LIBS $LIBS"
  64     AC_DEFINE([HAVE_CAIRO], 1,
  65               [Define to 1 if Cairo and Pango are available.])],
  66    [HAVE_CAIRO=no
  67     PSPP_OPTIONAL_PREREQ([cairo 1.5 or later])])
  68 AM_CONDITIONAL([HAVE_CAIRO], [test $HAVE_CAIRO = yes])
  69
  70 dnl Checks needed for psql reader
  71
  72 dnl The 8.x series postgres tarballs installs with a default prefix of
  73 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  74
  75 dnl If the libpq.so file is in a non standard path, (one which the linker
  76 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  77 dnl However, if the system happens to have more than one version of other
  78 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  79 dnl /usr and /usr/local) then the wrong one may get linked.
  80
  81 dnl To overcome this, we first check for libpq in the standard places, and
  82 dnl only set PG_LDFLAGS if it's not found.
  83
  84
  85 AC_ARG_WITH(
  86   libpq,
  87   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  88
  89 if test x"$with_libpq" != x"no" ; then
  90  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  91
  92  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  93  if test x"$cross_compiling" != x"yes" ; then
  94    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  95  fi
  96  if test -n "$PG_CONFIG" ; then
  97    AC_SUBST(PG_CONFIG)
  98    AC_DEFINE([PSQL_SUPPORT], 1,
  99    [Define to 1 if building in support for reading from postgres databases.])
 100    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 101    AC_SUBST(PG_CFLAGS)
 102
 103    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 104       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 105    fi
 106    AC_SUBST(PG_LDFLAGS)
 107
 108    PG_LIBS=-lpq
 109    AC_SUBST(PG_LIBS)
 110    PKG_CHECK_EXISTS(libssl,
 111          AC_DEFINE([USE_SSL],1,
 112                     [Define to 1 if the openssl library is present.])
 113             ,)
 114  fi
 115 fi
 116 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 117
 118 dnl Checks needed for gnumeric reader
 119 gnm_support=yes;
 120 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 121                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 122 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 123 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 124
 125 if test x"$gnm_support" = x"yes" ; then
 126    AC_DEFINE([GNM_SUPPORT], 1,
 127    [Define to 1 if building in support for reading Gnumeric files.])
 128 fi
 129 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 130
 131 AC_ARG_WITH(
 132   gui_tools,
 133   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 134 if test x"$with_gui_tools" = x"yes" ; then
 135         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 136 fi
 137 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 138
 139 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 140
 141 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 142 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 143 PSPP_GSL_NEEDS_FGNU89_INLINE
 144
 145 dnl Recent versions of GNU ncurses install the curses header files into
 146 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 147 dnl enables us to discover where they are. Earlier versions don't have
 148 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 149 dnl we'll trust it to find the right information.  Otherwise, we'll
 150 dnl try to discover it ourselves.
 151 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 152 dnl to ncurses8-config !!!
 153 AC_ARG_WITH(
 154   libncurses,
 155   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 156
 157 if test x"$with_libncurses" != x"no" ; then
 158   if test x"$cross_compiling" != x"yes" ; then
 159           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 160   fi
 161   if test x"$NCURSES_CONFIG" = x ; then
 162           AC_SEARCH_LIBS([tgetent], [ncurses],
 163               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 164   else
 165           old_cflags=$CFLAGS
 166           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 167           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 168           CFLAGS=$old_cflags
 169           if test x"$curses_available" = x"yes" ; then
 170            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 171            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 172            AC_SUBST(NCURSES_CFLAGS)
 173            AC_SUBST(NCURSES_LIBS)
 174           fi
 175   fi
 176   if test x"$curses_available" = x"yes" ; then
 177           AC_DEFINE([LIBNCURSES_USABLE], 1,
 178               [Define to 1 if the libncurses is both present and usable.])
 179   fi
 180   AC_CHECK_HEADERS([termcap.h])
 181 fi
 182
 183 PSPP_READLINE
 184
 185 dnl Checks for header files.
 186 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 187
 188 # For gnulib.
 189 gl_INIT
 190
 191 AC_C_INLINE
 192
 193 AC_CHECK_SIZEOF(double)
 194
 195 AC_C_BIGENDIAN
 196
 197 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 198
 199 AC_PROG_LN_S
 200
 201 AC_ARG_ENABLE(
 202   debug,
 203   [AS_HELP_STRING([--enable-debug],
 204                   [Turn on diagnostic features in the program])])
 205 if test x"$enable_debug" = x"yes"  ; then
 206   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 207 fi
 208
 209 # iconv is required
 210 if test "$am_cv_func_iconv" != "yes"; then
 211    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 212 fi
 213
 214 PSPP_CHECK_PREREQS
 215
 216 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 217
 218 AC_OUTPUT
 219 echo "PSPP configured successfully."
 220
 221 dnl configure.ac ends here