pintos-os.org Git - pspp/blob - configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.63)
  21 AC_INIT([GNU PSPP], [1.1.0], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 AM_PROG_CC_C_O
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_LIBTOOL_DLOPEN
  34 AC_PROG_LIBTOOL
  35 AC_HEADER_TIOCGWINSZ
  36 PKG_PROG_PKG_CONFIG
  37 m4_pattern_forbid([PKG_CHECK_MODULES])
  38 PSPP_CHECK_CLICKSEQUENCE
  39 PSPP_CHECK_DOT
  40
  41 PSPP_ENABLE_WERROR
  42
  43 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  44
  45 PSPP_CC_FOR_BUILD
  46 PSPP_PERL
  47
  48 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  49 AC_PROVIDE([AM_PO_SUBDIRS])
  50 AM_GNU_GETTEXT([external], [need-ngettext])
  51 LIBS="$LIBINTL $LIBS"
  52 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  53 if test "x$MSGFMT" = x; then
  54   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  55 fi
  56
  57
  58 dnl Checks for libraries.
  59 AC_SYS_LARGEFILE
  60 AC_SEARCH_LIBS([sin], [m])
  61 PSPP_LC_PAPER
  62
  63
  64 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  65 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  66
  67 # Support for Cairo and Pango.
  68 AC_ARG_WITH([cairo],
  69   [AS_HELP_STRING(
  70     [--without-cairo],
  71     [Don't build support for charts (using Cairo and Pango);
  72      implies --without-gui])],
  73   [], [with_cairo=yes])
  74 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  75 if test "$with_cairo" != no; then
  76   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  77     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  78      AC_DEFINE([HAVE_CAIRO], 1,
  79        [Define to 1 if Cairo and Pango are available.])],
  80     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  81 fi
  82
  83 dnl Xmllint is used in the rules to build the documentation.  It is not actually necessary,
  84 dnl but is used for post-build consistency checks.  Thus, non-developers can live without it.
  85 dnl However for it to be useful, it needs to be a certain version and have certain features.
  86 dnl The macros below check that it the xmllint available is up to scratch.  If it isn't
  87 dnl then a dummy /bin/echo is subsituted instead.
  88
  89 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  90 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  91   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  92     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  93     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  94    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  95
  96 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  97
  98 # Support for GUI.
  99 AC_ARG_WITH([gui],
 100   [AS_HELP_STRING([--without-gui],
 101                   [Don't build the PSPPIRE GUI (using GTK+)])],
 102   [], [with_gui=yes])
 103 AM_CONDITIONAL([HAVE_GUI],
 104                [test "$with_cairo" != no && test "$with_gui" != "no"])
 105 if test "$with_cairo" != no && test "$with_gui" != "no"; then
 106   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 107     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 108
 109   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.14.5], [],
 110     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.14.5 or later (or use --without-gui)])])
 111
 112   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 113     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
 114
 115   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 116     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 117
 118   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.2], [],
 119     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.2 (or use --without-gui)])])
 120
 121   AC_ARG_VAR([GLIB_GENMARSHAL])
 122   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 123   if test "x$GLIB_GENMARSHAL" = x; then
 124     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 125   fi
 126
 127   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 128   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 129     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 130   fi
 131
 132 fi
 133
 134 gl_NEXT_HEADERS([gtk/gtk.h])
 135
 136 dnl Checks needed for psql reader
 137
 138 dnl The 8.x series postgres tarballs installs with a default prefix of
 139 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 140
 141 dnl If the libpq.so file is in a non standard path, (one which the linker
 142 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 143 dnl However, if the system happens to have more than one version of other
 144 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 145 dnl /usr and /usr/local) then the wrong one may get linked.
 146
 147 dnl To overcome this, we first check for libpq in the standard places, and
 148 dnl only set PG_LDFLAGS if it's not found.
 149
 150
 151 AC_ARG_WITH(
 152   libpq,
 153   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 154 AC_ARG_VAR([PG_CONFIG],
 155            [Full pathname of the pg_config program shipped with Postgresql])
 156 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 157              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 158
 159 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 160   AC_SUBST(PG_CONFIG)
 161   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 162   AC_SUBST(PG_CFLAGS)
 163
 164   AC_CHECK_LIB([pq], [PQexec],
 165      [:],
 166      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 167   AC_SUBST(PG_LDFLAGS)
 168
 169   PG_LIBS=-lpq
 170   AC_SUBST(PG_LIBS)
 171
 172   PKG_CHECK_EXISTS(libssl,
 173         AC_DEFINE([USE_SSL],1,
 174                    [Define to 1 if the openssl library is present.])
 175            ,)
 176
 177   # Now verify that we can actually link against libpq.  If we are
 178   # cross-compiling and picked up a host libpq, or if libpq is just
 179   # badly installed, this will fail.
 180   AC_CACHE_CHECK(
 181     [whether -lpq links successfully],
 182     [pspp_cv_have_libpq],
 183     [save_CPPFLAGS=$CPPFLAGS
 184      save_LIBS=$LIBS
 185      save_LDFLAGS=$LDFLAGS
 186      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 187      LIBS="$PG_LIBS $LIBS"
 188      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 189      AC_LINK_IFELSE(
 190        [AC_LANG_PROGRAM(
 191          [#include <libpq-fe.h>
 192          ], [PQfinish (0);])],
 193        [pspp_cv_have_libpq=yes],
 194        [pspp_cv_have_libpq=no])
 195      CPPFLAGS=$save_CPPFLAGS
 196      LIBS=$save_LIBS
 197      LDFLAGS=$save_LDFLAGS])
 198
 199   if test $pspp_cv_have_libpq = yes; then
 200     PSQL_SUPPORT=yes
 201     AC_DEFINE([PSQL_SUPPORT], [1],
 202       [Define to 1 if building in support for reading from postgres
 203        databases.])
 204   else
 205     PSQL_SUPPORT=no
 206     PG_CONFIG=
 207     PG_CFLAGS=
 208     PG_LDFLAGS=
 209     PG_LIBS=
 210   fi
 211 else
 212   PSQL_SUPPORT=no
 213   pspp_cv_have_libpq=no
 214 fi
 215 AC_SUBST([PSQL_SUPPORT])
 216
 217 dnl Check for libxml2
 218 PKG_CHECK_MODULES(
 219   [LIBXML2], [libxml-2.0],
 220   [HAVE_LIBXML2=yes],
 221   [HAVE_LIBXML2=no
 222    PSPP_OPTIONAL_PREREQ([libxml2])])
 223
 224 dnl Check for zlib.
 225 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 226 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 227
 228 dnl Avoid interference between zlib's crc32() function and gnulib's
 229 dnl crc32() function, which have different signatures.  PSPP calls
 230 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 231 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 232 dnl crc32(), then zlib will call gnulib's version instead of its own,
 233 dnl causing failures.  (This can happen even if zlib isn't detected
 234 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 235 dnl sometimes use zlib themselves.)
 236 AC_DEFINE(
 237   [crc32], [gl_crc32],
 238   [Avoid making zlib call gnulib's crc32() instead of its own.])
 239
 240 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 241 if test $HAVE_LIBXML2 = yes; then
 242   GNM_READ_SUPPORT=yes
 243   ODF_READ_SUPPORT=yes
 244   AC_DEFINE(
 245     [GNM_READ_SUPPORT], [1],
 246     [Define to 1 if building in support for reading Gnumeric files.])
 247   AC_DEFINE(
 248     [ODF_READ_SUPPORT], [1],
 249     [Define to 1 if building in support for reading OpenDocument files.])
 250 else
 251   GNM_READ_SUPPORT=no
 252   ODF_READ_SUPPORT=no
 253 fi
 254 AC_SUBST([GNM_READ_SUPPORT])
 255 AC_SUBST([ODF_READ_SUPPORT])
 256
 257 dnl ODF support requires libxml2 (zlib is optional).
 258 if test $HAVE_LIBXML2 = yes; then
 259   AC_DEFINE(
 260     [ODF_WRITE_SUPPORT], [1],
 261     [Define to 1 if building in support for writing OpenDocument files.])
 262 fi
 263 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 264
 265 AC_ARG_WITH(
 266   gui_tools,
 267   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 268 if test x"$with_gui_tools" = x"yes" ; then
 269         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 270 fi
 271 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 272
 273 AC_ARG_WITH(
 274   [perl-module],
 275   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 276   [case $with_perl_module in # (
 277      yes|no) ;; # (
 278      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 279    esac
 280    WITH_PERL_MODULE=$with_perl_module],
 281   [if test x"$cross_compiling" != x"yes"; then
 282      WITH_PERL_MODULE=yes
 283    else
 284      WITH_PERL_MODULE=no
 285    fi])
 286 AC_SUBST([WITH_PERL_MODULE])
 287 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 288
 289 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 290 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 291                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 292
 293
 294 PSPP_GSL_NEEDS_FGNU89_INLINE
 295
 296 PSPP_READLINE
 297
 298 dnl Checks for header files.
 299 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 300
 301 dnl Some systems don't have SIGWINCH
 302 AC_CHECK_DECLS([SIGWINCH], [], [],
 303           [#include <signal.h>
 304           /* NetBSD declares sys_siglist in unistd.h.  */
 305           #ifdef HAVE_UNISTD_H
 306           # include <unistd.h>
 307           #endif
 308           ])
 309
 310
 311 # For gnulib.
 312 gl_INIT
 313
 314 AC_C_INLINE
 315
 316 AC_C_BIGENDIAN
 317
 318 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 319
 320 AC_PROG_LN_S
 321
 322 AC_ARG_ENABLE(
 323   debug,
 324   [AS_HELP_STRING([--enable-debug],
 325                   [Turn on diagnostic features in the program])])
 326 if test x"$enable_debug" = x"yes"  ; then
 327   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 328 fi
 329
 330 # iconv is required
 331 AM_ICONV
 332 if test "$am_cv_func_iconv" != "yes"; then
 333    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 334 fi
 335 LIBS="$LIBICONV $LIBS"
 336
 337 dnl Required by the gnulib 'relocatable-prog' module.
 338 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 339 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 340 RELOCATABLE_STRIP=:
 341
 342 PSPP_CHECK_PREREQS
 343
 344 AC_CONFIG_FILES(
 345   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 346
 347 AC_CONFIG_COMMANDS([doc/dummy], [:])
 348
 349 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 350
 351 AC_OUTPUT
 352 echo "PSPP configured successfully."
 353
 354 dnl configure.ac ends here