pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017, 2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.5.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 if test x"$cross_compiling" = x"yes"; then
  32    if test x"$srcdir" = x"."; then
  33       AC_ERROR([Cross compiling must be done out of source.])
  34    fi
  35 fi
  36
  37 AM_PROG_CC_C_O
  38 AC_LIBTOOL_WIN32_DLL
  39 AC_LIBTOOL_DLOPEN
  40 AC_PROG_LIBTOOL
  41 AC_HEADER_TIOCGWINSZ
  42 PKG_PROG_PKG_CONFIG
  43 m4_pattern_forbid([PKG_CHECK_MODULES])
  44 PSPP_CHECK_CLICKSEQUENCE
  45 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  46 PSPP_CHECK_DOT
  47
  48 PSPP_ENABLE_WERROR
  49
  50 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  51
  52 PSPP_PERL
  53 PSPP_PYTHON
  54 AC_CHECK_PROGS([TEX], [tex], [no])
  55 AC_SUBST([TEX])
  56 AC_CHECK_PROGS([GWC], [gwc wc], [no])
  57 AC_SUBST([GWC])
  58
  59 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  60 # avoided in GCC 10.x:
  61 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  62 #   cc1: error: function may return address of local variable
  63 CFLAGS="$CFLAGS -DGCC_LINT"
  64
  65 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  66 AC_PROVIDE([AM_PO_SUBDIRS])
  67 AM_GNU_GETTEXT([external], [need-ngettext])
  68
  69 LIBS="$LIBINTL $LIBS"
  70 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  71 if test "x$MSGFMT" = x; then
  72   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  73 fi
  74
  75 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  76 if test "x$XGETTEXT" = x; then
  77   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  78 fi
  79
  80 PSPP_CHECK_XGETTEXT
  81
  82 if test "$pspp_cv_progrecent_xgettext"  != "yes"; then
  83    PSPP_REQUIRED_PREREQ([xgettext version 0.20 or greater])
  84 fi
  85
  86 dnl Checks for libraries.
  87 AC_SYS_LARGEFILE
  88 AC_SEARCH_LIBS([sin], [m])
  89 PSPP_LC_PAPER
  90
  91
  92 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  93 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  94
  95 # Support for Cairo and Pango.
  96 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  97   [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"],
  98   [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later])])
  99
 100 dnl One of the tests uses xmllint.
 101 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 102 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 103   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 104     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 105     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 106    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 107
 108 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 109
 110 # Support for GUI.
 111 AC_ARG_WITH([gui],
 112   [AS_HELP_STRING([--without-gui],
 113                   [Don't build the PSPPIRE GUI (using GTK+)])],
 114   [], [with_gui=yes])
 115 AM_CONDITIONAL([building_gui], [test "$with_gui" != "no"])
 116 if test "$with_gui" != "no"; then
 117   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 118     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 119
 120   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 121     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 122
 123   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 124     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 125
 126   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 127     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 128
 129   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 130     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 131   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 132
 133   AC_ARG_VAR([GLIB_GENMARSHAL])
 134   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 135   if test "x$GLIB_GENMARSHAL" = x; then
 136     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 137   fi
 138
 139   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 140   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 141     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 142   fi
 143
 144 fi
 145
 146 gl_NEXT_HEADERS([gtk/gtk.h])
 147
 148 dnl Checks needed for psql reader
 149
 150 dnl The 8.x series postgres tarballs installs with a default prefix of
 151 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 152
 153 dnl If the libpq.so file is in a non standard path, (one which the linker
 154 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 155 dnl However, if the system happens to have more than one version of other
 156 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 157 dnl /usr and /usr/local) then the wrong one may get linked.
 158
 159 dnl To overcome this, we first check for libpq in the standard places, and
 160 dnl only set PG_LDFLAGS if it's not found.
 161
 162
 163 AC_ARG_WITH(
 164   libpq,
 165   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 166 AC_ARG_VAR([PG_CONFIG],
 167            [Full pathname of the pg_config program shipped with Postgresql])
 168 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 169              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 170
 171 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 172   AC_SUBST(PG_CONFIG)
 173   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 174   AC_SUBST(PG_CFLAGS)
 175
 176   AC_CHECK_LIB([pq], [PQexec],
 177      [:],
 178      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 179   AC_SUBST(PG_LDFLAGS)
 180
 181   PG_LIBS=-lpq
 182   AC_SUBST(PG_LIBS)
 183
 184   PKG_CHECK_EXISTS(libssl,
 185         AC_DEFINE([USE_SSL],1,
 186                    [Define to 1 if the openssl library is present.])
 187            ,)
 188
 189   # Now verify that we can actually link against libpq.  If we are
 190   # cross-compiling and picked up a host libpq, or if libpq is just
 191   # badly installed, this will fail.
 192   AC_CACHE_CHECK(
 193     [whether -lpq links successfully],
 194     [pspp_cv_have_libpq],
 195     [save_CPPFLAGS=$CPPFLAGS
 196      save_LIBS=$LIBS
 197      save_LDFLAGS=$LDFLAGS
 198      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 199      LIBS="$PG_LIBS $LIBS"
 200      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 201      AC_LINK_IFELSE(
 202        [AC_LANG_PROGRAM(
 203          [#include <libpq-fe.h>
 204          ], [PQfinish (0);])],
 205        [pspp_cv_have_libpq=yes],
 206        [pspp_cv_have_libpq=no])
 207      CPPFLAGS=$save_CPPFLAGS
 208      LIBS=$save_LIBS
 209      LDFLAGS=$save_LDFLAGS])
 210
 211   if test $pspp_cv_have_libpq = yes; then
 212     PSQL_SUPPORT=yes
 213     AC_DEFINE([PSQL_SUPPORT], [1],
 214       [Define to 1 if building in support for reading from postgres
 215        databases.])
 216   else
 217     PSQL_SUPPORT=no
 218     PG_CONFIG=
 219     PG_CFLAGS=
 220     PG_LDFLAGS=
 221     PG_LIBS=
 222   fi
 223 else
 224   PSQL_SUPPORT=no
 225   pspp_cv_have_libpq=no
 226 fi
 227 AC_SUBST([PSQL_SUPPORT])
 228
 229 dnl Check for libxml2
 230 PKG_CHECK_MODULES(
 231   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 232
 233 dnl Check for zlib.
 234 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 235 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 236
 237 dnl Avoid interference between zlib's crc32() function and gnulib's
 238 dnl crc32() function, which have different signatures.  PSPP calls
 239 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 240 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 241 dnl crc32(), then zlib will call gnulib's version instead of its own,
 242 dnl causing failures.  (This can happen even if zlib isn't detected
 243 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 244 dnl sometimes use zlib themselves.)
 245 AC_DEFINE(
 246   [crc32], [gl_crc32],
 247   [Avoid making zlib call gnulib's crc32() instead of its own.])
 248
 249 AC_ARG_WITH(
 250   [perl-module],
 251   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 252   [case $with_perl_module in # (
 253      yes|no) ;; # (
 254      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 255    esac
 256    WITH_PERL_MODULE=$with_perl_module],
 257   [if test x"$cross_compiling" != x"yes"; then
 258      WITH_PERL_MODULE=yes
 259    else
 260      WITH_PERL_MODULE=no
 261    fi])
 262 AC_SUBST([WITH_PERL_MODULE])
 263 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 264
 265 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 266 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 267                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 268
 269
 270 PSPP_GSL_NEEDS_FGNU89_INLINE
 271
 272 PSPP_READLINE
 273
 274 dnl Checks for header files.
 275 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 276
 277 dnl Some systems don't have SIGWINCH
 278 AC_CHECK_DECLS([SIGWINCH], [], [],
 279           [#include <signal.h>
 280           /* NetBSD declares sys_siglist in unistd.h.  */
 281           #ifdef HAVE_UNISTD_H
 282           # include <unistd.h>
 283           #endif
 284           ])
 285
 286
 287 # For gnulib.
 288 gl_INIT
 289
 290 AC_C_INLINE
 291
 292 AC_C_BIGENDIAN
 293
 294 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 295
 296 AC_PROG_LN_S
 297
 298 # iconv is required
 299 AM_ICONV
 300 if test "$am_cv_func_iconv" != "yes"; then
 301    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 302 fi
 303 LIBS="$LIBICONV $LIBS"
 304
 305 dnl Required by the gnulib 'relocatable-prog' module.
 306 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 307 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 308 RELOCATABLE_STRIP=:
 309
 310 PSPP_CHECK_PREREQS
 311
 312 dnl The makefile needs to know if we're cross compiling, so that
 313 dnl it can make arrangements to build the documentation examples.
 314 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 315
 316 AC_CONFIG_FILES(
 317   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 318
 319 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 320
 321 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 322
 323 AC_OUTPUT
 324 echo "PSPP configured successfully."
 325
 326 dnl configure.ac ends here