configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 PSPP_LIBPLOT
  44 PSPP_LC_PAPER
  45 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  46
  47
  48 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  49 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  50
  51
  52 AC_ARG_WITH(
  53   gui,
  54   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  55
  56 required_gtk_version=2.12
  57
  58 if test x"$with_gui" != x"no" ; then
  59   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  60     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  61 fi
  62 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  63
  64
  65 dnl Checks needed for psql reader
  66
  67 dnl The 8.x series postgres tarballs installs with a default prefix of
  68 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  69
  70 dnl If the libpq.so file is in a non standard path, (one which the linker
  71 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  72 dnl However, if the system happens to have more than one version of other
  73 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  74 dnl /usr and /usr/local) then the wrong one may get linked.
  75
  76 dnl To overcome this, we first check for libpq in the standard places, and
  77 dnl only set PG_LDFLAGS if it's not found.
  78
  79
  80 AC_ARG_WITH(
  81   libpq,
  82   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  83
  84 if test x"$with_libpq" != x"no" ; then
  85  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  86
  87  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  88  if test x"$cross_compiling" != x"yes" ; then
  89    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  90  fi
  91  if test -n "$PG_CONFIG" ; then
  92    AC_SUBST(PG_CONFIG)
  93    AC_DEFINE([PSQL_SUPPORT], 1,
  94    [Define to 1 if building in support for reading from postgres databases.])
  95    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  96    AC_SUBST(PG_CFLAGS)
  97
  98    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  99       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 100    fi
 101    AC_SUBST(PG_LDFLAGS)
 102
 103    PG_LIBS=-lpq
 104    AC_SUBST(PG_LIBS)
 105    PKG_CHECK_EXISTS(libssl,
 106          AC_DEFINE([USE_SSL],1,
 107                     [Define to 1 if the openssl library is present.])
 108             ,)
 109  fi
 110 fi
 111 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 112
 113 dnl Checks needed for Gnumeric reader
 114 gnm_support=yes;
 115 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 116                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 117 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 118 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 119
 120 if test x"$gnm_support" = x"yes" ; then
 121    AC_DEFINE([GNM_SUPPORT], 1,
 122    [Define to 1 if building in support for reading Gnumeric files.])
 123 fi
 124 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 125
 126 AC_ARG_WITH(
 127   gui_tools,
 128   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 129 if test x"$with_gui_tools" = x"yes" ; then
 130         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 131 fi
 132 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 133
 134 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 135
 136 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 137 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 138 PSPP_GSL_NEEDS_FGNU89_INLINE
 139
 140 dnl Recent versions of GNU ncurses install the curses header files into
 141 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 142 dnl enables us to discover where they are. Earlier versions don't have
 143 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 144 dnl we'll trust it to find the right information.  Otherwise, we'll
 145 dnl try to discover it ourselves.
 146 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 147 dnl to ncurses8-config !!!
 148 AC_ARG_WITH(
 149   libncurses,
 150   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 151
 152 if test x"$with_libncurses" != x"no" ; then
 153   if test x"$cross_compiling" != x"yes" ; then
 154           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 155   fi
 156   if test x"$NCURSES_CONFIG" = x ; then
 157           AC_SEARCH_LIBS([tgetent], [ncurses],
 158               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 159   else
 160           old_cflags=$CFLAGS
 161           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 162           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 163           CFLAGS=$old_cflags
 164           if test x"$curses_available" = x"yes" ; then
 165            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 166            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 167            AC_SUBST(NCURSES_CFLAGS)
 168            AC_SUBST(NCURSES_LIBS)
 169           fi
 170   fi
 171   if test x"$curses_available" = x"yes" ; then
 172           AC_DEFINE([LIBNCURSES_USABLE], 1,
 173               [Define to 1 if the libncurses is both present and usable.])
 174   fi
 175   AC_CHECK_HEADERS([termcap.h])
 176 fi
 177
 178 PSPP_READLINE
 179
 180 dnl Checks for header files.
 181 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 182
 183 # For gnulib.
 184 gl_INIT
 185
 186 AC_C_INLINE
 187
 188 AC_CHECK_SIZEOF(double)
 189
 190 AC_C_BIGENDIAN
 191
 192 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 193
 194 AC_PROG_LN_S
 195
 196 AC_ARG_ENABLE(
 197   debug,
 198   [AS_HELP_STRING([--enable-debug],
 199                   [Turn on diagnostic features in the program])])
 200 if test x"$enable_debug" = x"yes"  ; then
 201   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 202 fi
 203
 204 # iconv is required
 205 if test "$am_cv_func_iconv" != "yes"; then
 206    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 207 fi
 208
 209 PSPP_CHECK_PREREQS
 210
 211 AC_CONFIG_FILES([Makefile gl/Makefile])
 212
 213 AC_OUTPUT
 214 echo "PSPP configured successfully."
 215
 216 dnl configure.ac ends here