pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.63)
  21 AC_INIT([GNU PSPP], [1.2.0], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  40 PSPP_CHECK_DOT
  41
  42 PSPP_ENABLE_WERROR
  43
  44 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  45
  46 PSPP_CC_FOR_BUILD
  47 PSPP_PERL
  48 PSPP_PYTHON
  49
  50 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  51 AC_PROVIDE([AM_PO_SUBDIRS])
  52 AM_GNU_GETTEXT([external], [need-ngettext])
  53 LIBS="$LIBINTL $LIBS"
  54 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  55 if test "x$MSGFMT" = x; then
  56   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  57 fi
  58
  59
  60 dnl Checks for libraries.
  61 AC_SYS_LARGEFILE
  62 AC_SEARCH_LIBS([sin], [m])
  63 PSPP_LC_PAPER
  64
  65
  66 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  67 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  68
  69 # Support for Cairo and Pango.
  70 AC_ARG_WITH([cairo],
  71   [AS_HELP_STRING(
  72     [--without-cairo],
  73     [Don't build support for charts (using Cairo and Pango);
  74      implies --without-gui])],
  75   [], [with_cairo=yes])
  76 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  77 if test "$with_cairo" != no; then
  78   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  79     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  80      AC_DEFINE([HAVE_CAIRO], 1,
  81        [Define to 1 if Cairo and Pango are available.])],
  82     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  83 fi
  84
  85 dnl One of the tests uses xmllint.
  86 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  87 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  88   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  89     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  90     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  91    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  92
  93 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  94
  95 # Support for GUI.
  96 AC_ARG_WITH([gui],
  97   [AS_HELP_STRING([--without-gui],
  98                   [Don't build the PSPPIRE GUI (using GTK+)])],
  99   [], [with_gui=yes])
 100 AM_CONDITIONAL([HAVE_GUI],
 101                [test "$with_cairo" != no && test "$with_gui" != "no"])
 102 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 103   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 104     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 105
 106   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.18.0], [],
 107     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.18.0 or later (or use --without-gui)])])
 108
 109   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 110     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 111
 112   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 113     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 114
 115   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.3], [],
 116     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.3 (or use --without-gui)])])
 117
 118   AC_ARG_VAR([GLIB_GENMARSHAL])
 119   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 120   if test "x$GLIB_GENMARSHAL" = x; then
 121     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 122   fi
 123
 124   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 125   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 126     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 127   fi
 128
 129 fi
 130
 131 gl_NEXT_HEADERS([gtk/gtk.h])
 132
 133 dnl Checks needed for psql reader
 134
 135 dnl The 8.x series postgres tarballs installs with a default prefix of
 136 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 137
 138 dnl If the libpq.so file is in a non standard path, (one which the linker
 139 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 140 dnl However, if the system happens to have more than one version of other
 141 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 142 dnl /usr and /usr/local) then the wrong one may get linked.
 143
 144 dnl To overcome this, we first check for libpq in the standard places, and
 145 dnl only set PG_LDFLAGS if it's not found.
 146
 147
 148 AC_ARG_WITH(
 149   libpq,
 150   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 151 AC_ARG_VAR([PG_CONFIG],
 152            [Full pathname of the pg_config program shipped with Postgresql])
 153 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 154              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 155
 156 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 157   AC_SUBST(PG_CONFIG)
 158   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 159   AC_SUBST(PG_CFLAGS)
 160
 161   AC_CHECK_LIB([pq], [PQexec],
 162      [:],
 163      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 164   AC_SUBST(PG_LDFLAGS)
 165
 166   PG_LIBS=-lpq
 167   AC_SUBST(PG_LIBS)
 168
 169   PKG_CHECK_EXISTS(libssl,
 170         AC_DEFINE([USE_SSL],1,
 171                    [Define to 1 if the openssl library is present.])
 172            ,)
 173
 174   # Now verify that we can actually link against libpq.  If we are
 175   # cross-compiling and picked up a host libpq, or if libpq is just
 176   # badly installed, this will fail.
 177   AC_CACHE_CHECK(
 178     [whether -lpq links successfully],
 179     [pspp_cv_have_libpq],
 180     [save_CPPFLAGS=$CPPFLAGS
 181      save_LIBS=$LIBS
 182      save_LDFLAGS=$LDFLAGS
 183      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 184      LIBS="$PG_LIBS $LIBS"
 185      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 186      AC_LINK_IFELSE(
 187        [AC_LANG_PROGRAM(
 188          [#include <libpq-fe.h>
 189          ], [PQfinish (0);])],
 190        [pspp_cv_have_libpq=yes],
 191        [pspp_cv_have_libpq=no])
 192      CPPFLAGS=$save_CPPFLAGS
 193      LIBS=$save_LIBS
 194      LDFLAGS=$save_LDFLAGS])
 195
 196   if test $pspp_cv_have_libpq = yes; then
 197     PSQL_SUPPORT=yes
 198     AC_DEFINE([PSQL_SUPPORT], [1],
 199       [Define to 1 if building in support for reading from postgres
 200        databases.])
 201   else
 202     PSQL_SUPPORT=no
 203     PG_CONFIG=
 204     PG_CFLAGS=
 205     PG_LDFLAGS=
 206     PG_LIBS=
 207   fi
 208 else
 209   PSQL_SUPPORT=no
 210   pspp_cv_have_libpq=no
 211 fi
 212 AC_SUBST([PSQL_SUPPORT])
 213
 214 dnl Check for libxml2
 215 PKG_CHECK_MODULES(
 216   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 217
 218 dnl Check for zlib.
 219 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 220 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 221
 222 dnl Avoid interference between zlib's crc32() function and gnulib's
 223 dnl crc32() function, which have different signatures.  PSPP calls
 224 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 225 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 226 dnl crc32(), then zlib will call gnulib's version instead of its own,
 227 dnl causing failures.  (This can happen even if zlib isn't detected
 228 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 229 dnl sometimes use zlib themselves.)
 230 AC_DEFINE(
 231   [crc32], [gl_crc32],
 232   [Avoid making zlib call gnulib's crc32() instead of its own.])
 233
 234 AC_ARG_WITH(
 235   gui_tools,
 236   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 237 if test x"$with_gui_tools" = x"yes" ; then
 238         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 239 fi
 240 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 241
 242 AC_ARG_WITH(
 243   [perl-module],
 244   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 245   [case $with_perl_module in # (
 246      yes|no) ;; # (
 247      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 248    esac
 249    WITH_PERL_MODULE=$with_perl_module],
 250   [if test x"$cross_compiling" != x"yes"; then
 251      WITH_PERL_MODULE=yes
 252    else
 253      WITH_PERL_MODULE=no
 254    fi])
 255 AC_SUBST([WITH_PERL_MODULE])
 256 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 257
 258 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 259 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 260                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 261
 262
 263 PSPP_GSL_NEEDS_FGNU89_INLINE
 264
 265 PSPP_READLINE
 266
 267 dnl Checks for header files.
 268 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 269
 270 dnl Some systems don't have SIGWINCH
 271 AC_CHECK_DECLS([SIGWINCH], [], [],
 272           [#include <signal.h>
 273           /* NetBSD declares sys_siglist in unistd.h.  */
 274           #ifdef HAVE_UNISTD_H
 275           # include <unistd.h>
 276           #endif
 277           ])
 278
 279
 280 # For gnulib.
 281 gl_INIT
 282
 283 AC_C_INLINE
 284
 285 AC_C_BIGENDIAN
 286
 287 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 288
 289 AC_PROG_LN_S
 290
 291 AC_ARG_ENABLE(
 292   debug,
 293   [AS_HELP_STRING([--enable-debug],
 294                   [Turn on diagnostic features in the program])])
 295 if test x"$enable_debug" = x"yes"  ; then
 296   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 297 fi
 298
 299 # iconv is required
 300 AM_ICONV
 301 if test "$am_cv_func_iconv" != "yes"; then
 302    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 303 fi
 304 LIBS="$LIBICONV $LIBS"
 305
 306 dnl Required by the gnulib 'relocatable-prog' module.
 307 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 308 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 309 RELOCATABLE_STRIP=:
 310
 311 PSPP_CHECK_PREREQS
 312
 313 AC_CONFIG_FILES(
 314   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 315
 316 AC_CONFIG_COMMANDS([doc/dummy], [:])
 317
 318 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 319
 320 AC_OUTPUT
 321 echo "PSPP configured successfully."
 322
 323 dnl configure.ac ends here