pintos-os.org Git - pspp/blob - build-pspp.m4

   1 m4_define([_m4_divert(INIT_PREPARE)],   300)
   2
   3 m4_pattern_forbid([^_?BP_])
   4 m4_pattern_allow([_BP_EOF])
   5
   6 # BP_INIT([LOGFILE])
   7 # ------------------
   8 # Initializes and starts logging to LOGFILE.
   9 m4_define([BP_INIT],
  10 [AS_INIT
  11 _BP_INIT_LOG([$1])
  12 _BP_INIT_RESULTS
  13 AS_PREPARE
  14 ])
  15
  16 # _BP_INIT_LOG([LOGFILE])
  17 # -----------------------
  18 # Initialize the log file descriptor and write header to it.
  19 m4_define([_BP_INIT_LOG],
  20 [m4_divert_text([INIT_PREPARE],
  21 [m4_define([BP_LOG_FILE], [$1])
  22 m4_define([AS_MESSAGE_LOG_FD], 5)dnl
  23 cat >$1 <<_BPEOF
  24 This file is a build log.
  25
  26 Invocation command line was
  27
  28   $ $[0] $[@]
  29
  30 _BPEOF
  31 exec AS_MESSAGE_LOG_FD>>$1
  32 AS_UNAME >&AS_MESSAGE_LOG_FD
  33
  34 cat >&AS_MESSAGE_LOG_FD <<_BPEOF
  35
  36 _BPEOF
  37 ])])# _BP_INIT_LOG
  38
  39 # _BP_INIT_RESULTS
  40 m4_define([_BP_INIT_RESULTS],
  41 [AS_MKDIR_P([results])
  42 m4_define([BP_VARS_FD], 6)dnl
  43 exec BP_VARS_FD>results/VARS
  44 ])
  45
  46 # _BP_INIT_DEFAULTS
  47 # -----------------
  48 m4_define([_BP_INIT_DEFAULTS],
  49 [m4_divert_push([DEFAULTS])dnl
  50
  51 test -n "$DJDIR" || exec AS_ORIGINAL_STDIN_FD<&0 </dev/null
  52 exec AS_MESSAGE_FD>&1
  53 ])
  54
  55 # BP_START_STEP([MESSAGE])
  56 m4_define([BP_START_STEP],
  57   [AS_ECHO(["$1"])
  58 AS_ECHO(["\f@&t@
  59 $1"]) >&AS_MESSAGE_LOG_FD
  60 ])
  61
  62 # BP_SET_VAR(VARIABLE, [VALUE])
  63 m4_define([BP_SET_VAR],
  64   [m4_if([$2], [], [], [$1='$2'
  65 ])dnl
  66 AS_ECHO(["$1=$[$1]"]) >&BP_VARS_FD
  67 AS_ECHO(["$as_me:$LINENO: $1=$[$1]"]) >&AS_MESSAGE_LOG_FD
  68 AS_ECHO(["      $1=$[$1]"])])
  69
  70 # BP_OUTPUT(DESCRIPTION, FILE)
  71 m4_define([BP_OUTPUT],
  72 [BP_START_STEP([Saving `AS_BASENAME([$2])`: $1])])
  73
  74 # BP_MOVE_OUTPUT(DESCRIPTION, FILE)
  75 m4_define([BP_MOVE_OUTPUT],
  76 [BP_OUTPUT([$1], [$2])
  77 BP_RUN([mv $2 results/ >&AS_MESSAGE_LOG_FD 2>&1])])
  78
  79 # BP_COPY_OUTPUT(DESCRIPTION, FILE)
  80 m4_define([BP_COPY_OUTPUT],
  81 [BP_OUTPUT([$1], [$2])
  82 BP_RUN([cp -R $2 results/ >&AS_MESSAGE_LOG_FD 2>&1])])
  83
  84 # BP_RUN_LOG(COMMAND)
  85 m4_define([BP_RUN_LOG],
  86 [cat <<_BP_EOF >&AS_MESSAGE_LOG_FD
  87 $as_me:$LINENO: $1
  88 _BP_EOF
  89 $1
  90 ])
  91
  92 # BP_RUN(COMMAND)
  93 m4_define([BP_RUN],
  94 [BP_RUN_LOG([$1])
  95 _bp_status=$?
  96 if test $_bp_status != 0; then
  97   AS_ECHO(["Build failed, refer to BP_LOG_FILE for details"])
  98   AS_ECHO(["$as_me:$LINENO: command exited with status $_bp_status"]) >&AS_MESSAGE_LOG_FD
  99   AS_EXIT([1])
 100 fi])
 101
 102 # BP_FINISH
 103 m4_define([BP_FINISH],
 104 [BP_START_STEP([success])])