configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19 PSPP_CHECK_CLICKSEQUENCE
  20
  21 AC_ARG_ENABLE(
  22   anachronistic-dependencies,
  23   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  24                   [Attempt to allow building against older versions of dependent libraries])])
  25
  26 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  27
  28 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  29
  30 PSPP_CC_FOR_BUILD
  31 PSPP_PERL
  32
  33 dnl Internationalization macros.
  34 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  35 if  test x"$enable_nls" != x"no"  ; then
  36  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  37 fi
  38
  39
  40 dnl Checks for libraries.
  41 AC_SYS_LARGEFILE
  42 AC_SEARCH_LIBS([sin], [m])
  43 AC_SEARCH_LIBS([dcgettext], [intl])
  44 PSPP_LIBPLOT
  45 PSPP_LC_PAPER
  46 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  47
  48
  49 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  50 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  51
  52
  53 AC_ARG_WITH(
  54   gui,
  55   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  56
  57 required_gtk_version=2.12
  58
  59 if test x"$with_gui" != x"no" ; then
  60   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  61     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  62 fi
  63 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  64
  65
  66 dnl Checks needed for psql reader
  67
  68 dnl The 8.x series postgres tarballs installs with a default prefix of
  69 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  70
  71 dnl If the libpq.so file is in a non standard path, (one which the linker
  72 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  73 dnl However, if the system happens to have more than one version of other
  74 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  75 dnl /usr and /usr/local) then the wrong one may get linked.
  76
  77 dnl To overcome this, we first check for libpq in the standard places, and
  78 dnl only set PG_LDFLAGS if it's not found.
  79
  80
  81 AC_ARG_WITH(
  82   libpq,
  83   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  84
  85 if test x"$with_libpq" != x"no" ; then
  86  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  87
  88  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  89  if test x"$cross_compiling" != x"yes" ; then
  90    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  91  fi
  92  if test -n "$PG_CONFIG" ; then
  93    AC_SUBST(PG_CONFIG)
  94    AC_DEFINE([PSQL_SUPPORT], 1,
  95    [Define to 1 if building in support for reading from postgres databases.])
  96    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  97    AC_SUBST(PG_CFLAGS)
  98
  99    if test "x$libpq_in_std_lib_path" != x"yes" ; then
 100       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
 101    fi
 102    AC_SUBST(PG_LDFLAGS)
 103
 104    PG_LIBS=-lpq
 105    AC_SUBST(PG_LIBS)
 106    PKG_CHECK_EXISTS(libssl,
 107          AC_DEFINE([USE_SSL],1,
 108                     [Define to 1 if the openssl library is present.])
 109             ,)
 110  fi
 111 fi
 112 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 113
 114 dnl Checks needed for Gnumeric reader
 115 gnm_support=yes;
 116 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 117                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 118 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 119 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 120
 121 if test x"$gnm_support" = x"yes" ; then
 122    AC_DEFINE([GNM_SUPPORT], 1,
 123    [Define to 1 if building in support for reading Gnumeric files.])
 124 fi
 125 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 126
 127 AC_ARG_WITH(
 128   gui_tools,
 129   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 130 if test x"$with_gui_tools" = x"yes" ; then
 131         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 132 fi
 133 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 134
 135 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 136
 137 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 138 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 139 PSPP_GSL_NEEDS_FGNU89_INLINE
 140
 141 dnl Recent versions of GNU ncurses install the curses header files into
 142 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 143 dnl enables us to discover where they are. Earlier versions don't have
 144 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 145 dnl we'll trust it to find the right information.  Otherwise, we'll
 146 dnl try to discover it ourselves.
 147 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 148 dnl to ncurses8-config !!!
 149 AC_ARG_WITH(
 150   libncurses,
 151   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 152
 153 if test x"$with_libncurses" != x"no" ; then
 154   if test x"$cross_compiling" != x"yes" ; then
 155           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 156   fi
 157   if test x"$NCURSES_CONFIG" = x ; then
 158           AC_SEARCH_LIBS([tgetent], [ncurses],
 159               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 160   else
 161           old_cflags=$CFLAGS
 162           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 163           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 164           CFLAGS=$old_cflags
 165           if test x"$curses_available" = x"yes" ; then
 166            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 167            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 168            AC_SUBST(NCURSES_CFLAGS)
 169            AC_SUBST(NCURSES_LIBS)
 170           fi
 171   fi
 172   if test x"$curses_available" = x"yes" ; then
 173           AC_DEFINE([LIBNCURSES_USABLE], 1,
 174               [Define to 1 if the libncurses is both present and usable.])
 175   fi
 176   AC_CHECK_HEADERS([termcap.h])
 177 fi
 178
 179 PSPP_READLINE
 180
 181 dnl Checks for header files.
 182 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 183
 184 # For gnulib.
 185 gl_INIT
 186
 187 AC_C_INLINE
 188
 189 AC_CHECK_SIZEOF(double)
 190
 191 AC_C_BIGENDIAN
 192
 193 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 194
 195 AC_PROG_LN_S
 196
 197 AC_ARG_ENABLE(
 198   debug,
 199   [AS_HELP_STRING([--enable-debug],
 200                   [Turn on diagnostic features in the program])])
 201 if test x"$enable_debug" = x"yes"  ; then
 202   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 203 fi
 204
 205 # iconv is required
 206 if test "$am_cv_func_iconv" != "yes"; then
 207    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 208 fi
 209
 210 dnl Required by the gnulib 'relocatable-prog' module.
 211 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 212 RELOCATABLE_LIBRARY_PATH='$(libdir)'
 213 RELOCATABLE_STRIP=:
 214
 215 PSPP_CHECK_PREREQS
 216
 217 AC_CONFIG_FILES([Makefile gl/Makefile])
 218
 219 AC_OUTPUT
 220 echo "PSPP configured successfully."
 221
 222 dnl configure.ac ends here