pintos-os.org Git - pspp/blob - acinclude.m4

   1 dnl Copyright (C) 2005, 2006, 2007, 2009, 2014, 2015 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Prerequisites.
   7
   8 dnl Summarize all the missing prerequisites at the end of the run to
   9 dnl increase user-friendliness.
  10 AC_DEFUN([PSPP_REQUIRED_PREREQ],
  11   [AC_MSG_WARN([You must install $1 before building PSPP.])
  12 pspp_required_prereqs="$pspp_required_prereqs
  13         $1"])
  14 AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
  15         $1"])
  16 AC_DEFUN([PSPP_CHECK_PREREQS],
  17 [
  18   if test "$pspp_optional_prereqs" != ""; then
  19     AC_MSG_WARN([The following optional prerequisites are not installed.
  20 You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
  21 fi
  22   if test "$pspp_required_prereqs" != ""; then
  23     AC_MSG_ERROR([The following required prerequisites are not installed.
  24 You must install them before PSPP can be built:$pspp_required_prereqs])
  25 fi
  26 ])
  27
  28
  29 dnl Check that a new enough version of Perl is available.
  30 AC_DEFUN([PSPP_PERL],
  31 [
  32   AC_PATH_PROG([PERL], perl, no)
  33   AC_SUBST([PERL])dnl
  34   if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
  35     PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
  36   fi
  37
  38   # The PSPP autobuilder appends a build number to the PSPP version number,
  39   # e.g. "0.7.2-build40".  But Perl won't parse version numbers that contain
  40   # anything other than digits and periods, so "-build" causes an error.  So we
  41   # define $(VERSION_FOR_PERL) that drops everything from the hyphen onward.
  42   VERSION_FOR_PERL=`echo "$VERSION" | sed 's/-.*//'`
  43   AC_SUBST([VERSION_FOR_PERL])
  44 ])
  45
  46 dnl PSPP_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
  47 dnl Check whether the given C compiler OPTION is accepted.
  48 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
  49 AC_DEFUN([PSPP_CHECK_CC_OPTION],
  50 [
  51   m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
  52   AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name],
  53     [pspp_save_CFLAGS="$CFLAGS"
  54      CFLAGS="$CFLAGS $1"
  55      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
  56      CFLAGS="$pspp_save_CFLAGS"])
  57   if test $pspp_cv_name = yes; then
  58     m4_if([$2], [], [;], [$2])
  59   else
  60     m4_if([$3], [], [:], [$3])
  61   fi
  62 ])
  63
  64 dnl Check for readline and history libraries.
  65
  66 dnl Modified for PSPP, based on readline.m4 serial 3 from
  67 dnl gnulib, which was written by Simon Josefsson, with help from Bruno
  68 dnl Haible and Oskar Liljeblad.
  69
  70 AC_DEFUN([PSPP_READLINE],
  71 [
  72   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  73   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  74   AC_REQUIRE([AC_LIB_RPATH])
  75
  76   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
  77   dnl INCREADLINE accordingly.
  78   AC_LIB_LINKFLAGS_BODY([readline])
  79   AC_LIB_LINKFLAGS_BODY([history])
  80
  81   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
  82   dnl because if the user has installed libreadline and not disabled its use
  83   dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
  84   dnl will then succeed.
  85   am_save_CPPFLAGS="$CPPFLAGS"
  86   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
  87
  88   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
  89     gl_cv_lib_readline=no
  90     am_save_LIBS="$LIBS"
  91     dnl On some systems, -lreadline doesn't link without an additional
  92     dnl -lncurses or -ltermcap.
  93     dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
  94     dnl by design and obsolete since 1994. Try -lcurses last, because
  95     dnl libcurses is unusable on some old Unices.
  96     for extra_lib in "" ncurses termcap curses; do
  97       LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
  98       if test -n "$extra_lib"; then
  99         LIBS="$LIBS -l$extra_lib"
 100       fi
 101       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 102 #include <readline/readline.h>
 103 #include <readline/history.h>]], [[readline((char*)0); add_history((char*)0);]])],[gl_cv_lib_readline=yes],[])
 104       if test "$gl_cv_lib_readline" = yes; then
 105         if test -n "$extra_lib"; then
 106           LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
 107           LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
 108         fi
 109         break
 110       fi
 111     done
 112     LIBS="$am_save_LIBS"
 113   ])
 114
 115   if test "$gl_cv_lib_readline" = yes; then
 116     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
 117     AC_MSG_CHECKING([how to link with libreadline])
 118     AC_MSG_RESULT([$LIBREADLINE])
 119     AC_SEARCH_LIBS([rl_echo_signal_char], [readline],
 120         AC_DEFINE(HAVE_RL_ECHO_SIGNAL_CHAR, 1, [Define if the readline library provides rl_echo_signal_char.]),[],[$LIBREADLINE])
 121     AC_SEARCH_LIBS([rl_outstream], [readline],
 122         AC_DEFINE(HAVE_RL_OUTSTREAM, 1, [Define if the readline library provides rl_outstream.]),[],[$LIBREADLINE])
 123   else
 124     dnl If $LIBREADLINE didn't lead to a usable library, we don't
 125     dnl need $INCREADLINE either.
 126     CPPFLAGS="$am_save_CPPFLAGS"
 127     LIBREADLINE=
 128     LTLIBREADLINE=
 129     LIBHISTORY=
 130     LTLIBHISTORY=
 131     PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
 132   fi
 133   AC_SUBST(LIBREADLINE)
 134   AC_SUBST(LTLIBREADLINE)
 135 ])
 136
 137 dnl Check for build tools.  Adapted from bfd library.
 138
 139 AC_DEFUN([PSPP_CC_FOR_BUILD],
 140 [# Put a plausible default for CC_FOR_BUILD in Makefile.
 141 if test -z "$CC_FOR_BUILD"; then
 142   if test "x$cross_compiling" = "xno"; then
 143     CC_FOR_BUILD='$(CC)'
 144   else
 145     CC_FOR_BUILD=cc
 146   fi
 147 fi
 148 AC_SUBST(CC_FOR_BUILD)
 149 # Also set EXEEXT_FOR_BUILD.
 150 if test "x$cross_compiling" = "xno"; then
 151   EXEEXT_FOR_BUILD='$(EXEEXT)'
 152 else
 153   AC_CACHE_CHECK([for build system executable suffix], pspp_cv_build_exeext,
 154     [rm -f conftest*
 155      echo 'int main () { return 0; }' > conftest.c
 156      pspp_cv_build_exeext=
 157      ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5
 158      for file in conftest.*; do
 159        case $file in # (
 160        *.c | *.o | *.obj | *.ilk | *.pdb) ;; # (
 161        *) pspp_cv_build_exeext=`echo $file | sed -e s/conftest//` ;;
 162        esac
 163      done
 164      rm -f conftest*
 165      test x"${pspp_cv_build_exeext}" = x && pspp_cv_build_exeext=no])
 166   EXEEXT_FOR_BUILD=""
 167   test x"${pspp_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${pspp_cv_build_exeex
 168 t}
 169 fi
 170 AC_SUBST(EXEEXT_FOR_BUILD)])
 171
 172 dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
 173 AC_DEFUN([PSPP_LC_PAPER],
 174 [AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
 175     pspp_cv_lc_paper=no
 176     AC_COMPILE_IFELSE(
 177       [AC_LANG_PROGRAM(
 178         [#include <locale.h>
 179 #include <langinfo.h>
 180 ],
 181         [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
 182       [pspp_cv_lc_paper=yes])
 183   ])
 184   if test "$pspp_cv_lc_paper" = yes; then
 185     AC_DEFINE(HAVE_LC_PAPER, 1, [Define if you have LC_PAPER.])
 186   fi
 187 ])
 188
 189
 190 # PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 191 # -------------------------------------------------------------
 192 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 193 # into a program.
 194 #
 195 # Test that resulting file is executable; see the problem reported by mwoehlke
 196 # in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
 197 # But skip the test when cross-compiling, to prevent problems like the one
 198 # reported by Chris Johns in
 199 # <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
 200 #
 201 m4_define([PSPP_LINK2_IFELSE],
 202 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 203 mv conftest.$ac_ext conftest1.$ac_ext
 204 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 205 mv conftest.$ac_ext conftest2.$ac_ext
 206 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 207 pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 208 AS_IF([_AC_DO_STDERR($pspp_link2) && {
 209          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 210          test ! -s conftest.err
 211        } && test -s conftest$ac_exeext && {
 212          test "$cross_compiling" = yes ||
 213          AS_TEST_X([conftest$ac_exeext])
 214        }],
 215       [$3],
 216       [echo "$as_me: failed source file 1 of 2 was:" >&5
 217 sed 's/^/| /' conftest1.$ac_ext >&5
 218 echo "$as_me: failed source file 2 of 2 was:" >&5
 219 sed 's/^/| /' conftest2.$ac_ext >&5
 220         $4])
 221 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 222 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 223 dnl as it would interfere with the next link command.
 224 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 225 rm -f core conftest.err conftest1.err conftest2.err
 226 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 227 rm -f conftest$ac_exeext
 228 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 229 ])# PSPP_LINK2_IFELSE
 230
 231 # GSL uses "extern inline" without determining whether the compiler uses
 232 # GCC inline rules or C99 inline rules.  If it uses the latter then GSL
 233 # will be broken without passing -fgnu89-inline to GCC.
 234 AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
 235 [# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
 236  # In turn, gnulib's gl_INLINE is one macro that does that.  We need to
 237  # make sure that it has run by the time we run this test, otherwise we'll
 238  # get a false result.
 239  AC_REQUIRE([gl_INLINE])
 240  PSPP_CHECK_CC_OPTION(
 241    [-fgnu89-inline],
 242    [AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
 243                     pspp_cv_gsl_needs_fgnu89_inline, [
 244                     PSPP_LINK2_IFELSE(
 245                       [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
 246                                        ], [GSL_MAX_INT(1,2);])],
 247                       [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
 248                                        void x (void) {}])],
 249                       [pspp_cv_gsl_needs_fgnu89_inline=no],
 250                       [pspp_cv_gsl_needs_fgnu89_inline=yes])])
 251      if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
 252          CFLAGS="$CFLAGS -fgnu89-inline"
 253      fi])
 254 ])
 255
 256 AC_DEFUN([PSPP_CHECK_CLICKSEQUENCE],
 257   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 258    AC_CACHE_CHECK([whether makeinfo supports @clicksequence],
 259      [pspp_cv_have_clicksequence],
 260      [cat > conftest.texi  <<EOF
 261 @setfilename conftest.info
 262 @clicksequence{File @click{} Open}
 263 EOF
 264       echo "configure:__oline__: running $MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
 265       eval "$MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD 2>&1"
 266       retval=$?
 267       echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
 268       if test $retval = 0; then
 269         pspp_cv_have_clicksequence=yes
 270       else
 271         pspp_cv_have_clicksequence=no
 272       fi
 273       rm -f conftest.texi conftest.info])
 274    if test $pspp_cv_have_clicksequence = no; then
 275        AM_MAKEINFOFLAGS="$AM_MAKEINFOFLAGS -DMISSING_CLICKSEQUENCE"
 276        AC_SUBST([AM_MAKEINFOFLAGS])
 277    fi])
 278
 279 # The following comes from Open vSwitch:
 280 # ----------------------------------------------------------------------
 281 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
 282 #
 283 # Licensed under the Apache License, Version 2.0 (the "License");
 284 # you may not use this file except in compliance with the License.
 285 # You may obtain a copy of the License at:
 286 #
 287 #     http://www.apache.org/licenses/LICENSE-2.0
 288 #
 289 # Unless required by applicable law or agreed to in writing, software
 290 # distributed under the License is distributed on an "AS IS" BASIS,
 291 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 292 # See the License for the specific language governing permissions and
 293 # limitations under the License.
 294
 295 dnl PSPP_ENABLE_WERROR
 296 AC_DEFUN([PSPP_ENABLE_WERROR],
 297   [AC_ARG_ENABLE(
 298      [Werror],
 299      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
 300      [], [enable_Werror=no])
 301    AC_CONFIG_COMMANDS_PRE(
 302      [if test "X$enable_Werror" = Xyes; then
 303         CFLAGS="$CFLAGS -Werror -Wno-error=deprecated-declarations"
 304       fi])])
 305
 306 # The following comes from Open vSwitch:
 307 # ----------------------------------------------------------------------
 308 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
 309 #
 310 # Licensed under the Apache License, Version 2.0 (the "License");
 311 # you may not use this file except in compliance with the License.
 312 # You may obtain a copy of the License at:
 313 #
 314 #     http://www.apache.org/licenses/LICENSE-2.0
 315 #
 316 # Unless required by applicable law or agreed to in writing, software
 317 # distributed under the License is distributed on an "AS IS" BASIS,
 318 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 319 # See the License for the specific language governing permissions and
 320 # limitations under the License.
 321
 322 dnl Checks for dot.
 323 AC_DEFUN([PSPP_CHECK_DOT],
 324   [AC_CACHE_CHECK(
 325     [for dot],
 326     [pspp_cv_dot],
 327     [dnl "dot" writes -V output to stderr:
 328      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 329        pspp_cv_dot=yes
 330      else
 331        pspp_cv_dot=no
 332      fi])
 333    AM_CONDITIONAL([HAVE_DOT], [test "$pspp_cv_dot" = yes])])