acinclude.m4

   1 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Prerequisites.
   7
   8 dnl Instead of giving an error about each prerequisite as we encounter it,
   9 dnl group them all together at the end of the run, to be user-friendly.
  10 AC_DEFUN([PSPP_REQUIRED_PREREQ], [pspp_required_prereqs="$pspp_required_prereqs
  11         $1"])
  12 AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
  13         $1"])
  14 AC_DEFUN([PSPP_CHECK_PREREQS],
  15 [
  16   if test "$pspp_optional_prereqs" != ""; then
  17     AC_MSG_WARN([The following optional prerequisites are not installed.
  18 You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
  19 fi
  20   if test "$pspp_required_prereqs" != ""; then
  21     AC_MSG_ERROR([The following required prerequisites are not installed.
  22 You must install them before PSPP can be built:$pspp_required_prereqs])
  23 fi
  24 ])
  25
  26
  27 dnl Check that a new enough version of Perl is available.
  28 AC_DEFUN([PSPP_PERL],
  29 [
  30   AC_PATH_PROG([PERL], perl, no)
  31   AC_SUBST([PERL])dnl
  32   if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
  33     PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
  34   fi
  35 ])
  36
  37 dnl Check that libplot is available.
  38 AC_DEFUN([PSPP_LIBPLOT],
  39 [
  40   AC_ARG_WITH(
  41     libplot,
  42     [AS_HELP_STRING([--without-libplot],
  43                     [don't compile in support of charts (using libplot)])])
  44
  45   if test x"$with_libplot" != x"no" ; then
  46     # Check whether we can link against libplot without any extra libraries.
  47     AC_CHECK_LIB(plot, pl_newpl_r, [LIBPLOT_LIBS="-lplot"])
  48
  49     # Check whether we can link against libplot if we also link X.
  50     if test x"$LIBPLOT_LIBS" = x""; then
  51       AC_PATH_XTRA
  52       extra_libs="-lXaw -lXmu -lXt $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS -lm"
  53       AC_CHECK_LIB(plot, pl_newpl_r,
  54                    [LIBPLOT_LIBS="-lplot $extra_libs"
  55                     LDFLAGS="$LDFLAGS $X_LIBS"],,
  56                    [$extra_libs])
  57     fi
  58
  59     # Still can't link?
  60     if test x"$LIBPLOT_LIBS" = x""; then
  61       PSPP_REQUIRED_PREREQ([libplot (or use --without-libplot)])
  62     fi
  63
  64     # Set up to make everything work.
  65     LIBS="$LIBPLOT_LIBS $LIBS"
  66     AC_DEFINE(HAVE_LIBPLOT, 1,
  67               [Define to 1 if you have the `libplot' library (-lplot).])
  68   fi
  69 ])
  70
  71 dnl Check that off_t is defined as an integer type.
  72 dnl Solaris sometimes declares it as a struct, if it
  73 dnl thinks that the compiler does not support `long long'.
  74 AC_DEFUN([PSPP_OFF_T],
  75 [
  76   AC_COMPILE_IFELSE([#include <sys/types.h>
  77   #include <unistd.h>
  78   off_t x = 0;
  79   int main (void)
  80   {
  81     lseek (0, 1, 2);
  82     return 0;
  83   }], [], [AC_MSG_ERROR(
  84   [Your system's definition of off_t is broken.  You are probably
  85   using Solaris.  You can probably fix the problem with
  86   `--disable-largefile' or `CFLAGS=-ansi'.])])
  87 ])
  88
  89 dnl Check whether a C compiler option is accepted.
  90 dnl If so, add it to CFLAGS.
  91 dnl Example: PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  92 AC_DEFUN([PSPP_ENABLE_OPTION],
  93 [
  94   m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
  95   AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name],
  96     [pspp_save_CFLAGS="$CFLAGS"
  97      CFLAGS="$CFLAGS $1"
  98      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
  99      CFLAGS="$pspp_save_CFLAGS"])
 100   if test $pspp_cv_name = yes; then
 101     CFLAGS="$CFLAGS $1"
 102   fi
 103 ])
 104
 105 dnl Check for readline and history libraries.
 106
 107 dnl Modified for PSPP, based on readline.m4 serial 3 from
 108 dnl gnulib, which was written by Simon Josefsson, with help from Bruno
 109 dnl Haible and Oskar Liljeblad.
 110
 111 AC_DEFUN([PSPP_READLINE],
 112 [
 113   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
 114   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
 115   AC_REQUIRE([AC_LIB_RPATH])
 116
 117   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
 118   dnl INCREADLINE accordingly.
 119   AC_LIB_LINKFLAGS_BODY([readline])
 120   AC_LIB_LINKFLAGS_BODY([history])
 121
 122   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
 123   dnl because if the user has installed libreadline and not disabled its use
 124   dnl via --without-libreadline-prefix, he wants to use it. The AC_TRY_LINK
 125   dnl will then succeed.
 126   am_save_CPPFLAGS="$CPPFLAGS"
 127   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
 128
 129   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
 130     gl_cv_lib_readline=no
 131     am_save_LIBS="$LIBS"
 132     dnl On some systems, -lreadline doesn't link without an additional
 133     dnl -lncurses or -ltermcap.
 134     dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
 135     dnl by design and obsolete since 1994. Try -lcurses last, because
 136     dnl libcurses is unusable on some old Unices.
 137     for extra_lib in "" ncurses termcap curses; do
 138       LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
 139       if test -n "$extra_lib"; then
 140         LIBS="$LIBS -l$extra_lib"
 141       fi
 142       AC_TRY_LINK([#include <stdio.h>
 143 #include <readline/readline.h>
 144 #include <readline/history.h>],
 145         [readline((char*)0); add_history((char*)0);],
 146         gl_cv_lib_readline=yes)
 147       if test "$gl_cv_lib_readline" = yes; then
 148         if test -n "$extra_lib"; then
 149           LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
 150           LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
 151         fi
 152         break
 153       fi
 154     done
 155     LIBS="$am_save_LIBS"
 156   ])
 157
 158   if test "$gl_cv_lib_readline" = yes; then
 159     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
 160     AC_MSG_CHECKING([how to link with libreadline])
 161     AC_MSG_RESULT([$LIBREADLINE])
 162   else
 163     dnl If $LIBREADLINE didn't lead to a usable library, we don't
 164     dnl need $INCREADLINE either.
 165     CPPFLAGS="$am_save_CPPFLAGS"
 166     LIBREADLINE=
 167     LTLIBREADLINE=
 168     LIBHISTORY=
 169     LTLIBHISTORY=
 170     PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
 171   fi
 172   AC_SUBST(LIBREADLINE)
 173   AC_SUBST(LTLIBREADLINE)
 174 ])
 175
 176 dnl Check for build tools.  Adapted from bfd library.
 177
 178 AC_DEFUN([PSPP_CC_FOR_BUILD],
 179 [# Put a plausible default for CC_FOR_BUILD in Makefile.
 180 if test -z "$CC_FOR_BUILD"; then
 181   if test "x$cross_compiling" = "xno"; then
 182     CC_FOR_BUILD='$(CC)'
 183   else
 184     CC_FOR_BUILD=cc
 185   fi
 186 fi
 187 AC_SUBST(CC_FOR_BUILD)
 188 # Also set EXEEXT_FOR_BUILD.
 189 if test "x$cross_compiling" = "xno"; then
 190   EXEEXT_FOR_BUILD='$(EXEEXT)'
 191 else
 192   AC_CACHE_CHECK([for build system executable suffix], pspp_cv_build_exeext,
 193     [rm -f conftest*
 194      echo 'int main () { return 0; }' > conftest.c
 195      pspp_cv_build_exeext=
 196      ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5
 197      for file in conftest.*; do
 198        case $file in # (
 199        *.c | *.o | *.obj | *.ilk | *.pdb) ;; # (
 200        *) pspp_cv_build_exeext=`echo $file | sed -e s/conftest//` ;;
 201        esac
 202      done
 203      rm -f conftest*
 204      test x"${pspp_cv_build_exeext}" = x && pspp_cv_build_exeext=no])
 205   EXEEXT_FOR_BUILD=""
 206   test x"${pspp_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${pspp_cv_build_exeex
 207 t}
 208 fi
 209 AC_SUBST(EXEEXT_FOR_BUILD)])
 210
 211 dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
 212 AC_DEFUN([PSPP_LC_PAPER],
 213 [AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
 214     pspp_cv_lc_paper=no
 215     AC_COMPILE_IFELSE(
 216       [AC_LANG_PROGRAM(
 217         [#include <locale.h>
 218 #include <langinfo.h>
 219 ],
 220         [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
 221       [pspp_cv_lc_paper=yes])
 222   ])
 223   if test "$pspp_cv_lc_paper" = yes; then
 224     AC_DEFINE(HAVE_LC_PAPER, 1, [Define if you have LC_PAPER.])
 225   fi
 226 ])
 227
 228 dnl acinclude.m4 ends here