pintos-os.org Git - pspp/blob - build-pspp

   1 #! /usr/bin/env perl
   2
   3 use Cwd;
   4 use File::Basename;
   5 use File::Spec;
   6 use Getopt::Long qw(:config bundling no_ignore_case);
   7 use IO::Handle;
   8 use POSIX;
   9
  10 use strict;
  11 use warnings;
  12
  13 my $help = 0;
  14 my $build_binary = 1;
  15 my $batch = 0;
  16 my $builddir;
  17 my $build_number;
  18 GetOptions ("h|help" => \$help,
  19             "binary!" => \$build_binary,
  20             "batch!" => \$batch,
  21             "o|output=s" => \$builddir,
  22             "build-number=i" => \$build_number);
  23
  24 usage () if $help;
  25
  26 die "$0: exactly one or two nonoption arguments are required\n"
  27   if @ARGV != 1 && @ARGV != 2;
  28
  29 my $tarball;
  30 if (@ARGV == 1) {
  31     $tarball = File::Spec->rel2abs ($ARGV[0]);
  32 } else {
  33     # Tarball will be generated later.
  34 }
  35
  36 # Select build number.
  37 if (!defined ($build_number)) {
  38     $build_number = POSIX::strftime("%Y%m%d%H%M%S", localtime);
  39 }
  40
  41 my $topdir = dirname ($0);
  42 $topdir = cwd () . "/$topdir" if $topdir !~ m%^/%;
  43
  44 # Create build directory.
  45 if (!defined ($builddir)) {
  46     $builddir = "builds/$build_number";
  47     mkdir "builds" or die "builds: mkdir: $!\n" if ! -d "builds";
  48 }
  49 $builddir = File::Spec->rel2abs ($builddir);
  50 -d $builddir or mkdir $builddir or die "$builddir: mkdir: $!\n";
  51 chdir ($builddir) or die "$builddir: chdir: $!\n";
  52
  53 our $resultsdir = "$builddir/results";
  54 mkdir $resultsdir or die "$resultsdir: mkdir: $!\n";
  55 mkdir "$resultsdir/vars" or die "$resultsdir/vars: mkdir: $!\n";
  56
  57 my $varsfile = "$resultsdir/VARS";
  58 open (VARS, '>', $varsfile) or die "creating $varsfile failed: $!\n";
  59 VARS->autoflush (1);
  60
  61 our $logfile = "$resultsdir/LOG";
  62 open (LOG, '>', $logfile) or die "creating $logfile failed: $!\n";
  63
  64 my $build_host = `hostname`;
  65 chomp $build_host;
  66 set_var ("build_host", $build_host);
  67 set_var ("build_number", $build_number);
  68
  69 sub start_step {
  70     my ($msg) = @_;
  71     print LOG "\f\n$msg\n";
  72     print "$msg\n" unless $batch;
  73 }
  74
  75 sub set_var {
  76     my ($var, $value) = @_;
  77
  78     print VARS "$var=$value\n";
  79
  80     print "\t$var=$value\n" unless $batch;
  81
  82     open (VAR, '>', "$resultsdir/vars/$var")
  83       or die "creating $resultsdir/$var failed: $!\n";
  84     print VAR "$value\n";
  85     close VAR;
  86 }
  87
  88 sub saved_result {
  89     my ($name, $product) = @_;
  90     start_step ("Saving $name: $product");
  91 }
  92
  93 sub save_result {
  94     my ($name, $src, $rm_src) = @_;
  95     my ($basename) = $src;
  96     $basename =~ s(^.*/)();
  97     my ($dst) = "$resultsdir/$basename";
  98
  99     saved_result ($name, $basename);
 100     run ("cp -R $src $dst");
 101
 102     if (defined ($rm_src) && $rm_src) {
 103         run ("rm $src");
 104     }
 105
 106     return $dst;
 107 }
 108
 109 sub save_result_if_exists {
 110     my ($name, $src, $rm_src) = @_;
 111     if (-e $src) {
 112         save_result (@_);
 113     } else {
 114         start_step ("$src does not exist, cannot save");
 115     }
 116 }
 117
 118 sub ref_to_commit {
 119     my ($ref) = @_;
 120     my $commit = `$GIT rev-parse $ref`;
 121     chomp $commit;
 122     return $commit;
 123 }
 124
 125 my $GIT = "git --git-dir=$topdir/.git";
 126
 127 if (@ARGV == 2) {
 128     my ($repo, $branch) = @ARGV;
 129
 130     start_step ("Fetch branch from Git");
 131     set_var ("git_repo", $repo);
 132     set_var ("git_branch", $branch);
 133     run ("$GIT fetch $repo +$branch:refs/builds/$build_number/pspp");
 134
 135     # Get revision number.
 136     set_var ("pspp_ref", "refs/builds/$build_number/pspp");
 137     my $revision = ref_to_commit ("refs/builds/$build_number/pspp");
 138     set_var ("pspp_commit", $revision);
 139     my $abbrev_commit = substr ($revision, 0, 6);
 140
 141     # Extract source.
 142     start_step ("Extract branch into source directory");
 143     run ("$GIT archive --format=tar --prefix=pspp/ refs/builds/$build_number/pspp | tar xf -");
 144
 145     # Extract version number.
 146     start_step ("Extract repository version number");
 147     my $trace = `cd pspp && autoconf -t AC_INIT`;
 148     chomp $trace;
 149     my ($file, $line, $macro, $package, $repo_version, @rest)
 150       = split (':', $trace);
 151     set_var ("repo_version", $repo_version);
 152
 153     # Is this a "gnits" mode tree?
 154     start_step ("Checking Automake mode");
 155     open (MAKEFILE_AM, '<', "pspp/Makefile.am");
 156     my $am_mode = "gnu";
 157     while (<MAKEFILE_AM>) {
 158         if (/gnits/) {
 159             $am_mode = "gnits";
 160             last;
 161         }
 162     }
 163     close (MAKEFILE_AM);
 164     print LOG "Automake mode is $am_mode\n";
 165
 166     # Generate version number for build.
 167     # We want to append -g012345, but if we're in Gnits mode and the
 168     # version number already has a hyphen, we have to omit it.
 169     start_step ("Generate build version number");
 170     my $version = $repo_version;
 171     $version .= '-' unless $version =~ /-/;
 172     $version .= "g$abbrev_commit";
 173     set_var ("version", $version);
 174
 175     # Append -g012345 to configure.ac version number.
 176     start_step ("Updating version number in $file");
 177     my $fullname = "pspp/$file";
 178     open (OLDFILE, '<', $fullname)
 179       or die "opening $fullname failed: $!\n";
 180     open (NEWFILE, '>', "$fullname.new")
 181       or die "creating $fullname.new failed: $!\n";
 182     while (<OLDFILE>) {
 183         if ($. != $line) {
 184             print NEWFILE $_;
 185         } else {
 186             print NEWFILE "AC_INIT([$package], [$version]";
 187             print NEWFILE ", [$_]" foreach @rest;
 188             print NEWFILE ")\n";
 189         }
 190     }
 191     close (NEWFILE);
 192     close (OLDFILE);
 193     rename ("$fullname.new", $fullname)
 194       or die "rename $fullname.new to $fullname failed: $!\n";
 195
 196     # Get Gnulib commit number.
 197     start_step ("Reading README.Git to find Gnulib commit number");
 198     my $gnulib_commit;
 199     $fullname = "pspp/README.Git";
 200     open (README_GIT, '<', $fullname)
 201       or die "opening $fullname failed: $!\n";
 202     while (<README_GIT>) {
 203         ($gnulib_commit) = /^\s+commit ([0-9a-fA-F]{8,})/ and last;
 204     }
 205     die "$fullname does not specify a Git commit number\n"
 206       if !defined ($gnulib_commit);
 207     set_var ("gnulib_commit", $gnulib_commit);
 208
 209     # Add note to beginning of NEWS (otherwise "make dist" fails).
 210     start_step ("Updating NEWS");
 211     $fullname = "pspp/NEWS";
 212     open (OLDFILE, '<', $fullname)
 213       or die "opening $fullname failed: $!\n";
 214     open (NEWFILE, '>', "$fullname.new")
 215       or die "creating $fullname.new failed: $!\n";
 216     my $found_changes = 0;
 217     while (<OLDFILE>) {
 218         if (!$found_changes && /^Changes/) {
 219             $found_changes = 1;
 220             print NEWFILE <<EOF;
 221 Changes from $repo_version to $version:
 222
 223  * Built from PSPP commit $revision
 224    in branch $branch on host $build_host.
 225
 226  * Built from Gnulib commit $gnulib_commit.
 227
 228 EOF
 229         }
 230         print NEWFILE $_;
 231     }
 232     close (NEWFILE);
 233     close (OLDFILE);
 234     rename ("$fullname.new", $fullname)
 235       or die "rename $fullname.new to $fullname failed: $!\n";
 236
 237     # If we don't already have that Gnulib commit, update Gnulib.
 238     system ("$GIT rev-parse --verify --quiet $gnulib_commit > /dev/null");
 239     if ($? != 0) {
 240         start_step ("Updating Gnulib to obtain commit");
 241         run ("$GIT fetch gnulib");
 242     }
 243     run ("$GIT update-ref refs/builds/$build_number/gnulib $gnulib_commit");
 244     set_var ("gnulib_ref", "refs/builds/$build_number/gnulib");
 245
 246     # Extract gnulib source.
 247     start_step ("Extract Gnulib source");
 248     run ("$GIT archive --format=tar --prefix=gnulib/ $gnulib_commit | tar xf -");
 249
 250     # Bootstrap.
 251     start_step ("Bootstrap (make -f Smake)");
 252     run ("cd pspp && make -f Smake", "bootstrap");
 253
 254     # Configure.
 255     start_step ("Configure source");
 256     run ("cd pspp && mkdir _build && cd _build && ../configure", "configure");
 257
 258     # Distribute.
 259     start_step ("Make source tarball");
 260     run ("cd pspp/_build && make dist", "dist");
 261     my $tarname = "pspp-$version.tar.gz";
 262     $tarball = save_result ("source distribution", "pspp/_build/$tarname", 1);
 263
 264     # Save translation templates.
 265     my $potfile = "pspp/_build/po/pspp.pot";
 266     $potfile = "pspp/po/pspp.pot" if ! -e $potfile;
 267     save_result ("translation templates", $potfile);
 268
 269     # Build user manual
 270     start_step ("Build user manual");
 271     run ("cd pspp && cp _build/doc/*.texi doc/");
 272     run ("cd pspp && GENDOCS_TEMPLATE_DIR=$topdir $topdir/gendocs.sh -s doc/pspp.texinfo -o $resultsdir/user-manual --email bug-gnu-pspp\@gnu.org pspp \"GNU PSPP User Manual\"", "user-manual");
 273     saved_result ("User Manual", "user-manual");
 274
 275     # Build developer's guide
 276     start_step ("Build developers guide");
 277     run ("cd pspp && GENDOCS_TEMPLATE_DIR=$topdir $topdir/gendocs.sh -s doc/pspp-dev.texinfo -o $resultsdir/dev-guide --email bug-gnu-pspp\@gnu.org pspp-dev \"GNU PSPP Developers Guide\"", "dev-guide");
 278     saved_result ("Developers Guide", "dev-guide");
 279 } else {
 280     $tarball = saved_result ("source distribution", $tarball);
 281 }
 282
 283 if ($build_binary) {
 284     start_step ("Save tarball to Git");
 285     run ("GIT_DIR=$topdir/.git $topdir/git-import-tar $tarball refs/builds/$build_number/dist", "git-dist");
 286     set_var ("dist_ref", "refs/builds/$build_number/dist");
 287     set_var ("dist_commit", ref_to_commit ("refs/builds/$build_number/dist"));
 288
 289     start_step ("Extracting source tarball");
 290     run ("zcat $tarball | (cd $builddir && tar xf -)");
 291
 292     start_step ("Extracting tar version");
 293     my ($version) = `cd $builddir/$tarball_dir && ./configure --version | head -1`
 294       =~ /configure (\S+)$/;
 295     set_var ("dist_version", $version);
 296     my ($binary_version) = "$version-$build_host-build$build_number";
 297     set_var ("binary_version", $binary_version);
 298
 299     start_step ("Configuring");
 300     run ("chmod -R a-w $builddir/$tarball_dir");
 301     run ("chmod u+w $builddir/$tarball_dir");
 302     run ("mkdir $builddir/$tarball_dir/_build");
 303     run ("chmod a-w $builddir/$tarball_dir");
 304     my $ok = try_run ("cd $builddir/$tarball_dir/_build && ../configure --enable-relocatable --prefix=''", "bin-configure");
 305     for my $basename ("config.h", "config.log") {
 306         save_result_if_exists ("build configuration",
 307                                "$builddir/$tarball_dir/_build/$basename");
 308     }
 309     fail () if !$ok;
 310
 311     start_step ("Build");
 312     run ("cd $builddir/$tarball_dir/_build && make", "build");
 313
 314     start_step ("Install");
 315     run ("cd $builddir/$tarball_dir/_build && make install DESTDIR=\$PWD/pspp-$binary_version", "install");
 316
 317     start_step ("Make binary distribution");
 318     run ("cd $builddir/$tarball_dir/_build && tar cfz pspp-$binary_version.tar.gz pspp-$binary_version");
 319     save_result ("binary distribution", "$builddir/$tarball_dir/_build/pspp-$binary_version.tar.gz", 1);
 320
 321     start_step ("Check");
 322     $ok = try_run ("cd $builddir/$tarball_dir/_build && make check", "check");
 323     for my $basename ("tests/testsuite.log", "tests/testsuite.dir") {
 324         save_result_if_exists ("test logs", "$builddir/$tarball_dir/_build/$basename");
 325     }
 326     fail () if !$ok;
 327
 328     start_step ("Uninstall");
 329     run ("cd $builddir/$tarball_dir/_build && make uninstall DESTDIR=\$PWD/pspp-$binary_version", "uninstall");
 330
 331     start_step ("Check uninstall");
 332     run ("cd $builddir/$tarball_dir/_build && make distuninstallcheck distuninstallcheck_dir=\$PWD/pspp-$binary_version", "distuninstallcheck");
 333
 334     # distcleancheck
 335 }
 336
 337 start_step ("Success");
 338
 339 sub usage {
 340     print <<EOF;
 341 $0, for building and testing PSPP
 342 usage: $0 [OPTIONS] [TARBALL | REPO REFSPEC]
 343 where TARBALL is the name of a tarball produced by "make dist"
 344    or REPO and REFSPEC are a Git repo and refspec (e.g. branch) to clone.
 345
 346 Options:
 347   --help            Print this usage message and exit
 348   --no-binary       Build source tarballs but no binaries.
 349   --batch           Do not print progress to stdout.
 350 EOF
 351     exit(0);
 352 }
 353
 354 sub run {
 355     fail () if !try_run (@_);
 356 }
 357
 358 sub try_run {
 359     my ($command, $id) = @_;
 360
 361     print LOG "$command\n";
 362
 363     my $pid = open (COMMAND, '-|');
 364     if (!defined ($pid)) {
 365         die "fork failed: $!\n";
 366     } elsif (!$pid) {
 367         dup2 (1, 2);
 368         exec ($command);
 369         die "$command: exec failed: $!\n";
 370     }
 371
 372     my ($start) = time ();
 373     my ($est_time) = (defined ($id) ? read_timing ($id) : 0);
 374
 375     local ($|) = 1;
 376     my $lines = 0;
 377     while (<COMMAND>) {
 378         print LOG $_;
 379
 380         my $elapsed = time () - $start;
 381         my $progress = sprintf "%d lines logged, %d s elapsed",
 382           $lines++, $elapsed;
 383         if ($est_time > 0) {
 384             my $left = $est_time - $elapsed;
 385             if ($left > 0) {
 386                 $progress .= sprintf ", ETA %d s", $left;
 387             }
 388         }
 389         print "\r$progress", " " x (79 - length ($progress)), "\r"
 390           unless $batch;
 391     }
 392     close (COMMAND);
 393     print "\r", " " x 79, "\r" unless $batch;
 394
 395     write_timing ($id, time () - $start) if defined ($id);
 396
 397     return 1 if !$?;
 398
 399     if ($? & 127) {
 400         printf STDERR "%s: child died with signal %d, %s coredump\n",
 401           $command, ($? & 127),  ($? & 128) ? 'with' : 'without';
 402     } else {
 403         printf STDERR "%s: child exited with value %d\n", $command, $? >> 8;
 404     }
 405     return 0;
 406 }
 407
 408 sub read_timing {
 409     my ($id) = @_;
 410     open (TIMINGS, "<", "$topdir/timings") or return 0;
 411     while (<TIMINGS>) {
 412         chomp;
 413         my ($key, $value) = /^([^=]+)=(.*)/ or next;
 414         return $value if $key eq $id;
 415     }
 416     close (TIMINGS);
 417     return 0;
 418 }
 419
 420 sub write_timing {
 421     my ($id, $time) = @_;
 422
 423     open (NEWTIMINGS, ">", "$topdir/timings.tmp$$") or return;
 424
 425     if (open (OLDTIMINGS, "<", "$topdir/timings")) {
 426         while (<OLDTIMINGS>) {
 427             if (my ($key, $value) = /^([^=]+)=(.*)/) {
 428                 next if $key eq $id;
 429             }
 430             print NEWTIMINGS $_;
 431         }
 432         close (OLDTIMINGS);
 433     }
 434
 435     print NEWTIMINGS "$id=$time\n";
 436     close (NEWTIMINGS);
 437
 438     rename ("$topdir/timings.tmp$$", "$topdir/timings");
 439 }
 440
 441 sub fail {
 442     die "Build failed, refer to:\n\t$logfile\nfor details.\n";
 443 }