acinclude.m4

   1 dnl Copyright (C) 2005, 2006, 2007, 2009 Free Software Foundation, Inc.
   2 dnl This file is free software; the Free Software Foundation
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Prerequisites.
   7
   8 dnl Summarize all the missing prerequisites at the end of the run to
   9 dnl increase user-friendliness.
  10 AC_DEFUN([PSPP_REQUIRED_PREREQ],
  11   [AC_MSG_WARN([You must install $1 before building PSPP.])
  12 pspp_required_prereqs="$pspp_required_prereqs
  13         $1"])
  14 AC_DEFUN([PSPP_OPTIONAL_PREREQ], [pspp_optional_prereqs="$pspp_optional_prereqs
  15         $1"])
  16 AC_DEFUN([PSPP_CHECK_PREREQS],
  17 [
  18   if test "$pspp_optional_prereqs" != ""; then
  19     AC_MSG_WARN([The following optional prerequisites are not installed.
  20 You may wish to install them to obtain additional functionality:$pspp_optional_prereqs])
  21 fi
  22   if test "$pspp_required_prereqs" != ""; then
  23     AC_MSG_ERROR([The following required prerequisites are not installed.
  24 You must install them before PSPP can be built:$pspp_required_prereqs])
  25 fi
  26 ])
  27
  28
  29 dnl Check that a new enough version of Perl is available.
  30 AC_DEFUN([PSPP_PERL],
  31 [
  32   AC_PATH_PROG([PERL], perl, no)
  33   AC_SUBST([PERL])dnl
  34   if test "$PERL" != no && $PERL -e 'require 5.005_03;'; then :; else
  35     PSPP_REQUIRED_PREREQ([Perl 5.005_03 (or later)])
  36   fi
  37 ])
  38
  39 dnl Check that libplot is available.
  40 AC_DEFUN([PSPP_LIBPLOT],
  41 [
  42   AC_ARG_WITH(
  43     libplot,
  44     [AS_HELP_STRING([--without-libplot],
  45                     [don't compile in support of charts (using libplot)])])
  46
  47   if test x"$with_libplot" != x"no" ; then
  48     # Check whether we can link against libplot without any extra libraries.
  49     AC_CHECK_LIB(plot, pl_newpl_r, [LIBPLOT_LIBS="-lplot"])
  50
  51     # Check whether we can link against libplot if we also link X.
  52     if test x"$LIBPLOT_LIBS" = x""; then
  53       AC_PATH_XTRA
  54       extra_libs="-lXaw -lXmu -lXt $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS -lm"
  55       AC_CHECK_LIB(plot, pl_newpl_r,
  56                    [LIBPLOT_LIBS="-lplot $extra_libs"
  57                     LDFLAGS="$LDFLAGS $X_LIBS"],,
  58                    [$extra_libs])
  59     fi
  60
  61     # Still can't link?
  62     if test x"$LIBPLOT_LIBS" = x""; then
  63       PSPP_REQUIRED_PREREQ([libplot (or use --without-libplot)])
  64     fi
  65
  66     # Set up to make everything work.
  67     LIBS="$LIBPLOT_LIBS $LIBS"
  68     AC_DEFINE(HAVE_LIBPLOT, 1,
  69               [Define to 1 if you have the `libplot' library (-lplot).])
  70   fi
  71 ])
  72
  73 dnl PSPP_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
  74 dnl Check whether the given C compiler OPTION is accepted.
  75 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
  76 AC_DEFUN([PSPP_CHECK_CC_OPTION],
  77 [
  78   m4_define([pspp_cv_name], [pspp_cv_[]m4_translit([$1], [-], [_])])dnl
  79   AC_CACHE_CHECK([whether $CC accepts $1], [pspp_cv_name],
  80     [pspp_save_CFLAGS="$CFLAGS"
  81      CFLAGS="$CFLAGS $1"
  82      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [pspp_cv_name[]=yes], [pspp_cv_name[]=no])
  83      CFLAGS="$pspp_save_CFLAGS"])
  84   if test $pspp_cv_name = yes; then
  85     m4_if([$2], [], [;], [$2])
  86   else
  87     m4_if([$3], [], [:], [$3])
  88   fi
  89 ])
  90
  91 dnl PSPP_ENABLE_OPTION([OPTION])
  92 dnl Check whether the given C compiler OPTION is accepted.
  93 dnl If so, add it to CFLAGS.
  94 dnl Example: PSPP_ENABLE_OPTION([-Wdeclaration-after-statement])
  95 AC_DEFUN([PSPP_ENABLE_OPTION],
  96   [PSPP_CHECK_CC_OPTION([$1], [CFLAGS="$CFLAGS $1"])])
  97
  98 dnl Check for readline and history libraries.
  99
 100 dnl Modified for PSPP, based on readline.m4 serial 3 from
 101 dnl gnulib, which was written by Simon Josefsson, with help from Bruno
 102 dnl Haible and Oskar Liljeblad.
 103
 104 AC_DEFUN([PSPP_READLINE],
 105 [
 106   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
 107   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
 108   AC_REQUIRE([AC_LIB_RPATH])
 109
 110   dnl Search for libreadline and define LIBREADLINE, LTLIBREADLINE and
 111   dnl INCREADLINE accordingly.
 112   AC_LIB_LINKFLAGS_BODY([readline])
 113   AC_LIB_LINKFLAGS_BODY([history])
 114
 115   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
 116   dnl because if the user has installed libreadline and not disabled its use
 117   dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
 118   dnl will then succeed.
 119   am_save_CPPFLAGS="$CPPFLAGS"
 120   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE $INCHISTORY])
 121
 122   AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
 123     gl_cv_lib_readline=no
 124     am_save_LIBS="$LIBS"
 125     dnl On some systems, -lreadline doesn't link without an additional
 126     dnl -lncurses or -ltermcap.
 127     dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
 128     dnl by design and obsolete since 1994. Try -lcurses last, because
 129     dnl libcurses is unusable on some old Unices.
 130     for extra_lib in "" ncurses termcap curses; do
 131       LIBS="$am_save_LIBS $LIBREADLINE $LIBHISTORY"
 132       if test -n "$extra_lib"; then
 133         LIBS="$LIBS -l$extra_lib"
 134       fi
 135       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 136 #include <readline/readline.h>
 137 #include <readline/history.h>]], [[readline((char*)0); add_history((char*)0);]])],[gl_cv_lib_readline=yes],[])
 138       if test "$gl_cv_lib_readline" = yes; then
 139         if test -n "$extra_lib"; then
 140           LIBREADLINE="$LIBREADLINE $LIBHISTORY -l$extra_lib"
 141           LTLIBREADLINE="$LTLIBREADLINE $LTLIBHISTORY -l$extra_lib"
 142         fi
 143         break
 144       fi
 145     done
 146     LIBS="$am_save_LIBS"
 147   ])
 148
 149   if test "$gl_cv_lib_readline" = yes; then
 150     AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
 151     AC_MSG_CHECKING([how to link with libreadline])
 152     AC_MSG_RESULT([$LIBREADLINE])
 153   else
 154     dnl If $LIBREADLINE didn't lead to a usable library, we don't
 155     dnl need $INCREADLINE either.
 156     CPPFLAGS="$am_save_CPPFLAGS"
 157     LIBREADLINE=
 158     LTLIBREADLINE=
 159     LIBHISTORY=
 160     LTLIBHISTORY=
 161     PSPP_OPTIONAL_PREREQ([libreadline (which may itself require libncurses or libtermcap)])
 162   fi
 163   AC_SUBST(LIBREADLINE)
 164   AC_SUBST(LTLIBREADLINE)
 165 ])
 166
 167 dnl Check for build tools.  Adapted from bfd library.
 168
 169 AC_DEFUN([PSPP_CC_FOR_BUILD],
 170 [# Put a plausible default for CC_FOR_BUILD in Makefile.
 171 if test -z "$CC_FOR_BUILD"; then
 172   if test "x$cross_compiling" = "xno"; then
 173     CC_FOR_BUILD='$(CC)'
 174   else
 175     CC_FOR_BUILD=cc
 176   fi
 177 fi
 178 AC_SUBST(CC_FOR_BUILD)
 179 # Also set EXEEXT_FOR_BUILD.
 180 if test "x$cross_compiling" = "xno"; then
 181   EXEEXT_FOR_BUILD='$(EXEEXT)'
 182 else
 183   AC_CACHE_CHECK([for build system executable suffix], pspp_cv_build_exeext,
 184     [rm -f conftest*
 185      echo 'int main () { return 0; }' > conftest.c
 186      pspp_cv_build_exeext=
 187      ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5
 188      for file in conftest.*; do
 189        case $file in # (
 190        *.c | *.o | *.obj | *.ilk | *.pdb) ;; # (
 191        *) pspp_cv_build_exeext=`echo $file | sed -e s/conftest//` ;;
 192        esac
 193      done
 194      rm -f conftest*
 195      test x"${pspp_cv_build_exeext}" = x && pspp_cv_build_exeext=no])
 196   EXEEXT_FOR_BUILD=""
 197   test x"${pspp_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${pspp_cv_build_exeex
 198 t}
 199 fi
 200 AC_SUBST(EXEEXT_FOR_BUILD)])
 201
 202 dnl Check for LC_PAPER, _NL_PAPER_WIDTH, _NL_PAPER_HEIGHT.
 203 AC_DEFUN([PSPP_LC_PAPER],
 204 [AC_CACHE_CHECK(for LC_PAPER, pspp_cv_lc_paper, [
 205     pspp_cv_lc_paper=no
 206     AC_COMPILE_IFELSE(
 207       [AC_LANG_PROGRAM(
 208         [#include <locale.h>
 209 #include <langinfo.h>
 210 ],
 211         [(void) LC_PAPER; (void) _NL_PAPER_WIDTH; (void) _NL_PAPER_HEIGHT])],
 212       [pspp_cv_lc_paper=yes])
 213   ])
 214   if test "$pspp_cv_lc_paper" = yes; then
 215     AC_DEFINE(HAVE_LC_PAPER, 1, [Define if you have LC_PAPER.])
 216   fi
 217 ])
 218
 219
 220 # PSPP_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 221 # -------------------------------------------------------------
 222 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 223 # into a program.
 224 #
 225 # Test that resulting file is executable; see the problem reported by mwoehlke
 226 # in <http://lists.gnu.org/archive/html/bug-coreutils/2006-10/msg00048.html>.
 227 # But skip the test when cross-compiling, to prevent problems like the one
 228 # reported by Chris Johns in
 229 # <http://lists.gnu.org/archive/html/autoconf/2007-03/msg00085.html>.
 230 #
 231 m4_define([PSPP_LINK2_IFELSE],
 232 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 233 mv conftest.$ac_ext conftest1.$ac_ext
 234 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 235 mv conftest.$ac_ext conftest2.$ac_ext
 236 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 237 pspp_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 238 AS_IF([_AC_DO_STDERR($pspp_link2) && {
 239          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 240          test ! -s conftest.err
 241        } && test -s conftest$ac_exeext && {
 242          test "$cross_compiling" = yes ||
 243          AS_TEST_X([conftest$ac_exeext])
 244        }],
 245       [$3],
 246       [echo "$as_me: failed source file 1 of 2 was:" >&5
 247 sed 's/^/| /' conftest1.$ac_ext >&5
 248 echo "$as_me: failed source file 2 of 2 was:" >&5
 249 sed 's/^/| /' conftest2.$ac_ext >&5
 250         $4])
 251 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 252 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 253 dnl as it would interfere with the next link command.
 254 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 255 rm -f core conftest.err conftest1.err conftest2.err
 256 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 257 rm -f conftest$ac_exeext
 258 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 259 ])# PSPP_LINK2_IFELSE
 260
 261 # GSL uses "extern inline" without determining whether the compiler uses
 262 # GCC inline rules or C99 inline rules.  If it uses the latter then GSL
 263 # will be broken without passing -fgnu89-inline to GCC.
 264 AC_DEFUN([PSPP_GSL_NEEDS_FGNU89_INLINE],
 265 [# GSL only uses "inline" at all if HAVE_INLINE is defined as a macro.
 266  # In turn, gnulib's gl_INLINE is one macro that does that.  We need to
 267  # make sure that it has run by the time we run this test, otherwise we'll
 268  # get a false result.
 269  AC_REQUIRE([gl_INLINE])
 270  PSPP_CHECK_CC_OPTION(
 271    [-fgnu89-inline],
 272    [AC_CACHE_CHECK([whether GSL needs -fgnu89-inline to link],
 273                     pspp_cv_gsl_needs_fgnu89_inline, [
 274                     PSPP_LINK2_IFELSE(
 275                       [AC_LANG_PROGRAM([#include <gsl/gsl_math.h>
 276                                        ], [GSL_MAX_INT(1,2);])],
 277                       [AC_LANG_SOURCE([#include <gsl/gsl_math.h>
 278                                        void x (void) {}])],
 279                       [pspp_cv_gsl_needs_fgnu89_inline=no],
 280                       [pspp_cv_gsl_needs_fgnu89_inline=yes])])
 281      if test "$pspp_cv_gsl_needs_fgnu89_inline" = "yes"; then
 282          CFLAGS="$CFLAGS -fgnu89-inline"
 283      fi])
 284 ])
 285
 286 AC_DEFUN([PSPP_CHECK_CLICKSEQUENCE],
 287   [AC_REQUIRE([AM_INIT_AUTOMAKE])  # Defines MAKEINFO
 288    AC_CACHE_CHECK([whether makeinfo supports @clicksequence],
 289      [pspp_cv_have_clicksequence],
 290      [cat > conftest.texi  <<EOF
 291 @setfilename conftest.info
 292 @clicksequence{File @click{} Open}
 293 EOF
 294       echo "configure:__oline__: running $MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD" >&AS_MESSAGE_LOG_FD
 295       eval "$MAKEINFO conftest.texi >&AS_MESSAGE_LOG_FD 2>&1"
 296       retval=$?
 297       echo "configure:__oline__: \$? = $retval" >&AS_MESSAGE_LOG_FD
 298       if test $retval = 0; then
 299         pspp_cv_have_clicksequence=yes
 300       else
 301         pspp_cv_have_clicksequence=no
 302       fi
 303       rm -f conftest.texi conftest.info])
 304    if test $pspp_cv_have_clicksequence = no; then
 305        AM_MAKEINFOFLAGS="$AM_MAKEINFOFLAGS -DMISSING_CLICKSEQUENCE"
 306        AC_SUBST([AM_MAKEINFOFLAGS])
 307    fi])