pintos-os.org Git - pspp/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.9.0], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_WERROR
  24
  25 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  26
  27 PSPP_CC_FOR_BUILD
  28 PSPP_PERL
  29
  30 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  31 AC_PROVIDE([AM_PO_SUBDIRS])
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 LIBS="$LIBINTL $LIBS"
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LC_PAPER
  39
  40
  41 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  42 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  43
  44 # Support for Cairo and Pango.
  45 AC_ARG_WITH([cairo],
  46   [AS_HELP_STRING(
  47     [--without-cairo],
  48     [Don't build support for charts (using Cairo and Pango);
  49      implies --without-gui])],
  50   [], [with_cairo=yes])
  51 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  52 if test "$with_cairo" != no; then
  53   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  54     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  55      AC_DEFINE([HAVE_CAIRO], 1,
  56        [Define to 1 if Cairo and Pango are available.])],
  57     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  58 fi
  59
  60 dnl Xmllint may be required to build the documentation
  61 AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  62 AC_SUBST(XMLLINT)
  63
  64 # Support for GUI.
  65 AC_ARG_WITH([gui],
  66   [AS_HELP_STRING([--without-gui],
  67                   [Don't build the PSPPIRE GUI (using GTK+)])],
  68   [], [with_gui=yes])
  69 AM_CONDITIONAL([HAVE_GUI],
  70                [test "$with_cairo" != no && test "$with_gui" != "no"])
  71 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  72   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  73     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  74
  75   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.2], [],
  76     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.4.2 or later (or use --without-gui)])])
  77
  78   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
  79     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
  80
  81   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
  82     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
  83
  84   AC_ARG_VAR([GLIB_GENMARSHAL])
  85   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  86   if test "x$GLIB_GENMARSHAL" = x; then
  87     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  88   fi
  89
  90 fi
  91
  92 gl_NEXT_HEADERS([gtk/gtk.h])
  93
  94 dnl Checks needed for psql reader
  95
  96 dnl The 8.x series postgres tarballs installs with a default prefix of
  97 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  98
  99 dnl If the libpq.so file is in a non standard path, (one which the linker
 100 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 101 dnl However, if the system happens to have more than one version of other
 102 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 103 dnl /usr and /usr/local) then the wrong one may get linked.
 104
 105 dnl To overcome this, we first check for libpq in the standard places, and
 106 dnl only set PG_LDFLAGS if it's not found.
 107
 108
 109 AC_ARG_WITH(
 110   libpq,
 111   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 112 AC_ARG_VAR([PG_CONFIG],
 113            [Full pathname of the pg_config program shipped with Postgresql])
 114 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 115              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 116
 117 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 118   AC_SUBST(PG_CONFIG)
 119   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 120   AC_SUBST(PG_CFLAGS)
 121
 122   AC_CHECK_LIB([pq], [PQexec],
 123      [:],
 124      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 125   AC_SUBST(PG_LDFLAGS)
 126
 127   PG_LIBS=-lpq
 128   AC_SUBST(PG_LIBS)
 129
 130   PKG_CHECK_EXISTS(libssl,
 131         AC_DEFINE([USE_SSL],1,
 132                    [Define to 1 if the openssl library is present.])
 133            ,)
 134
 135   # Now verify that we can actually link against libpq.  If we are
 136   # cross-compiling and picked up a host libpq, or if libpq is just
 137   # badly installed, this will fail.
 138   AC_CACHE_CHECK(
 139     [whether -lpq links successfully],
 140     [pspp_cv_have_libpq],
 141     [save_CPPFLAGS=$CPPFLAGS
 142      save_LIBS=$LIBS
 143      save_LDFLAGS=$LDFLAGS
 144      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 145      LIBS="$PG_LIBS $LIBS"
 146      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 147      AC_LINK_IFELSE(
 148        [AC_LANG_PROGRAM(
 149          [#include <libpq-fe.h>
 150          ], [PQfinish (0);])],
 151        [pspp_cv_have_libpq=yes],
 152        [pspp_cv_have_libpq=no])
 153      CPPFLAGS=$save_CPPFLAGS
 154      LIBS=$save_LIBS
 155      LDFLAGS=$save_LDFLAGS])
 156
 157   if test $pspp_cv_have_libpq = yes; then
 158     PSQL_SUPPORT=yes
 159     AC_DEFINE([PSQL_SUPPORT], [1],
 160       [Define to 1 if building in support for reading from postgres
 161        databases.])
 162   else
 163     PSQL_SUPPORT=no
 164     PG_CONFIG=
 165     PG_CFLAGS=
 166     PG_LDFLAGS=
 167     PG_LIBS=
 168   fi
 169 else
 170   PSQL_SUPPORT=no
 171   pspp_cv_have_libpq=no
 172 fi
 173 AC_SUBST([PSQL_SUPPORT])
 174
 175 dnl Check for libxml2
 176 PKG_CHECK_MODULES(
 177   [LIBXML2], [libxml-2.0],
 178   [HAVE_LIBXML2=yes],
 179   [HAVE_LIBXML2=no
 180    PSPP_OPTIONAL_PREREQ([libxml2])])
 181
 182 dnl Check for zlib.
 183 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 184 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 185
 186 dnl Avoid interference between zlib's crc32() function and gnulib's
 187 dnl crc32() function, which have different signatures.  PSPP calls
 188 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 189 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 190 dnl crc32(), then zlib will call gnulib's version instead of its own,
 191 dnl causing failures.  (This can happen even if zlib isn't detected
 192 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 193 dnl sometimes use zlib themselves.)
 194 AC_DEFINE(
 195   [crc32], [gl_crc32],
 196   [Avoid making zlib call gnulib's crc32() instead of its own.])
 197
 198 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 199 if test $HAVE_LIBXML2 = yes; then
 200   GNM_READ_SUPPORT=yes
 201   ODF_READ_SUPPORT=yes
 202   AC_DEFINE(
 203     [GNM_READ_SUPPORT], [1],
 204     [Define to 1 if building in support for reading Gnumeric files.])
 205   AC_DEFINE(
 206     [ODF_READ_SUPPORT], [1],
 207     [Define to 1 if building in support for reading OpenDocument files.])
 208 else
 209   GNM_READ_SUPPORT=no
 210   ODF_READ_SUPPORT=no
 211 fi
 212 AC_SUBST([GNM_READ_SUPPORT])
 213 AC_SUBST([ODF_READ_SUPPORT])
 214
 215 dnl ODF support requires libxml2 (zlib is optional).
 216 if test $HAVE_LIBXML2 = yes; then
 217   AC_DEFINE(
 218     [ODF_WRITE_SUPPORT], [1],
 219     [Define to 1 if building in support for writing OpenDocument files.])
 220 fi
 221 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 222
 223 AC_ARG_WITH(
 224   gui_tools,
 225   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 226 if test x"$with_gui_tools" = x"yes" ; then
 227         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 228 fi
 229 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 230
 231 AC_ARG_WITH(
 232   [perl-module],
 233   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 234   [case $with_perl_module in # (
 235      yes|no) ;; # (
 236      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 237    esac
 238    WITH_PERL_MODULE=$with_perl_module],
 239   [if test x"$cross_compiling" != x"yes"; then
 240      WITH_PERL_MODULE=yes
 241    else
 242      WITH_PERL_MODULE=no
 243    fi])
 244 AC_SUBST([WITH_PERL_MODULE])
 245 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 246
 247 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 248 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 249                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 250
 251
 252 PSPP_GSL_NEEDS_FGNU89_INLINE
 253
 254 dnl Recent versions of GNU ncurses install the curses header files into
 255 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 256 dnl enables us to discover where they are. Earlier versions don't have
 257 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 258 dnl we'll trust it to find the right information.  Otherwise, we'll
 259 dnl try to discover it ourselves.
 260 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 261 dnl to ncurses8-config !!!
 262 AC_ARG_WITH(
 263   libncurses,
 264   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 265
 266 if test x"$with_libncurses" != x"no" ; then
 267   if test x"$cross_compiling" != x"yes" ; then
 268           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 269   fi
 270   if test x"$NCURSES_CONFIG" = x ; then
 271           AC_SEARCH_LIBS([tgetent], [ncurses],
 272               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 273   else
 274           old_cflags=$CFLAGS
 275           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 276           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 277           CFLAGS=$old_cflags
 278           if test x"$curses_available" = x"yes" ; then
 279            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 280            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 281            AC_SUBST(NCURSES_CFLAGS)
 282            AC_SUBST(NCURSES_LIBS)
 283           fi
 284   fi
 285   if test x"$curses_available" = x"yes" ; then
 286           AC_DEFINE([LIBNCURSES_USABLE], 1,
 287               [Define to 1 if the libncurses is both present and usable.])
 288   fi
 289   AC_CHECK_HEADERS([termcap.h])
 290 fi
 291
 292 PSPP_READLINE
 293
 294 dnl Checks for header files.
 295 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 296
 297 dnl Some systems dont have SIGWINCH
 298 AC_CHECK_DECLS([SIGWINCH], [], [],
 299           [#include <signal.h>
 300           /* NetBSD declares sys_siglist in unistd.h.  */
 301           #ifdef HAVE_UNISTD_H
 302           # include <unistd.h>
 303           #endif
 304           ])
 305
 306
 307 # For gnulib.
 308 gl_INIT
 309
 310 AC_C_INLINE
 311
 312 AC_C_BIGENDIAN
 313
 314 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 315
 316 AC_PROG_LN_S
 317
 318 AC_ARG_ENABLE(
 319   debug,
 320   [AS_HELP_STRING([--enable-debug],
 321                   [Turn on diagnostic features in the program])])
 322 if test x"$enable_debug" = x"yes"  ; then
 323   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 324 fi
 325
 326 # iconv is required
 327 AM_ICONV
 328 if test "$am_cv_func_iconv" != "yes"; then
 329    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 330 fi
 331 LIBS="$LIBICONV $LIBS"
 332
 333 dnl Required by the gnulib 'relocatable-prog' module.
 334 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 335 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 336 RELOCATABLE_STRIP=:
 337
 338 PSPP_CHECK_PREREQS
 339
 340 AC_CONFIG_FILES(
 341   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 342
 343 AC_CONFIG_COMMANDS([doc/dummy], [:])
 344
 345 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 346
 347 AC_OUTPUT
 348 echo "PSPP configured successfully."
 349
 350 dnl configure.ac ends here