configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AX_PREREQ(2.60)
   5 AC_INIT(pspp, 0.4.3,bug-gnu-pspp@gnu.org)
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_DLOPEN
  15 AC_PROG_LIBTOOL
  16 PKG_PROG_PKG_CONFIG
  17
  18 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  19
  20 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  21
  22 PSPP_CC_FOR_BUILD
  23 PSPP_PERL
  24
  25 dnl Internationalization macros.
  26 AM_GNU_GETTEXT([external], [need-ngettext])
  27 AM_GNU_GETTEXT_VERSION([0.16.1])
  28
  29 dnl Checks for libraries.
  30 AC_SYS_LARGEFILE
  31 AC_CHECK_LIB(m, sin)
  32 PSPP_LIBPLOT
  33 PSPP_LC_PAPER
  34 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  35
  36
  37 AC_ARG_WITH(
  38   gui,
  39   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  40
  41 if test x"$with_gui" != x"no" ; then
  42   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0,,
  43     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v2.8.0 or later (or use --without-gui)])])
  44   PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0,,
  45     [PSPP_REQUIRED_PREREQ([libglade 2.0 (or use --without-gui)])])
  46 fi
  47 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  48
  49
  50 dnl Checks needed for gnumeric reader
  51 gnm_support=yes;
  52 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
  53                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
  54 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
  55 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
  56
  57 if test x"$gnm_support" = x"yes" ; then
  58    AC_DEFINE([GNM_SUPPORT], 1,
  59    [Define to 1 if building in support for reading Gnumeric files.])
  60 fi
  61 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
  62
  63 AC_ARG_WITH(
  64   gui_tools,
  65   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools])])
  66 if test x"$with_gui_tools" = x"yes" ; then
  67         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
  68 fi
  69 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
  70
  71 AC_CHECK_LIB(gslcblas,main,,[PSPP_REQUIRED_PREREQ([libgslcblas])])
  72 AC_CHECK_LIB(gsl, gsl_cdf_chisq_Q,,[PSPP_REQUIRED_PREREQ([libgsl (version 1.4 or later)])])
  73
  74 AC_CHECK_LIB(ncurses, tgetent)
  75 AC_CHECK_HEADERS(termcap.h)
  76
  77 PSPP_READLINE
  78
  79 dnl Checks for header files.
  80 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
  81
  82 # For gnulib.
  83 gl_INIT
  84
  85 AC_C_INLINE
  86
  87 AC_CHECK_SIZEOF(double)
  88
  89 AC_C_BIGENDIAN
  90
  91 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
  92
  93 AC_PROG_LN_S
  94
  95 AC_ARG_ENABLE(
  96   debug,
  97   [AS_HELP_STRING([--enable-debug],
  98                   [Turn on diagnostic features in the program])])
  99 if test x"$enable_debug" = x"yes"  ; then
 100   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 101 fi
 102
 103 # iconv is required
 104 if test "$am_cv_func_iconv" != "yes"; then
 105    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 106 fi
 107
 108 PSPP_CHECK_PREREQS
 109
 110 AC_CONFIG_FILES([Makefile gl/Makefile po/Makefile.in])
 111
 112 AC_OUTPUT
 113 echo "PSPP configured successfully."
 114
 115 dnl configure.ac ends here