pintos-os.org Git - pspp/blob - acinclude.m4

   1 dnl Copyright (C) 2005, 2006, 2007, 2009, 2014, 2015, 2021 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Prerequisites.
   7
   8 dnl Summarize all the missing prerequisites at the end of the run to
   9 dnl increase user-friendliness.
  10 AC_DEFUN([PSPP_REQUIRED_PREREQ],
  11   [AC_MSG_WARN([You must install $1 before building PSPP.])
  12 pspp_required_prereqs="$pspp_required_prereqs
  13         $1"])
  14 AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
  15         $1"])
  16 AC_DEFUN([PSPP_CHECK_PREREQS],
  17 [
  18   if test "$pspp_optional_prereqs" != ""; then
  19     AC_MSG_WARN([The following optional packages are not installed.
  20 You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
  21 fi
  22   if test "$pspp_required_prereqs" != ""; then
  23     AC_MSG_ERROR([The following required packages are not installed.
  24 You must install them before PSPP can be built:$pspp_required_prereqs])
  25 fi
  26 ])
  27
  28
  29 dnl Check that a new enough version of Perl is available.
  30 AC_DEFUN([PSPP_PERL],
  31 [
  32   AC_PATH_PROG([PERL], perl, no)
  33   AC_SUBST([PERL])dnl
  34   if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
  35     PSPP_OPTIONAL_PREREQ([Perl 5.005_03 (or later)])
  36   fi
  37
  38   # The PSPP autobuilder appends a build number to the PSPP version number,
  39   # e.g. "0.7.2-build40".  But Perl won't parse version numbers that contain
  40   # anything other than digits and periods, so "-build" causes an error.  So we
  41   # define $(VERSION_FOR_PERL) that drops everything from the hyphen onward.
  42   VERSION_FOR_PERL=`echo "$VERSION" | sed 's/-.*//'`
  43   AC_SUBST([VERSION_FOR_PERL])
  44 ])
  45
  46 dnl CHECK_PERL_MODULE([MODULE], [RUN-IF-AVAILABLE], [RUN-IF-NOT-AVAILABLE])
  47 AC_DEFUN([CHECK_PERL_MODULE],
  48   [echo "configure:__oline__: running $PERL -M$1 -e '' >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
  49    $PERL -M$1 -e '' >&AS_MESSAGE_LOG_FD 2>&1
  50    retval=$?
  51    echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
  52    AS_IF([test $retval = 0], [$2], [$3])])
  53
  54 AC_DEFUN([PSPP_PERL_MODULE],
  55   [AC_ARG_WITH(
  56      [perl-module],
  57      [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
  58      [AS_CASE([$with_perl_module],
  59         [yes|no], [],
  60         [AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no'])])
  61       WITH_PERL_MODULE=$with_perl_module],
  62      [if test "$PERL" != no && test x"$cross_compiling" != x"yes"; then
  63         WITH_PERL_MODULE=yes
  64       else
  65         WITH_PERL_MODULE=no
  66       fi])
  67    AC_SUBST([WITH_PERL_MODULE])
  68    AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
  69
  70    if test $WITH_PERL_MODULE = yes; then
  71      if test "$PERL" = no; then
  72        PSPP_REQUIRED_PREREQ([Perl 5.005_03 or later (or use --without-perl-module)])
  73      fi
  74      CHECK_PERL_MODULE([Config::Perl::V], [],
  75        [PSPP_REQUIRED_PREREQ([Config::Perl::V Perl module (or use --without-perl-module)])])
  76      CHECK_PERL_MODULE([Text::Diff], [],
  77        [PSPP_OPTIONAL_PREREQ([Text::Diff Perl module for running Perl tests])])
  78      CHECK_PERL_MODULE([Memory::Usage], [],
  79        [PSPP_OPTIONAL_PREREQ([Memory::Usage Perl module for running Perl tests])])
  80    fi])
  81
  82 dnl Check that Python 3 is available.
  83 AC_DEFUN([PSPP_PYTHON3],
  84   [AC_ARG_VAR([PYTHON3], [Python 3 interpreter])
  85    AC_CHECK_PROGS([PYTHON3], [python3 python], [none])
  86    if test "$PYTHON3" != no && $PYTHON3 -c '
  87 import sys
  88 sys.exit(0 if sys.version_info >= (3,4) else 1)
  89 '; then :; else
  90      PSPP_REQUIRED_PREREQ([Python 3.4 (or later)])
  91    fi
  92   ])
  93
  94 dnl PSPP_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
  95 dnl Check whether the given C compiler OPTION is accepted.
  96 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
  97 AC_DEFUN([PSPP_CHECK_CC_OPTION],
  98 [
  99   m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
 100   AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name],
 101     [pspp_save_CFLAGS="$CFLAGS"
 102      CFLAGS="$CFLAGS $1"
 103      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
 104      CFLAGS="$pspp_save_CFLAGS"])
 105   if test $pspp_cv_name = yes; then
 106     m4_if([$2], [], [;], [$2])
 107   else
 108     m4_if([$3], [], [:], [$3])
 109   fi
 110 ])
 111
 112 # PSPP_ENABLE_OPTION comes from Open vSwitch:
 113 # ----------------------------------------------------------------------
 114 # Copyright (c) 2007-2017 Nicira, Inc.
 115 #
 116 # Licensed under the Apache License, Version 2.0 (the "License");
 117 # you may not use this file except in compliance with the License.
 118 # You may obtain a copy of the License at:
 119 #
 120 #     http://www.apache.org/licenses/LICENSE-2.0
 121 #
 122 # Unless required by applicable law or agreed to in writing, software
 123 # distributed under the License is distributed on an "AS IS" BASIS,
 124 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 125 # See the License for the specific language governing permissions and
 126 # limitations under the License.
 127 dnl PSPP_ENABLE_OPTION([OPTION])
 128 dnl Check whether the given C compiler OPTION is accepted.
 129 dnl If so, add it to WARNING_FLAGS.
 130 dnl Example: PSPP_ENABLE_OPTION([-Wdeclaration-after-statement])
 131 AC_DEFUN([PSPP_ENABLE_OPTION],
 132   [PSPP_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 133    AC_SUBST([WARNING_FLAGS])])
 134 # ----------------------------------------------------------------------
 135
 136 dnl Check for readline and history libraries.
 137
 138 dnl Modified for PSPP, based on readline.m4 serial 3 from
 139 dnl gnulib, which was written by Simon Josefsson, with help from Bruno
 140 dnl Haible and Oskar Liljeblad.
 141
 142 AC_DEFUN([PSPP_READLINE],
 143 [
 144   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
 145   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
 146   AC_REQUIRE([AC_LIB_RPATH])
 147
 148   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
 149   dnl INCREADLINE accordingly.
 150   AC_LIB_LINKFLAGS_BODY([readline])
 151   AC_LIB_LINKFLAGS_BODY([history])
 152
 153   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
 154   dnl because if the user has installed libreadline and not disabled its use
 155   dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
 156   dnl will then succeed.
 157   am_save_CPPFLAGS="$CPPFLAGS"
 158   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
 159
 160   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
 161     gl_cv_lib_readline=no
 162     am_save_LIBS="$LIBS"
 163     dnl On some systems, -lreadline doesn't link without an additional
 164     dnl -lncurses or -ltermcap.
 165     dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
 166     dnl by design and obsolete since 1994. Try -lcurses last, because
 167     dnl libcurses is unusable on some old Unices.
 168     for extra_lib in "" ncurses termcap curses; do
 169       LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
 170       if test -n "$extra_lib"; then
 171         LIBS="$LIBS -l$extra_lib"
 172       fi
 173       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 174 #include <readline/readline.h>
 175 #include <readline/history.h>]], [[readline((char*)0); add_history((char*)0);]])],[gl_cv_lib_readline=yes],[])
 176       if test "$gl_cv_lib_readline" = yes; then
 177         if test -n "$extra_lib"; then
 178           LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
 179           LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
 180         fi
 181         break
 182       fi
 183     done
 184     LIBS="$am_save_LIBS"
 185   ])
 186
 187   if test "$gl_cv_lib_readline" = yes; then
 188     AC_DEFINE([HAVE_READLINE], 1, [Define if you have the readline library.])
 189     AC_MSG_CHECKING([how to link with libreadline])
 190     AC_MSG_RESULT([$LIBREADLINE])
 191     AC_SEARCH_LIBS([rl_echo_signal_char], [readline],
 192         AC_DEFINE([HAVE_RL_ECHO_SIGNAL_CHAR], 1, [Define if the readline library provides rl_echo_signal_char.]),[],[$LIBREADLINE])
 193     AC_SEARCH_LIBS([rl_outstream], [readline],
 194         AC_DEFINE([HAVE_RL_OUTSTREAM], 1, [Define if the readline library provides rl_outstream.]),[],[$LIBREADLINE])
 195   else
 196     dnl If $LIBREADLINE didn't lead to a usable library, we don't
 197     dnl need $INCREADLINE either.
 198     CPPFLAGS="$am_save_CPPFLAGS"
 199     LIBREADLINE=
 200     LTLIBREADLINE=
 201     LIBHISTORY=
 202     LTLIBHISTORY=
 203     PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
 204   fi
 205   AC_SUBST(LIBREADLINE)
 206   AC_SUBST(LTLIBREADLINE)
 207 ])
 208
 209 dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
 210 AC_DEFUN([PSPP_LC_PAPER],
 211 [AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
 212     pspp_cv_lc_paper=no
 213     AC_COMPILE_IFELSE(
 214       [AC_LANG_PROGRAM(
 215         [#include <locale.h>
 216 #include <langinfo.h>
 217 ],
 218         [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
 219       [pspp_cv_lc_paper=yes])
 220   ])
 221   if test "$pspp_cv_lc_paper" = yes; then
 222     AC_DEFINE([HAVE_LC_PAPER], 1, [Define if you have LC_PAPER.])
 223   fi
 224 ])
 225
 226
 227 # PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 228 # -------------------------------------------------------------
 229 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 230 # into a program.
 231 #
 232 # Test that resulting file is executable; see the problem reported by mwoehlke
 233 # in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
 234 # But skip the test when cross-compiling, to prevent problems like the one
 235 # reported by Chris Johns in
 236 # <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
 237 #
 238 m4_define([PSPP_LINK2_IFELSE],
 239 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 240 mv conftest.$ac_ext conftest1.$ac_ext
 241 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 242 mv conftest.$ac_ext conftest2.$ac_ext
 243 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 244 pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 245 AS_IF([_AC_DO_STDERR($pspp_link2) && {
 246          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 247          test ! -s conftest.err
 248        } && test -s conftest$ac_exeext && {
 249          test "$cross_compiling" = yes ||
 250          AS_TEST_X([conftest$ac_exeext])
 251        }],
 252       [$3],
 253       [echo "$as_me: failed source file 1 of 2 was:" >&5
 254 sed 's/^/| /' conftest1.$ac_ext >&5
 255 echo "$as_me: failed source file 2 of 2 was:" >&5
 256 sed 's/^/| /' conftest2.$ac_ext >&5
 257         $4])
 258 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 259 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 260 dnl as it would interfere with the next link command.
 261 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 262 rm -f core conftest.err conftest1.err conftest2.err
 263 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 264 rm -f conftest$ac_exeext
 265 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 266 ])# PSPP_LINK2_IFELSE
 267
 268 # GSL uses "extern inline" without determining whether the compiler uses
 269 # GCC inline rules or C99 inline rules.  If it uses the latter then GSL
 270 # will be broken without passing -fgnu89-inline to GCC.
 271 AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
 272 [# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
 273  # In turn, gnulib's gl_INLINE is one macro that does that.  We need to
 274  # make sure that it has run by the time we run this test, otherwise we'll
 275  # get a false result.
 276  AC_REQUIRE([gl_INLINE])
 277  PSPP_CHECK_CC_OPTION(
 278    [-fgnu89-inline],
 279    [AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
 280                     pspp_cv_gsl_needs_fgnu89_inline, [
 281                     PSPP_LINK2_IFELSE(
 282                       [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
 283                                        ], [GSL_MAX_INT(1,2);])],
 284                       [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
 285                                        void x (void) {}])],
 286                       [pspp_cv_gsl_needs_fgnu89_inline=no],
 287                       [pspp_cv_gsl_needs_fgnu89_inline=yes])])
 288      if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
 289          CFLAGS="$CFLAGS -fgnu89-inline"
 290      fi])
 291 ])
 292
 293 AC_DEFUN([PSPP_CHECK_CLICKSEQUENCE],
 294   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 295    AC_CACHE_CHECK([whether makeinfo supports @clicksequence],
 296      [pspp_cv_have_clicksequence],
 297      [cat > conftest.texi  <<EOF
 298 @setfilename conftest.info
 299 @clicksequence{File @click{} Open}
 300 EOF
 301       echo "configure:__oline__: running $MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
 302       eval "$MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD 2>&1"
 303       retval=$?
 304       echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
 305       if test $retval = 0; then
 306         pspp_cv_have_clicksequence=yes
 307       else
 308         pspp_cv_have_clicksequence=no
 309       fi
 310       rm -f conftest.texi conftest.info])
 311    if test $pspp_cv_have_clicksequence = no; then
 312        AC_MSG_ERROR([$MAKEINFO does not support @clicksequence.
 313 Please install a newer or working version, or point the MAKEINFO variable
 314 to one that is already installed.])
 315    fi])
 316
 317 dnl Texinfo 4.13 generates broken DocBook XML.  Probably other old
 318 dnl versions do too, but that's the one that causes problems.
 319 AC_DEFUN([PSPP_CHECK_MAKEINFO_DOCBOOK_XML],
 320   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 321    AC_CACHE_CHECK(
 322      [whether makeinfo generates broken DocBook XML],
 323      [pspp_cv_broken_docbook_xml],
 324      [AS_CASE(
 325         [$(eval "$MAKEINFO --version | head -1")],
 326         [*texinfo*4.13*], [pspp_cv_broken_docbook_xml=yes],
 327         [*texinfo*], [pspp_cv_broken_docbook_xml=no],
 328         [*], [pspp_cv_broken_docbook_xml=yes])])
 329    AM_CONDITIONAL(
 330      [BROKEN_DOCBOOK_XML], [test "$pspp_cv_broken_docbook_xml" = yes])])
 331
 332 # The following comes from Open vSwitch:
 333 # ----------------------------------------------------------------------
 334 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
 335 #
 336 # Licensed under the Apache License, Version 2.0 (the "License");
 337 # you may not use this file except in compliance with the License.
 338 # You may obtain a copy of the License at:
 339 #
 340 #     http://www.apache.org/licenses/LICENSE-2.0
 341 #
 342 # Unless required by applicable law or agreed to in writing, software
 343 # distributed under the License is distributed on an "AS IS" BASIS,
 344 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 345 # See the License for the specific language governing permissions and
 346 # limitations under the License.
 347
 348 dnl PSPP_ENABLE_WERROR
 349 AC_DEFUN([PSPP_ENABLE_WERROR],
 350   [AC_ARG_ENABLE(
 351      [Werror],
 352      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
 353      [], [enable_Werror=no])
 354    AC_CONFIG_COMMANDS_PRE(
 355      [if test "X$enable_Werror" = Xyes; then
 356         CFLAGS="$CFLAGS -Werror -Wno-error=deprecated-declarations"
 357         # gnulib needs this, for now:
 358         CFLAGS="$CFLAGS -Wno-error=attributes"
 359       fi])])
 360
 361 # The following comes from Open vSwitch:
 362 # ----------------------------------------------------------------------
 363 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
 364 #
 365 # Licensed under the Apache License, Version 2.0 (the "License");
 366 # you may not use this file except in compliance with the License.
 367 # You may obtain a copy of the License at:
 368 #
 369 #     http://www.apache.org/licenses/LICENSE-2.0
 370 #
 371 # Unless required by applicable law or agreed to in writing, software
 372 # distributed under the License is distributed on an "AS IS" BASIS,
 373 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 374 # See the License for the specific language governing permissions and
 375 # limitations under the License.
 376
 377 dnl Checks for dot.
 378 AC_DEFUN([PSPP_CHECK_DOT],
 379   [AC_CACHE_CHECK(
 380     [for dot],
 381     [pspp_cv_dot],
 382     [dnl "dot" writes -V output to stderr:
 383      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 384        pspp_cv_dot=yes
 385      else
 386        pspp_cv_dot=no
 387      fi])
 388    AM_CONDITIONAL([HAVE_DOT], [test "$pspp_cv_dot" = yes])])
 389
 390
 391 dnl Check that xgettext is sufficiently recent
 392 dnl Before calling this macro, AC_CHECK_PROGS([XGETTEXT], [xgettext]) should have been called,
 393 dnl which sets the ac_cv_prog_XGETTEXT cache variable.
 394 AC_DEFUN([PSPP_CHECK_XGETTEXT],
 395  [AC_CACHE_CHECK([whether gettext is sufficiently recent],
 396    [pspp_cv_progrecent_xgettext],
 397    [pspp_cv_progrecent_xgettext=maybe
 398     ver=`$ac_cv_prog_XGETTEXT --version | sed -n -e '/xgettext/s/[[^0-9]]*\([[0-9\.]][[0-9\.]]*\).*/\1/p'`
 399     case $ver in # (
 400       *.*.*) ;; # (
 401       *.*) ver="$ver.0" ;;
 402     esac
 403     majmin=`echo $ver | sed -e 's/\.[[0-9]]*$//'`
 404     major=`echo $majmin | sed -e 's/\.[[0-9]]*$//'`
 405     minor=`echo $majmin | sed -e 's/^[[0-9]]*\.//'`
 406     if test "$major" -lt 0; then
 407       pspp_cv_progrecent_xgettext=no;
 408     elif test "$minor" -lt 20; then
 409       pspp_cv_progrecent_xgettext=no
 410     else
 411       pspp_cv_progrecent_xgettext=yes
 412     fi])])