configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.7.4], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_TESTDIR([tests])
   8 AM_INIT_AUTOMAKE
   9
  10 dnl Checks for programs.
  11 AC_GNU_SOURCE
  12 AC_PROG_CC
  13 gl_EARLY
  14 AM_PROG_CC_C_O
  15 AC_LIBTOOL_WIN32_DLL
  16 AC_LIBTOOL_DLOPEN
  17 AC_PROG_LIBTOOL
  18 PKG_PROG_PKG_CONFIG
  19 m4_pattern_forbid([PKG_CHECK_MODULES])
  20 PSPP_CHECK_CLICKSEQUENCE
  21
  22 AC_ARG_ENABLE(
  23   anachronistic-dependencies,
  24   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  25                   [Attempt to allow building against older versions of dependent libraries])])
  26
  27 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  28
  29 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  30
  31 PSPP_CC_FOR_BUILD
  32 PSPP_PERL
  33
  34 dnl Internationalization macros.
  35 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  36 if  test x"$enable_nls" != x"no"  ; then
  37  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  38 fi
  39
  40
  41 dnl Checks for libraries.
  42 AC_SYS_LARGEFILE
  43 AC_SEARCH_LIBS([sin], [m])
  44 AC_SEARCH_LIBS([dcgettext], [intl])
  45 PSPP_LC_PAPER
  46
  47
  48 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  49 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  50
  51 # Support for Cairo and Pango.
  52 AC_ARG_WITH([cairo],
  53   [AS_HELP_STRING(
  54     [--without-cairo],
  55     [Don't build support for charts (using Cairo and Pango);
  56      implies --without-gui])],
  57   [], [with_cairo=yes])
  58 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  59 if test "$with_cairo" != no; then
  60   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.20 pangocairo],
  61     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  62      AC_DEFINE([HAVE_CAIRO], 1,
  63        [Define to 1 if Cairo and Pango are available.])],
  64     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.20 or later (or use --without-cairo)])])
  65   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  66   AC_SUBST(XMLLINT)
  67 fi
  68
  69 # Support for GUI.
  70 AC_ARG_WITH([gui],
  71   [AS_HELP_STRING([--without-gui],
  72                   [Don't build the PSPPIRE GUI (using GTK+)])],
  73   [], [with_gui=yes])
  74 AM_CONDITIONAL([HAVE_GUI],
  75                [test "$with_cairo" != no && test "$with_gui" != "no"])
  76 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  77   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.12], [],
  78     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.12 or later (or use --without-gui)])])
  79 fi
  80
  81 dnl Checks needed for psql reader
  82
  83 dnl The 8.x series postgres tarballs installs with a default prefix of
  84 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  85
  86 dnl If the libpq.so file is in a non standard path, (one which the linker
  87 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  88 dnl However, if the system happens to have more than one version of other
  89 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  90 dnl /usr and /usr/local) then the wrong one may get linked.
  91
  92 dnl To overcome this, we first check for libpq in the standard places, and
  93 dnl only set PG_LDFLAGS if it's not found.
  94
  95
  96 AC_ARG_WITH(
  97   libpq,
  98   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  99
 100 if test x"$with_libpq" != x"no" ; then
 101  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
 102
 103  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
 104  if test x"$cross_compiling" != x"yes" ; then
 105    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 106  fi
 107  if test -n "$PG_CONFIG" ; then
 108    AC_SUBST(PG_CONFIG)
 109    AC_DEFINE([PSQL_SUPPORT], 1,
 110    [Define to 1 if building in support for reading from postgres databases.])
 111    PG_CFLAGS=-I`$PG_CONFIG --includedir`
 112    AC_SUBST(PG_CFLAGS)
 113
 114    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 115       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 116    fi
 117    AC_SUBST(PG_LDFLAGS)
 118
 119    PG_LIBS=-lpq
 120    AC_SUBST(PG_LIBS)
 121    PKG_CHECK_EXISTS(libssl,
 122          AC_DEFINE([USE_SSL],1,
 123                     [Define to 1 if the openssl library is present.])
 124             ,)
 125  fi
 126 fi
 127 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 128
 129 dnl Checks needed for Gnumeric reader
 130 gnm_support=yes;
 131 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 132                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 133 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 134 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 135
 136 if test x"$gnm_support" = x"yes" ; then
 137    AC_DEFINE([GNM_SUPPORT], 1,
 138    [Define to 1 if building in support for reading Gnumeric files.])
 139 fi
 140 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 141
 142 AC_ARG_WITH(
 143   gui_tools,
 144   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 145 if test x"$with_gui_tools" = x"yes" ; then
 146         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 147 fi
 148 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 149
 150 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 151
 152 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 153 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 154 PSPP_GSL_NEEDS_FGNU89_INLINE
 155
 156 dnl Recent versions of GNU ncurses install the curses header files into
 157 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 158 dnl enables us to discover where they are. Earlier versions don't have
 159 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 160 dnl we'll trust it to find the right information.  Otherwise, we'll
 161 dnl try to discover it ourselves.
 162 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 163 dnl to ncurses8-config !!!
 164 AC_ARG_WITH(
 165   libncurses,
 166   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 167
 168 if test x"$with_libncurses" != x"no" ; then
 169   if test x"$cross_compiling" != x"yes" ; then
 170           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 171   fi
 172   if test x"$NCURSES_CONFIG" = x ; then
 173           AC_SEARCH_LIBS([tgetent], [ncurses],
 174               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 175   else
 176           old_cflags=$CFLAGS
 177           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 178           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 179           CFLAGS=$old_cflags
 180           if test x"$curses_available" = x"yes" ; then
 181            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 182            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 183            AC_SUBST(NCURSES_CFLAGS)
 184            AC_SUBST(NCURSES_LIBS)
 185           fi
 186   fi
 187   if test x"$curses_available" = x"yes" ; then
 188           AC_DEFINE([LIBNCURSES_USABLE], 1,
 189               [Define to 1 if the libncurses is both present and usable.])
 190   fi
 191   AC_CHECK_HEADERS([termcap.h])
 192 fi
 193
 194 PSPP_READLINE
 195
 196 dnl Checks for header files.
 197 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 198
 199 # For gnulib.
 200 gl_INIT
 201
 202 AC_C_INLINE
 203
 204 AC_CHECK_SIZEOF(double)
 205
 206 AC_C_BIGENDIAN
 207
 208 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 209
 210 AC_PROG_LN_S
 211
 212 AC_ARG_ENABLE(
 213   debug,
 214   [AS_HELP_STRING([--enable-debug],
 215                   [Turn on diagnostic features in the program])])
 216 if test x"$enable_debug" = x"yes"  ; then
 217   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 218 fi
 219
 220 # iconv is required
 221 if test "$am_cv_func_iconv" != "yes"; then
 222    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 223 fi
 224
 225 dnl Required by the gnulib 'relocatable-prog' module.
 226 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 227 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 228 RELOCATABLE_STRIP=:
 229
 230 PSPP_CHECK_PREREQS
 231
 232 AC_CONFIG_FILES([Makefile gl/Makefile tests/atlocal])
 233
 234 AC_OUTPUT
 235 echo "PSPP configured successfully."
 236
 237 dnl configure.ac ends here