pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.9.0], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22 PSPP_CHECK_DOT
  23
  24 PSPP_ENABLE_WERROR
  25
  26 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  27
  28 PSPP_CC_FOR_BUILD
  29 PSPP_PERL
  30
  31 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  32 AC_PROVIDE([AM_PO_SUBDIRS])
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 LIBS="$LIBINTL $LIBS"
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LC_PAPER
  40
  41
  42 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  43 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  44
  45 # Support for Cairo and Pango.
  46 AC_ARG_WITH([cairo],
  47   [AS_HELP_STRING(
  48     [--without-cairo],
  49     [Don't build support for charts (using Cairo and Pango);
  50      implies --without-gui])],
  51   [], [with_cairo=yes])
  52 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  53 if test "$with_cairo" != no; then
  54   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  55     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  56      AC_DEFINE([HAVE_CAIRO], 1,
  57        [Define to 1 if Cairo and Pango are available.])],
  58     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  59 fi
  60
  61 dnl Xmllint is used in the rules to build the documentation.  It is not actually necessary,
  62 dnl but is used for post-build consistency checks.  Thus, non-developers can live without it.
  63 dnl However for it to be usefull, it needs to be a certain version and have certain features.
  64 dnl The macros below check that it the xmllint available is up to scratch.  If it isn't
  65 dnl then a dummy /bin/echo is subsituted instead.
  66
  67 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  68 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  69   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  70     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  71     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  72    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  73
  74 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  75
  76 # Support for GUI.
  77 AC_ARG_WITH([gui],
  78   [AS_HELP_STRING([--without-gui],
  79                   [Don't build the PSPPIRE GUI (using GTK+)])],
  80   [], [with_gui=yes])
  81 AM_CONDITIONAL([HAVE_GUI],
  82                [test "$with_cairo" != no && test "$with_gui" != "no"])
  83 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  84   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  85     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  86
  87   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.2], [],
  88     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.4.2 or later (or use --without-gui)])])
  89
  90   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
  91     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
  92
  93   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
  94     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
  95
  96   AC_ARG_VAR([GLIB_GENMARSHAL])
  97   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  98   if test "x$GLIB_GENMARSHAL" = x; then
  99     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 100   fi
 101
 102 fi
 103
 104 gl_NEXT_HEADERS([gtk/gtk.h])
 105
 106 dnl Checks needed for psql reader
 107
 108 dnl The 8.x series postgres tarballs installs with a default prefix of
 109 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 110
 111 dnl If the libpq.so file is in a non standard path, (one which the linker
 112 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 113 dnl However, if the system happens to have more than one version of other
 114 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 115 dnl /usr and /usr/local) then the wrong one may get linked.
 116
 117 dnl To overcome this, we first check for libpq in the standard places, and
 118 dnl only set PG_LDFLAGS if it's not found.
 119
 120
 121 AC_ARG_WITH(
 122   libpq,
 123   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 124 AC_ARG_VAR([PG_CONFIG],
 125            [Full pathname of the pg_config program shipped with Postgresql])
 126 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 127              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 128
 129 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 130   AC_SUBST(PG_CONFIG)
 131   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 132   AC_SUBST(PG_CFLAGS)
 133
 134   AC_CHECK_LIB([pq], [PQexec],
 135      [:],
 136      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 137   AC_SUBST(PG_LDFLAGS)
 138
 139   PG_LIBS=-lpq
 140   AC_SUBST(PG_LIBS)
 141
 142   PKG_CHECK_EXISTS(libssl,
 143         AC_DEFINE([USE_SSL],1,
 144                    [Define to 1 if the openssl library is present.])
 145            ,)
 146
 147   # Now verify that we can actually link against libpq.  If we are
 148   # cross-compiling and picked up a host libpq, or if libpq is just
 149   # badly installed, this will fail.
 150   AC_CACHE_CHECK(
 151     [whether -lpq links successfully],
 152     [pspp_cv_have_libpq],
 153     [save_CPPFLAGS=$CPPFLAGS
 154      save_LIBS=$LIBS
 155      save_LDFLAGS=$LDFLAGS
 156      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 157      LIBS="$PG_LIBS $LIBS"
 158      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 159      AC_LINK_IFELSE(
 160        [AC_LANG_PROGRAM(
 161          [#include <libpq-fe.h>
 162          ], [PQfinish (0);])],
 163        [pspp_cv_have_libpq=yes],
 164        [pspp_cv_have_libpq=no])
 165      CPPFLAGS=$save_CPPFLAGS
 166      LIBS=$save_LIBS
 167      LDFLAGS=$save_LDFLAGS])
 168
 169   if test $pspp_cv_have_libpq = yes; then
 170     PSQL_SUPPORT=yes
 171     AC_DEFINE([PSQL_SUPPORT], [1],
 172       [Define to 1 if building in support for reading from postgres
 173        databases.])
 174   else
 175     PSQL_SUPPORT=no
 176     PG_CONFIG=
 177     PG_CFLAGS=
 178     PG_LDFLAGS=
 179     PG_LIBS=
 180   fi
 181 else
 182   PSQL_SUPPORT=no
 183   pspp_cv_have_libpq=no
 184 fi
 185 AC_SUBST([PSQL_SUPPORT])
 186
 187 dnl Check for libxml2
 188 PKG_CHECK_MODULES(
 189   [LIBXML2], [libxml-2.0],
 190   [HAVE_LIBXML2=yes],
 191   [HAVE_LIBXML2=no
 192    PSPP_OPTIONAL_PREREQ([libxml2])])
 193
 194 dnl Check for zlib.
 195 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 196 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 197
 198 dnl Avoid interference between zlib's crc32() function and gnulib's
 199 dnl crc32() function, which have different signatures.  PSPP calls
 200 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 201 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 202 dnl crc32(), then zlib will call gnulib's version instead of its own,
 203 dnl causing failures.  (This can happen even if zlib isn't detected
 204 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 205 dnl sometimes use zlib themselves.)
 206 AC_DEFINE(
 207   [crc32], [gl_crc32],
 208   [Avoid making zlib call gnulib's crc32() instead of its own.])
 209
 210 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 211 if test $HAVE_LIBXML2 = yes; then
 212   GNM_READ_SUPPORT=yes
 213   ODF_READ_SUPPORT=yes
 214   AC_DEFINE(
 215     [GNM_READ_SUPPORT], [1],
 216     [Define to 1 if building in support for reading Gnumeric files.])
 217   AC_DEFINE(
 218     [ODF_READ_SUPPORT], [1],
 219     [Define to 1 if building in support for reading OpenDocument files.])
 220 else
 221   GNM_READ_SUPPORT=no
 222   ODF_READ_SUPPORT=no
 223 fi
 224 AC_SUBST([GNM_READ_SUPPORT])
 225 AC_SUBST([ODF_READ_SUPPORT])
 226
 227 dnl ODF support requires libxml2 (zlib is optional).
 228 if test $HAVE_LIBXML2 = yes; then
 229   AC_DEFINE(
 230     [ODF_WRITE_SUPPORT], [1],
 231     [Define to 1 if building in support for writing OpenDocument files.])
 232 fi
 233 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 234
 235 AC_ARG_WITH(
 236   gui_tools,
 237   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 238 if test x"$with_gui_tools" = x"yes" ; then
 239         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 240 fi
 241 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 242
 243 AC_ARG_WITH(
 244   [perl-module],
 245   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 246   [case $with_perl_module in # (
 247      yes|no) ;; # (
 248      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 249    esac
 250    WITH_PERL_MODULE=$with_perl_module],
 251   [if test x"$cross_compiling" != x"yes"; then
 252      WITH_PERL_MODULE=yes
 253    else
 254      WITH_PERL_MODULE=no
 255    fi])
 256 AC_SUBST([WITH_PERL_MODULE])
 257 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 258
 259 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 260 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 261                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 262
 263
 264 PSPP_GSL_NEEDS_FGNU89_INLINE
 265
 266 dnl Recent versions of GNU ncurses install the curses header files into
 267 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 268 dnl enables us to discover where they are. Earlier versions don't have
 269 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 270 dnl we'll trust it to find the right information.  Otherwise, we'll
 271 dnl try to discover it ourselves.
 272 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 273 dnl to ncurses8-config !!!
 274 AC_ARG_WITH(
 275   libncurses,
 276   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 277
 278 if test x"$with_libncurses" != x"no" ; then
 279   if test x"$cross_compiling" != x"yes" ; then
 280           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 281   fi
 282   if test x"$NCURSES_CONFIG" = x ; then
 283           AC_SEARCH_LIBS([tgetent], [ncurses],
 284               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 285   else
 286           old_cflags=$CFLAGS
 287           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 288           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 289           CFLAGS=$old_cflags
 290           if test x"$curses_available" = x"yes" ; then
 291            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 292            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 293            AC_SUBST(NCURSES_CFLAGS)
 294            AC_SUBST(NCURSES_LIBS)
 295           fi
 296   fi
 297   if test x"$curses_available" = x"yes" ; then
 298           AC_DEFINE([LIBNCURSES_USABLE], 1,
 299               [Define to 1 if the libncurses is both present and usable.])
 300   fi
 301   AC_CHECK_HEADERS([termcap.h])
 302 fi
 303
 304 PSPP_READLINE
 305
 306 dnl Checks for header files.
 307 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 308
 309 dnl Some systems dont have SIGWINCH
 310 AC_CHECK_DECLS([SIGWINCH], [], [],
 311           [#include <signal.h>
 312           /* NetBSD declares sys_siglist in unistd.h.  */
 313           #ifdef HAVE_UNISTD_H
 314           # include <unistd.h>
 315           #endif
 316           ])
 317
 318
 319 # For gnulib.
 320 gl_INIT
 321
 322 AC_C_INLINE
 323
 324 AC_C_BIGENDIAN
 325
 326 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 327
 328 AC_PROG_LN_S
 329
 330 AC_ARG_ENABLE(
 331   debug,
 332   [AS_HELP_STRING([--enable-debug],
 333                   [Turn on diagnostic features in the program])])
 334 if test x"$enable_debug" = x"yes"  ; then
 335   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 336 fi
 337
 338 # iconv is required
 339 AM_ICONV
 340 if test "$am_cv_func_iconv" != "yes"; then
 341    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 342 fi
 343 LIBS="$LIBICONV $LIBS"
 344
 345 dnl Required by the gnulib 'relocatable-prog' module.
 346 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 347 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 348 RELOCATABLE_STRIP=:
 349
 350 PSPP_CHECK_PREREQS
 351
 352 AC_CONFIG_FILES(
 353   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 354
 355 AC_CONFIG_COMMANDS([doc/dummy], [:])
 356
 357 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 358
 359 AC_OUTPUT
 360 echo "PSPP configured successfully."
 361
 362 dnl configure.ac ends here