pintos-os.org Git - pspp/blob - acinclude.m4

   1 dnl Copyright (C) 2005, 2006, 2007, 2009, 2014, 2015, 2021 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Prerequisites.
   7
   8 dnl Summarize all the missing prerequisites at the end of the run to
   9 dnl increase user-friendliness.
  10 AC_DEFUN([PSPP_REQUIRED_PREREQ],
  11   [AC_MSG_WARN([You must install $1 before building PSPP.])
  12 pspp_required_prereqs="$pspp_required_prereqs
  13         $1"])
  14 AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
  15         $1"])
  16 AC_DEFUN([PSPP_CHECK_PREREQS],
  17 [
  18   if test "$pspp_optional_prereqs" != ""; then
  19     AC_MSG_WARN([The following optional packages are not installed.
  20 You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
  21 fi
  22   if test "$pspp_required_prereqs" != ""; then
  23     AC_MSG_ERROR([The following required packages are not installed.
  24 You must install them before PSPP can be built:$pspp_required_prereqs])
  25 fi
  26 ])
  27
  28
  29 dnl Check that a new enough version of Perl is available.
  30 AC_DEFUN([PSPP_PERL],
  31 [
  32   AC_PATH_PROG([PERL], perl, no)
  33   AC_SUBST([PERL])dnl
  34   if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
  35     PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
  36   fi
  37
  38   # The PSPP autobuilder appends a build number to the PSPP version number,
  39   # e.g. "0.7.2-build40".  But Perl won't parse version numbers that contain
  40   # anything other than digits and periods, so "-build" causes an error.  So we
  41   # define $(VERSION_FOR_PERL) that drops everything from the hyphen onward.
  42   VERSION_FOR_PERL=`echo "$VERSION" | sed 's/-.*//'`
  43   AC_SUBST([VERSION_FOR_PERL])
  44 ])
  45
  46 dnl Check that Python 2 or 3 is available.
  47 AC_DEFUN([PSPP_PYTHON],
  48   [AC_ARG_VAR([PYTHON], [Python 2 or 3 interpreter])
  49    AC_CHECK_PROGS([PYTHON], [python python2 python3], [none])])
  50
  51 dnl PSPP_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
  52 dnl Check whether the given C compiler OPTION is accepted.
  53 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
  54 AC_DEFUN([PSPP_CHECK_CC_OPTION],
  55 [
  56   m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
  57   AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name],
  58     [pspp_save_CFLAGS="$CFLAGS"
  59      CFLAGS="$CFLAGS $1"
  60      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
  61      CFLAGS="$pspp_save_CFLAGS"])
  62   if test $pspp_cv_name = yes; then
  63     m4_if([$2], [], [;], [$2])
  64   else
  65     m4_if([$3], [], [:], [$3])
  66   fi
  67 ])
  68
  69 dnl Check for readline and history libraries.
  70
  71 dnl Modified for PSPP, based on readline.m4 serial 3 from
  72 dnl gnulib, which was written by Simon Josefsson, with help from Bruno
  73 dnl Haible and Oskar Liljeblad.
  74
  75 AC_DEFUN([PSPP_READLINE],
  76 [
  77   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  78   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  79   AC_REQUIRE([AC_LIB_RPATH])
  80
  81   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
  82   dnl INCREADLINE accordingly.
  83   AC_LIB_LINKFLAGS_BODY([readline])
  84   AC_LIB_LINKFLAGS_BODY([history])
  85
  86   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
  87   dnl because if the user has installed libreadline and not disabled its use
  88   dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
  89   dnl will then succeed.
  90   am_save_CPPFLAGS="$CPPFLAGS"
  91   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
  92
  93   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
  94     gl_cv_lib_readline=no
  95     am_save_LIBS="$LIBS"
  96     dnl On some systems, -lreadline doesn't link without an additional
  97     dnl -lncurses or -ltermcap.
  98     dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
  99     dnl by design and obsolete since 1994. Try -lcurses last, because
 100     dnl libcurses is unusable on some old Unices.
 101     for extra_lib in "" ncurses termcap curses; do
 102       LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
 103       if test -n "$extra_lib"; then
 104         LIBS="$LIBS -l$extra_lib"
 105       fi
 106       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 107 #include <readline/readline.h>
 108 #include <readline/history.h>]], [[readline((char*)0); add_history((char*)0);]])],[gl_cv_lib_readline=yes],[])
 109       if test "$gl_cv_lib_readline" = yes; then
 110         if test -n "$extra_lib"; then
 111           LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
 112           LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
 113         fi
 114         break
 115       fi
 116     done
 117     LIBS="$am_save_LIBS"
 118   ])
 119
 120   if test "$gl_cv_lib_readline" = yes; then
 121     AC_DEFINE([HAVE_READLINE], 1, [Define if you have the readline library.])
 122     AC_MSG_CHECKING([how to link with libreadline])
 123     AC_MSG_RESULT([$LIBREADLINE])
 124     AC_SEARCH_LIBS([rl_echo_signal_char], [readline],
 125         AC_DEFINE([HAVE_RL_ECHO_SIGNAL_CHAR], 1, [Define if the readline library provides rl_echo_signal_char.]),[],[$LIBREADLINE])
 126     AC_SEARCH_LIBS([rl_outstream], [readline],
 127         AC_DEFINE([HAVE_RL_OUTSTREAM], 1, [Define if the readline library provides rl_outstream.]),[],[$LIBREADLINE])
 128   else
 129     dnl If $LIBREADLINE didn't lead to a usable library, we don't
 130     dnl need $INCREADLINE either.
 131     CPPFLAGS="$am_save_CPPFLAGS"
 132     LIBREADLINE=
 133     LTLIBREADLINE=
 134     LIBHISTORY=
 135     LTLIBHISTORY=
 136     PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
 137   fi
 138   AC_SUBST(LIBREADLINE)
 139   AC_SUBST(LTLIBREADLINE)
 140 ])
 141
 142 dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
 143 AC_DEFUN([PSPP_LC_PAPER],
 144 [AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
 145     pspp_cv_lc_paper=no
 146     AC_COMPILE_IFELSE(
 147       [AC_LANG_PROGRAM(
 148         [#include <locale.h>
 149 #include <langinfo.h>
 150 ],
 151         [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
 152       [pspp_cv_lc_paper=yes])
 153   ])
 154   if test "$pspp_cv_lc_paper" = yes; then
 155     AC_DEFINE([HAVE_LC_PAPER], 1, [Define if you have LC_PAPER.])
 156   fi
 157 ])
 158
 159
 160 # PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 161 # -------------------------------------------------------------
 162 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 163 # into a program.
 164 #
 165 # Test that resulting file is executable; see the problem reported by mwoehlke
 166 # in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
 167 # But skip the test when cross-compiling, to prevent problems like the one
 168 # reported by Chris Johns in
 169 # <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
 170 #
 171 m4_define([PSPP_LINK2_IFELSE],
 172 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 173 mv conftest.$ac_ext conftest1.$ac_ext
 174 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 175 mv conftest.$ac_ext conftest2.$ac_ext
 176 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 177 pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 178 AS_IF([_AC_DO_STDERR($pspp_link2) && {
 179          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 180          test ! -s conftest.err
 181        } && test -s conftest$ac_exeext && {
 182          test "$cross_compiling" = yes ||
 183          AS_TEST_X([conftest$ac_exeext])
 184        }],
 185       [$3],
 186       [echo "$as_me: failed source file 1 of 2 was:" >&5
 187 sed 's/^/| /' conftest1.$ac_ext >&5
 188 echo "$as_me: failed source file 2 of 2 was:" >&5
 189 sed 's/^/| /' conftest2.$ac_ext >&5
 190         $4])
 191 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 192 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 193 dnl as it would interfere with the next link command.
 194 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 195 rm -f core conftest.err conftest1.err conftest2.err
 196 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 197 rm -f conftest$ac_exeext
 198 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 199 ])# PSPP_LINK2_IFELSE
 200
 201 # GSL uses "extern inline" without determining whether the compiler uses
 202 # GCC inline rules or C99 inline rules.  If it uses the latter then GSL
 203 # will be broken without passing -fgnu89-inline to GCC.
 204 AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
 205 [# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
 206  # In turn, gnulib's gl_INLINE is one macro that does that.  We need to
 207  # make sure that it has run by the time we run this test, otherwise we'll
 208  # get a false result.
 209  AC_REQUIRE([gl_INLINE])
 210  PSPP_CHECK_CC_OPTION(
 211    [-fgnu89-inline],
 212    [AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
 213                     pspp_cv_gsl_needs_fgnu89_inline, [
 214                     PSPP_LINK2_IFELSE(
 215                       [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
 216                                        ], [GSL_MAX_INT(1,2);])],
 217                       [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
 218                                        void x (void) {}])],
 219                       [pspp_cv_gsl_needs_fgnu89_inline=no],
 220                       [pspp_cv_gsl_needs_fgnu89_inline=yes])])
 221      if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
 222          CFLAGS="$CFLAGS -fgnu89-inline"
 223      fi])
 224 ])
 225
 226 AC_DEFUN([PSPP_CHECK_CLICKSEQUENCE],
 227   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 228    AC_CACHE_CHECK([whether makeinfo supports @clicksequence],
 229      [pspp_cv_have_clicksequence],
 230      [cat > conftest.texi  <<EOF
 231 @setfilename conftest.info
 232 @clicksequence{File @click{} Open}
 233 EOF
 234       echo "configure:__oline__: running $MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
 235       eval "$MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD 2>&1"
 236       retval=$?
 237       echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
 238       if test $retval = 0; then
 239         pspp_cv_have_clicksequence=yes
 240       else
 241         pspp_cv_have_clicksequence=no
 242       fi
 243       rm -f conftest.texi conftest.info])
 244    if test $pspp_cv_have_clicksequence = no; then
 245        AC_MSG_ERROR([$MAKEINFO does not support @clicksequence.
 246 Please install a newer or working version, or point the MAKEINFO variable
 247 to one that is already installed.])
 248    fi])
 249
 250 dnl Texinfo 4.13 generates broken DocBook XML.  Probably other old
 251 dnl versions do too, but that's the one that causes problems.
 252 AC_DEFUN([PSPP_CHECK_MAKEINFO_DOCBOOK_XML],
 253   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 254    AC_CACHE_CHECK(
 255      [whether makeinfo generates broken DocBook XML],
 256      [pspp_cv_broken_docbook_xml],
 257      [AS_CASE(
 258         [$(eval "$MAKEINFO --version | head -1")],
 259         [*texinfo*4.13*], [pspp_cv_broken_docbook_xml=yes],
 260         [*texinfo*], [pspp_cv_broken_docbook_xml=no],
 261         [*], [pspp_cv_broken_docbook_xml=yes])])
 262    AM_CONDITIONAL(
 263      [BROKEN_DOCBOOK_XML], [test "$pspp_cv_broken_docbook_xml" = yes])])
 264
 265 # The following comes from Open vSwitch:
 266 # ----------------------------------------------------------------------
 267 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
 268 #
 269 # Licensed under the Apache License, Version 2.0 (the "License");
 270 # you may not use this file except in compliance with the License.
 271 # You may obtain a copy of the License at:
 272 #
 273 #     http://www.apache.org/licenses/LICENSE-2.0
 274 #
 275 # Unless required by applicable law or agreed to in writing, software
 276 # distributed under the License is distributed on an "AS IS" BASIS,
 277 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 278 # See the License for the specific language governing permissions and
 279 # limitations under the License.
 280
 281 dnl PSPP_ENABLE_WERROR
 282 AC_DEFUN([PSPP_ENABLE_WERROR],
 283   [AC_ARG_ENABLE(
 284      [Werror],
 285      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
 286      [], [enable_Werror=no])
 287    AC_CONFIG_COMMANDS_PRE(
 288      [if test "X$enable_Werror" = Xyes; then
 289         CFLAGS="$CFLAGS -Werror -Wno-error=deprecated-declarations"
 290         # gnulib needs this, for now:
 291         CFLAGS="$CFLAGS -Wno-error=attributes"
 292       fi])])
 293
 294 # The following comes from Open vSwitch:
 295 # ----------------------------------------------------------------------
 296 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
 297 #
 298 # Licensed under the Apache License, Version 2.0 (the "License");
 299 # you may not use this file except in compliance with the License.
 300 # You may obtain a copy of the License at:
 301 #
 302 #     http://www.apache.org/licenses/LICENSE-2.0
 303 #
 304 # Unless required by applicable law or agreed to in writing, software
 305 # distributed under the License is distributed on an "AS IS" BASIS,
 306 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 307 # See the License for the specific language governing permissions and
 308 # limitations under the License.
 309
 310 dnl Checks for dot.
 311 AC_DEFUN([PSPP_CHECK_DOT],
 312   [AC_CACHE_CHECK(
 313     [for dot],
 314     [pspp_cv_dot],
 315     [dnl "dot" writes -V output to stderr:
 316      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 317        pspp_cv_dot=yes
 318      else
 319        pspp_cv_dot=no
 320      fi])
 321    AM_CONDITIONAL([HAVE_DOT], [test "$pspp_cv_dot" = yes])])
 322
 323
 324 dnl Check that xgettext is sufficiently recent
 325 dnl Before calling this macro, AC_CHECK_PROGS([XGETTEXT], [xgettext]) should have been called,
 326 dnl which sets the ac_cv_prog_XGETTEXT cache variable.
 327 AC_DEFUN([PSPP_CHECK_XGETTEXT],
 328  [AC_CACHE_CHECK([whether gettext is sufficiently recent],
 329    [pspp_cv_progrecent_xgettext],
 330    [pspp_cv_progrecent_xgettext=maybe
 331     ver=`$ac_cv_prog_XGETTEXT --version | sed -n -e '/xgettext/s/[[^0-9]]*\([[0-9\.]][[0-9\.]]*\).*/\1/p'`
 332     case $ver in # (
 333       *.*.*) ;; # (
 334       *.*) ver="$ver.0" ;;
 335     esac
 336     majmin=`echo $ver | sed -e 's/\.[[0-9]]*$//'`
 337     major=`echo $majmin | sed -e 's/\.[[0-9]]*$//'`
 338     minor=`echo $majmin | sed -e 's/^[[0-9]]*\.//'`
 339     if test "$major" -lt 0; then
 340       pspp_cv_progrecent_xgettext=no;
 341     elif test "$minor" -lt 20; then
 342       pspp_cv_progrecent_xgettext=no
 343     else
 344       pspp_cv_progrecent_xgettext=yes
 345     fi])])