configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AX_PREREQ(2.60)
   5 AC_INIT([pspp],[0.6.0],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_ARG_ENABLE(
  20   anachronistic-dependencies,
  21   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  22                   [Attempt to allow building against older versions of dependent libraries])])
  23
  24 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  25
  26 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  27
  28 PSPP_CC_FOR_BUILD
  29 PSPP_PERL
  30
  31 dnl Internationalization macros.
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 AM_GNU_GETTEXT_VERSION([0.17])
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LIBPLOT
  39 PSPP_LC_PAPER
  40 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  41
  42
  43 AC_ARG_WITH(
  44   gui,
  45   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  46
  47 required_gtk_version=2.12
  48 if test x"$enable_anachronistic_dependencies" = x"yes"  ; then
  49   required_gtk_version=2.8.20
  50 fi
  51
  52 if test x"$with_gui" != x"no" ; then
  53   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  54     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  55   PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0,,
  56     [PSPP_REQUIRED_PREREQ([libglade 2.0 v2.6.0 or later (or use --without-gui)])])
  57 fi
  58 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  59
  60
  61 dnl Checks needed for psql reader
  62
  63 dnl The 8.x series postgres tarballs installs with a default prefix of
  64 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  65
  66 dnl If the libpq.so file is in a non standard path, (one which the linker
  67 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  68 dnl However, if the system happens to have more than one version of other
  69 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  70 dnl /usr and /usr/local) then the wrong one may get linked.
  71
  72 dnl To overcome this, we first check for libpq in the standard places, and
  73 dnl only set PG_LDFLAGS if it's not found.
  74
  75
  76 AC_ARG_WITH(
  77   libpq,
  78   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  79
  80 if test x"$with_libpq" != x"no" ; then
  81  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  82
  83  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  84  if test x"$cross_compiling" != x"yes" ; then
  85    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  86  fi
  87  if test -n "$PG_CONFIG" ; then
  88    AC_SUBST(PG_CONFIG)
  89    AC_DEFINE([PSQL_SUPPORT], 1,
  90    [Define to 1 if building in support for reading from postgres databases.])
  91    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  92    AC_SUBST(PG_CFLAGS)
  93
  94    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  95       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
  96    fi
  97    AC_SUBST(PG_LDFLAGS)
  98
  99    PG_LIBS=-lpq
 100    AC_SUBST(PG_LIBS)
 101    PKG_CHECK_EXISTS(libssl,
 102          AC_DEFINE([USE_SSL],1,
 103                     [Define to 1 if the openssl library is present.])
 104             ,)
 105  fi
 106 fi
 107 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 108
 109 dnl Checks needed for gnumeric reader
 110 gnm_support=yes;
 111 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 112                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 113 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 114 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 115
 116 if test x"$gnm_support" = x"yes" ; then
 117    AC_DEFINE([GNM_SUPPORT], 1,
 118    [Define to 1 if building in support for reading Gnumeric files.])
 119 fi
 120 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 121
 122 AC_ARG_WITH(
 123   gui_tools,
 124   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools])])
 125 if test x"$with_gui_tools" = x"yes" ; then
 126         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 127 fi
 128 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 129
 130 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 131 AC_SEARCH_LIBS([gsl_cdf_chisq_Q], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.4 or later)])])
 132
 133 dnl Recent versions of GNU ncurses install the curses header files into
 134 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 135 dnl enables us to discover where they are. Earlier versions don't have
 136 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 137 dnl we'll trust it to find the right information.  Otherwise, we'll
 138 dnl try to discover it ourselves.
 139 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 140 dnl to ncurses8-config !!!
 141 AC_ARG_WITH(
 142   libncurses,
 143   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 144
 145 if test x"$with_libncurses" != x"no" ; then
 146   if test x"$cross_compiling" != x"yes" ; then
 147           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 148   fi
 149   if test x"$NCURSES_CONFIG" = x ; then
 150           AC_SEARCH_LIBS([tgetent], [ncurses],
 151               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 152   else
 153           old_cflags=$CFLAGS
 154           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 155           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 156           CFLAGS=$old_cflags
 157           if test x"$curses_available" = x"yes" ; then
 158            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 159            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 160            AC_SUBST(NCURSES_CFLAGS)
 161            AC_SUBST(NCURSES_LIBS)
 162           fi
 163   fi
 164   if test x"$curses_available" = x"yes" ; then
 165           AC_DEFINE([LIBNCURSES_USABLE], 1,
 166               [Define to 1 if the libncurses is both present and usable.])
 167   fi
 168   AC_CHECK_HEADERS([termcap.h])
 169 fi
 170
 171 PSPP_READLINE
 172
 173 dnl Checks for header files.
 174 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 175
 176 # For gnulib.
 177 gl_INIT
 178
 179 AC_C_INLINE
 180
 181 AC_CHECK_SIZEOF(double)
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 186
 187 AC_PROG_LN_S
 188
 189 AC_ARG_ENABLE(
 190   debug,
 191   [AS_HELP_STRING([--enable-debug],
 192                   [Turn on diagnostic features in the program])])
 193 if test x"$enable_debug" = x"yes"  ; then
 194   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 195 fi
 196
 197 # iconv is required
 198 if test "$am_cv_func_iconv" != "yes"; then
 199    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 200 fi
 201
 202 PSPP_CHECK_PREREQS
 203
 204 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 205
 206 AC_OUTPUT
 207 echo "PSPP configured successfully."
 208
 209 dnl configure.ac ends here