configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.0],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AM_GNU_GETTEXT([external], [need-ngettext])
  34 AM_GNU_GETTEXT_VERSION([0.17])
  35
  36 dnl Checks for libraries.
  37 AC_SYS_LARGEFILE
  38 AC_SEARCH_LIBS([sin], [m])
  39 PSPP_LIBPLOT
  40 PSPP_LC_PAPER
  41 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  42
  43
  44 AC_ARG_WITH(
  45   gui,
  46   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  47
  48 required_gtk_version=2.12
  49 if test x"$enable_anachronistic_dependencies" = x"yes"  ; then
  50   required_gtk_version=2.8.20
  51 fi
  52
  53 if test x"$with_gui" != x"no" ; then
  54   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  55     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  56   PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0,,
  57     [PSPP_REQUIRED_PREREQ([libglade 2.0 v2.6.0 or later (or use --without-gui)])])
  58 fi
  59 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  60
  61
  62 dnl Checks needed for psql reader
  63
  64 dnl The 8.x series postgres tarballs installs with a default prefix of
  65 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  66
  67 dnl If the libpq.so file is in a non standard path, (one which the linker
  68 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  69 dnl However, if the system happens to have more than one version of other
  70 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  71 dnl /usr and /usr/local) then the wrong one may get linked.
  72
  73 dnl To overcome this, we first check for libpq in the standard places, and
  74 dnl only set PG_LDFLAGS if it's not found.
  75
  76
  77 AC_ARG_WITH(
  78   libpq,
  79   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  80
  81 if test x"$with_libpq" != x"no" ; then
  82  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  83
  84  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  85  if test x"$cross_compiling" != x"yes" ; then
  86    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  87  fi
  88  if test -n "$PG_CONFIG" ; then
  89    AC_SUBST(PG_CONFIG)
  90    AC_DEFINE([PSQL_SUPPORT], 1,
  91    [Define to 1 if building in support for reading from postgres databases.])
  92    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  93    AC_SUBST(PG_CFLAGS)
  94
  95    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  96       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
  97    fi
  98    AC_SUBST(PG_LDFLAGS)
  99
 100    PG_LIBS=-lpq
 101    AC_SUBST(PG_LIBS)
 102    PKG_CHECK_EXISTS(libssl,
 103          AC_DEFINE([USE_SSL],1,
 104                     [Define to 1 if the openssl library is present.])
 105             ,)
 106  fi
 107 fi
 108 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 109
 110 dnl Checks needed for gnumeric reader
 111 gnm_support=yes;
 112 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 113                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 114 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 115 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 116
 117 if test x"$gnm_support" = x"yes" ; then
 118    AC_DEFINE([GNM_SUPPORT], 1,
 119    [Define to 1 if building in support for reading Gnumeric files.])
 120 fi
 121 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 122
 123 AC_ARG_WITH(
 124   gui_tools,
 125   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 126 if test x"$with_gui_tools" = x"yes" ; then
 127         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 128 fi
 129 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 130
 131 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 132 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 133 PSPP_GSL_NEEDS_FGNU89_INLINE
 134
 135 dnl Recent versions of GNU ncurses install the curses header files into
 136 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 137 dnl enables us to discover where they are. Earlier versions don't have
 138 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 139 dnl we'll trust it to find the right information.  Otherwise, we'll
 140 dnl try to discover it ourselves.
 141 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 142 dnl to ncurses8-config !!!
 143 AC_ARG_WITH(
 144   libncurses,
 145   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 146
 147 if test x"$with_libncurses" != x"no" ; then
 148   if test x"$cross_compiling" != x"yes" ; then
 149           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 150   fi
 151   if test x"$NCURSES_CONFIG" = x ; then
 152           AC_SEARCH_LIBS([tgetent], [ncurses],
 153               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 154   else
 155           old_cflags=$CFLAGS
 156           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 157           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 158           CFLAGS=$old_cflags
 159           if test x"$curses_available" = x"yes" ; then
 160            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 161            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 162            AC_SUBST(NCURSES_CFLAGS)
 163            AC_SUBST(NCURSES_LIBS)
 164           fi
 165   fi
 166   if test x"$curses_available" = x"yes" ; then
 167           AC_DEFINE([LIBNCURSES_USABLE], 1,
 168               [Define to 1 if the libncurses is both present and usable.])
 169   fi
 170   AC_CHECK_HEADERS([termcap.h])
 171 fi
 172
 173 PSPP_READLINE
 174
 175 dnl Checks for header files.
 176 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 177
 178 # For gnulib.
 179 gl_INIT
 180
 181 AC_C_INLINE
 182
 183 AC_CHECK_SIZEOF(double)
 184
 185 AC_C_BIGENDIAN
 186
 187 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 188
 189 AC_PROG_LN_S
 190
 191 AC_ARG_ENABLE(
 192   debug,
 193   [AS_HELP_STRING([--enable-debug],
 194                   [Turn on diagnostic features in the program])])
 195 if test x"$enable_debug" = x"yes"  ; then
 196   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 197 fi
 198
 199 # iconv is required
 200 if test "$am_cv_func_iconv" != "yes"; then
 201    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 202 fi
 203
 204 PSPP_CHECK_PREREQS
 205
 206 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 207
 208 AC_OUTPUT
 209 echo "PSPP configured successfully."
 210
 211 dnl configure.ac ends here