pintos-os.org Git - pspp/blob - build-pspp

   1 #! /usr/bin/env perl
   2
   3 use Cwd;
   4 use File::Basename;
   5 use File::Spec;
   6 use Getopt::Long qw(:config bundling no_ignore_case);
   7 use IO::Handle;
   8 use POSIX;
   9
  10 use strict;
  11 use warnings;
  12
  13 my $help = 0;
  14 my $build_binary = 1;
  15 my $batch = 0;
  16 my $builddir;
  17 my $build_number;
  18 GetOptions ("h|help" => \$help,
  19             "binary!" => \$build_binary,
  20             "batch!" => \$batch,
  21             "o|output=s" => \$builddir,
  22             "build-number=i" => \$build_number);
  23
  24 usage () if $help;
  25
  26 die "$0: exactly one or two nonoption arguments are required\n"
  27   if @ARGV != 1 && @ARGV != 2;
  28
  29 my $tarball;
  30 if (@ARGV == 1) {
  31     $tarball = File::Spec->rel2abs ($ARGV[0]);
  32 } else {
  33     # Tarball will be generated later.
  34 }
  35
  36 # Select build number.
  37 if (!defined ($build_number)) {
  38     $build_number = POSIX::strftime("%Y%m%d%H%M%S", localtime);
  39 }
  40
  41 my $topdir = dirname ($0);
  42 $topdir = cwd () . "/$topdir" if $topdir !~ m%^/%;
  43
  44 # Create build directory.
  45 if (!defined ($builddir)) {
  46     $builddir = "builds/$build_number";
  47     mkdir "builds" or die "builds: mkdir: $!\n" if ! -d "builds";
  48 }
  49 $builddir = File::Spec->rel2abs ($builddir);
  50 -d $builddir or mkdir $builddir or die "$builddir: mkdir: $!\n";
  51 chdir ($builddir) or die "$builddir: chdir: $!\n";
  52
  53 our $resultsdir = "$builddir/results";
  54 mkdir $resultsdir or die "$resultsdir: mkdir: $!\n";
  55 mkdir "$resultsdir/vars" or die "$resultsdir/vars: mkdir: $!\n";
  56
  57 my $varsfile = "$resultsdir/VARS";
  58 open (VARS, '>', $varsfile) or die "creating $varsfile failed: $!\n";
  59 VARS->autoflush (1);
  60
  61 our $logfile = "$resultsdir/LOG";
  62 open (LOG, '>', $logfile) or die "creating $logfile failed: $!\n";
  63
  64 my $build_host = `hostname`;
  65 chomp $build_host;
  66 set_var ("build_host", $build_host);
  67 set_var ("build_number", $build_number);
  68
  69 sub start_step {
  70     my ($msg) = @_;
  71     print LOG "\f\n$msg\n";
  72     print "$msg\n" unless $batch;
  73 }
  74
  75 sub set_var {
  76     my ($var, $value) = @_;
  77
  78     print VARS "$var=$value\n";
  79
  80     print "\t$var=$value\n" unless $batch;
  81
  82     open (VAR, '>', "$resultsdir/vars/$var")
  83       or die "creating $resultsdir/$var failed: $!\n";
  84     print VAR "$value\n";
  85     close VAR;
  86 }
  87
  88 sub saved_result {
  89     my ($name, $product) = @_;
  90     start_step ("Saving $name: $product");
  91 }
  92
  93 sub save_result {
  94     my ($name, $src, $rm_src) = @_;
  95     my ($basename) = $src;
  96     $basename =~ s(^.*/)();
  97     my ($dst) = "$resultsdir/$basename";
  98
  99     saved_result ($name, $basename);
 100     run ("cp -R $src $dst");
 101
 102     if (defined ($rm_src) && $rm_src) {
 103         run ("rm $src");
 104     }
 105
 106     return $dst;
 107 }
 108
 109 sub save_result_if_exists {
 110     my ($name, $src, $rm_src) = @_;
 111     if (-e $src) {
 112         save_result (@_);
 113     } else {
 114         start_step ("$src does not exist, cannot save");
 115     }
 116 }
 117
 118 my $GIT = "git --git-dir=$topdir/.git";
 119
 120 if (@ARGV == 2) {
 121     my ($repo, $branch) = @ARGV;
 122
 123     # Fetch branch
 124     start_step ("Fetch $repo, branch $branch");
 125     run ("$GIT fetch $repo +$branch:refs/builds/$build_number/pspp");
 126
 127     # Get revision number.
 128     my $revision = `$GIT rev-parse refs/builds/$build_number/pspp`;
 129     chomp $revision;
 130     set_var ("pspp_commit", $revision);
 131     my $abbrev_commit = substr ($revision, 0, 6);
 132
 133     # Extract source.
 134     start_step ("Extract branch into source directory");
 135     run ("$GIT archive --format=tar --prefix=pspp/ refs/builds/$build_number/pspp | tar xf -");
 136
 137     # Extract version number.
 138     start_step ("Extract repository version number");
 139     my $trace = `cd pspp && autoconf -t AC_INIT`;
 140     chomp $trace;
 141     my ($file, $line, $macro, $package, $repo_version, @rest)
 142       = split (':', $trace);
 143     set_var ("repo_version", $repo_version);
 144
 145     # Is this a "gnits" mode tree?
 146     start_step ("Checking Automake mode");
 147     open (MAKEFILE_AM, '<', "pspp/Makefile.am");
 148     my $am_mode = "gnu";
 149     while (<MAKEFILE_AM>) {
 150         if (/gnits/) {
 151             $am_mode = "gnits";
 152             last;
 153         }
 154     }
 155     close (MAKEFILE_AM);
 156     set_var ("am_mode", $am_mode);
 157
 158     # Generate version number for build.
 159     # We want to append -g012345, but if we're in Gnits mode and the
 160     # version number already has a hyphen, we have to omit it.
 161     start_step ("Generate build version number");
 162     my $version = $repo_version;
 163     $version .= '-' unless $version =~ /-/;
 164     $version .= "g$abbrev_commit";
 165     set_var ("version", $version);
 166
 167     # Append -g012345 to configure.ac version number.
 168     start_step ("Updating version number in $file");
 169     my $fullname = "pspp/$file";
 170     open (OLDFILE, '<', $fullname)
 171       or die "opening $fullname failed: $!\n";
 172     open (NEWFILE, '>', "$fullname.new")
 173       or die "creating $fullname.new failed: $!\n";
 174     while (<OLDFILE>) {
 175         if ($. != $line) {
 176             print NEWFILE $_;
 177         } else {
 178             print NEWFILE "AC_INIT([$package], [$version]";
 179             print NEWFILE ", [$_]" foreach @rest;
 180             print NEWFILE ")\n";
 181         }
 182     }
 183     close (NEWFILE);
 184     close (OLDFILE);
 185     rename ("$fullname.new", $fullname)
 186       or die "rename $fullname.new to $fullname failed: $!\n";
 187
 188     # Get Gnulib commit number.
 189     start_step ("Reading README.Git to find Gnulib commit number");
 190     my $gnulib_commit;
 191     $fullname = "pspp/README.Git";
 192     open (README_GIT, '<', $fullname)
 193       or die "opening $fullname failed: $!\n";
 194     while (<README_GIT>) {
 195         ($gnulib_commit) = /^\s+commit ([0-9a-fA-F]{8,})/ and last;
 196     }
 197     die "$fullname does not specify a Git commit number\n"
 198       if !defined ($gnulib_commit);
 199     set_var ("gnulib_commit", $gnulib_commit);
 200
 201     # Add note to beginning of NEWS (otherwise "make dist" fails).
 202     start_step ("Updating NEWS");
 203     $fullname = "pspp/NEWS";
 204     open (OLDFILE, '<', $fullname)
 205       or die "opening $fullname failed: $!\n";
 206     open (NEWFILE, '>', "$fullname.new")
 207       or die "creating $fullname.new failed: $!\n";
 208     my $found_changes = 0;
 209     while (<OLDFILE>) {
 210         if (!$found_changes && /^Changes/) {
 211             $found_changes = 1;
 212             print NEWFILE <<EOF;
 213 Changes from $repo_version to $version:
 214
 215  * Built from PSPP commit $revision
 216    in branch $branch on host $build_host.
 217
 218  * Built from Gnulib commit $gnulib_commit.
 219
 220 EOF
 221         }
 222         print NEWFILE $_;
 223     }
 224     close (NEWFILE);
 225     close (OLDFILE);
 226     rename ("$fullname.new", $fullname)
 227       or die "rename $fullname.new to $fullname failed: $!\n";
 228
 229     # If we don't already have that Gnulib commit, update Gnulib.
 230     system ("$GIT rev-parse --verify --quiet $gnulib_commit");
 231     if ($? != 0) {
 232         start_step ("Updating Gnulib to obtain commit");
 233         run ("$GIT fetch gnulib");
 234     }
 235     run ("$GIT update-ref refs/builds/$build_number/gnulib $gnulib_commit");
 236
 237     # Extract gnulib source.
 238     start_step ("Extract Gnulib source");
 239     run ("$GIT archive --format=tar --prefix=gnulib/ $gnulib_commit | tar xf -");
 240
 241     # Bootstrap.
 242     start_step ("Bootstrap (make -f Smake)");
 243     run ("cd pspp && make -f Smake", "bootstrap");
 244
 245     # Configure.
 246     start_step ("Configure source");
 247     run ("cd pspp && mkdir _build && cd _build && ../configure", "configure");
 248
 249     # Distribute.
 250     start_step ("Make source tarball");
 251     run ("cd pspp/_build && make dist", "dist");
 252     my $tarname = "pspp-$version.tar.gz";
 253     $tarball = save_result ("source distribution", "pspp/_build/$tarname", 1);
 254
 255     # Save translation templates.
 256     my $potfile = "pspp/_build/po/pspp.pot";
 257     $potfile = "pspp/po/pspp.pot" if ! -e $potfile;
 258     save_result ("translation templates", $potfile);
 259
 260     # Build user manual
 261     start_step ("Build user manual");
 262     run ("cd pspp && cp _build/doc/*.texi doc/");
 263     run ("cd pspp && GENDOCS_TEMPLATE_DIR=$topdir $topdir/gendocs.sh -s doc/pspp.texinfo -o $resultsdir/user-manual --email bug-gnu-pspp\@gnu.org pspp \"GNU PSPP User Manual\"", "user-manual");
 264     saved_result ("User Manual", "user-manual");
 265
 266     # Build developer's guide
 267     start_step ("Build developers guide");
 268     run ("cd pspp && GENDOCS_TEMPLATE_DIR=$topdir $topdir/gendocs.sh -s doc/pspp-dev.texinfo -o $resultsdir/dev-guide --email bug-gnu-pspp\@gnu.org pspp-dev \"GNU PSPP Developers Guide\"", "dev-guide");
 269     saved_result ("Developers Guide", "dev-guide");
 270 }
 271
 272 if ($build_binary) {
 273     start_step ("Save tarball to Git");
 274     run ("GIT_DIR=$topdir/.git $topdir/git-import-tar $tarball refs/builds/$build_number/dist", "git-dist");
 275
 276     start_step ("Determining $tarball target directory");
 277     my $sample_filename = `zcat $tarball | tar tf - | head -1`;
 278     my ($tarball_dir) = $sample_filename =~ m%^(?:[./])*([^/]+)/%;
 279     set_var ("dist_dir", $tarball_dir);
 280
 281     start_step ("Extracting source tarball");
 282     run ("zcat $tarball | (cd $builddir && tar xf -)");
 283
 284     start_step ("Extracting tar version");
 285     my ($version) = `cd $builddir/$tarball_dir && ./configure --version | head -1`
 286       =~ /configure (\S+)$/;
 287     set_var ("dist_version", $version);
 288     my ($binary_version) = "$version-$build_host-build$build_number";
 289     set_var ("binary_version", $binary_version);
 290
 291     start_step ("Configuring");
 292     run ("chmod -R a-w $builddir/$tarball_dir");
 293     run ("chmod u+w $builddir/$tarball_dir");
 294     run ("mkdir $builddir/$tarball_dir/_build");
 295     run ("chmod a-w $builddir/$tarball_dir");
 296     my $ok = try_run ("cd $builddir/$tarball_dir/_build && ../configure --enable-relocatable --prefix=''", "bin-configure");
 297     for my $basename ("config.h", "config.log") {
 298         save_result_if_exists ("build configuration",
 299                                "$builddir/$tarball_dir/_build/$basename");
 300     }
 301     fail () if !$ok;
 302
 303     start_step ("Build");
 304     run ("cd $builddir/$tarball_dir/_build && make", "build");
 305
 306     start_step ("Install");
 307     run ("cd $builddir/$tarball_dir/_build && make install DESTDIR=\$PWD/pspp-$binary_version", "install");
 308
 309     start_step ("Make binary distribution");
 310     run ("cd $builddir/$tarball_dir/_build && tar cfz pspp-$binary_version.tar.gz pspp-$binary_version");
 311     save_result ("binary distribution", "$builddir/$tarball_dir/_build/pspp-$binary_version.tar.gz", 1);
 312
 313     start_step ("Check");
 314     $ok = try_run ("cd $builddir/$tarball_dir/_build && make check", "check");
 315     for my $basename ("tests/testsuite.log", "tests/testsuite.dir") {
 316         save_result_if_exists ("test logs", "$builddir/$tarball_dir/_build/$basename");
 317     }
 318     fail () if !$ok;
 319
 320     start_step ("Uninstall");
 321     run ("cd $builddir/$tarball_dir/_build && make uninstall DESTDIR=\$PWD/pspp-$binary_version", "uninstall");
 322
 323     start_step ("Check uninstall");
 324     run ("cd $builddir/$tarball_dir/_build && make distuninstallcheck distuninstallcheck_dir=\$PWD/pspp-$binary_version", "distuninstallcheck");
 325
 326     # distcleancheck
 327 }
 328
 329 start_step ("Success");
 330
 331 sub usage {
 332     print <<EOF;
 333 $0, for building and testing PSPP
 334 usage: $0 [OPTIONS] [TARBALL | REPO REFSPEC]
 335 where TARBALL is the name of a tarball produced by "make dist"
 336    or REPO and REFSPEC are a Git repo and refspec (e.g. branch) to clone.
 337
 338 Options:
 339   --help            Print this usage message and exit
 340   --no-binary       Build source tarballs but no binaries.
 341   --batch           Do not print progress to stdout.
 342 EOF
 343     exit(0);
 344 }
 345
 346 sub run {
 347     fail () if !try_run (@_);
 348 }
 349
 350 sub try_run {
 351     my ($command, $id) = @_;
 352
 353     print LOG "$command\n";
 354
 355     my $pid = open (COMMAND, '-|');
 356     if (!defined ($pid)) {
 357         die "fork failed: $!\n";
 358     } elsif (!$pid) {
 359         dup2 (1, 2);
 360         exec ($command);
 361         die "$command: exec failed: $!\n";
 362     }
 363
 364     my ($start) = time ();
 365     my ($est_time) = (defined ($id) ? read_timing ($id) : 0);
 366
 367     local ($|) = 1;
 368     my $lines = 0;
 369     while (<COMMAND>) {
 370         print LOG $_;
 371
 372         my $elapsed = time () - $start;
 373         my $progress = sprintf "%d lines logged, %d s elapsed",
 374           $lines++, $elapsed;
 375         if ($est_time > 0) {
 376             my $left = $est_time - $elapsed;
 377             if ($left > 0) {
 378                 $progress .= sprintf ", ETA %d s", $left;
 379             }
 380         }
 381         print "\r$progress", " " x (79 - length ($progress)), "\r"
 382           unless $batch;
 383     }
 384     close (COMMAND);
 385     print "\r", " " x 79, "\r" unless $batch;
 386
 387     write_timing ($id, time () - $start) if defined ($id);
 388
 389     return 1 if !$?;
 390
 391     if ($? & 127) {
 392         printf STDERR "%s: child died with signal %d, %s coredump\n",
 393           $command, ($? & 127),  ($? & 128) ? 'with' : 'without';
 394     } else {
 395         printf STDERR "%s: child exited with value %d\n", $command, $? >> 8;
 396     }
 397     return 0;
 398 }
 399
 400 sub read_timing {
 401     my ($id) = @_;
 402     open (TIMINGS, "<", "$topdir/timings") or return 0;
 403     while (<TIMINGS>) {
 404         chomp;
 405         my ($key, $value) = /^([^=]+)=(.*)/ or next;
 406         return $value if $key eq $id;
 407     }
 408     close (TIMINGS);
 409     return 0;
 410 }
 411
 412 sub write_timing {
 413     my ($id, $time) = @_;
 414
 415     open (NEWTIMINGS, ">", "$topdir/timings.tmp$$") or return;
 416
 417     if (open (OLDTIMINGS, "<", "$topdir/timings")) {
 418         while (<OLDTIMINGS>) {
 419             if (my ($key, $value) = /^([^=]+)=(.*)/) {
 420                 next if $key eq $id;
 421             }
 422             print NEWTIMINGS $_;
 423         }
 424         close (OLDTIMINGS);
 425     }
 426
 427     print NEWTIMINGS "$id=$time\n";
 428     close (NEWTIMINGS);
 429
 430     rename ("$topdir/timings.tmp$$", "$topdir/timings");
 431 }
 432
 433 sub fail {
 434     die "Build failed, refer to:\n\t$logfile\nfor details.\n";
 435 }