configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AX_PREREQ(2.60)
   5 AC_INIT(pspp, 0.4.3,bug-gnu-pspp@gnu.org)
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_DLOPEN
  15 AC_PROG_LIBTOOL
  16
  17 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  18
  19 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  20
  21 PSPP_CC_FOR_BUILD
  22 PSPP_PERL
  23
  24 dnl Internationalization macros.
  25 AM_GNU_GETTEXT([external], [need-ngettext])
  26 AM_GNU_GETTEXT_VERSION([0.16.1])
  27
  28 dnl Checks for libraries.
  29 AC_SYS_LARGEFILE
  30 AC_CHECK_LIB(m, sin)
  31 PSPP_LIBPLOT
  32 PSPP_LC_PAPER
  33 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  34
  35
  36 AC_ARG_WITH(
  37   gui,
  38   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  39
  40 if test x"$with_gui" != x"no" ; then
  41   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0,,
  42     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v2.8.0 or later (or use --without-gui)])])
  43   PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0,,
  44     [PSPP_REQUIRED_PREREQ([libglade 2.0 (or use --without-gui)])])
  45 fi
  46 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  47
  48
  49 dnl Checks needed for gnumeric reader
  50 gnm_support=yes;
  51 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
  52                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no]);
  53 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
  54 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
  55
  56 if test x"$gnm_support" = x"yes" ; then
  57    AC_DEFINE([GNM_SUPPORT], 1,
  58    [Define to 1 if building in support for reading Gnumeric files.])
  59 fi
  60
  61 AC_ARG_WITH(
  62   gui_tools,
  63   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools])])
  64 if test x"$with_gui_tools" = x"yes" ; then
  65         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
  66 fi
  67 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
  68
  69 AC_CHECK_LIB(gslcblas,main,,[PSPP_REQUIRED_PREREQ([libgslcblas])])
  70 AC_CHECK_LIB(gsl, gsl_cdf_chisq_Q,,[PSPP_REQUIRED_PREREQ([libgsl (version 1.4 or later)])])
  71
  72 AC_CHECK_LIB(ncurses, tgetent)
  73 AC_CHECK_HEADERS(termcap.h)
  74
  75 PSPP_READLINE
  76
  77 dnl Checks for header files.
  78 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
  79
  80 # For gnulib.
  81 gl_INIT
  82
  83 AC_C_INLINE
  84
  85 dnl  Dont use AC_TYPE_OFF_T --- it doesnt generate the HAVE_TYPE macro
  86 AC_CHECK_TYPES(off_t)
  87 AC_CHECK_SIZEOF(float)
  88 AC_CHECK_SIZEOF(double)
  89 AC_CHECK_SIZEOF(long double)
  90
  91 AC_C_BIGENDIAN
  92
  93 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
  94
  95 AC_PROG_LN_S
  96
  97 dnl This is needed otherwise --with-included-gettext fails
  98 AH_BOTTOM([#include <locale.h>])
  99
 100 AC_ARG_ENABLE(
 101   debug,
 102   [AS_HELP_STRING([--enable-debug],
 103                   [Turn on diagnostic features in the program])])
 104 if test x"$enable_debug" = x"yes"  ; then
 105   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 106 fi
 107
 108 # iconv is required
 109 if test "$am_cv_func_iconv" != "yes"; then
 110    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 111 fi
 112
 113 PSPP_CHECK_PREREQS
 114
 115 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 116
 117 AC_OUTPUT
 118 echo "PSPP configured successfully."
 119
 120 dnl configure.ac ends here