configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.60)
   5 AC_INIT([pspp],[0.7.2],[bug-gnu-pspp@gnu.org])
   6 AC_CONFIG_HEADERS([config.h])
   7 AM_INIT_AUTOMAKE
   8
   9 dnl Checks for programs.
  10 AC_GNU_SOURCE
  11 AC_PROG_CC
  12 gl_EARLY
  13 AM_PROG_CC_C_O
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_LIBTOOL_DLOPEN
  16 AC_PROG_LIBTOOL
  17 PKG_PROG_PKG_CONFIG
  18 m4_pattern_forbid([PKG_CHECK_MODULES])
  19
  20 AC_ARG_ENABLE(
  21   anachronistic-dependencies,
  22   [AS_HELP_STRING([--enable-anachronistic-dependencies],
  23                   [Attempt to allow building against older versions of dependent libraries])])
  24
  25 PSPP_ENABLE_OPTION(-Wdeclaration-after-statement)
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Internationalization macros.
  33 AC_ARG_ENABLE(nls, [AS_HELP_STRING([--disable-nls], [do not use Native Language Support])])
  34 if  test x"$enable_nls" != x"no"  ; then
  35  AC_DEFINE(ENABLE_NLS, 1, [Define to 1 if translation of program messages to the user's native language is requested.])
  36 fi
  37
  38
  39 dnl Checks for libraries.
  40 AC_SYS_LARGEFILE
  41 AC_SEARCH_LIBS([sin], [m])
  42 PSPP_LIBPLOT
  43 PSPP_LC_PAPER
  44 AM_CONDITIONAL(WITHCHARTS, test x"$with_libplot" != x"no")
  45
  46
  47 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  48 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  49
  50
  51 AC_ARG_WITH(
  52   gui,
  53   [AS_HELP_STRING([--without-gui], [don't build the PSPPIRE gui])])
  54
  55 required_gtk_version=2.12
  56
  57 if test x"$with_gui" != x"no" ; then
  58   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $required_gtk_version,,
  59     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 v$required_gtk_version or later (or use --without-gui)])])
  60 fi
  61 AM_CONDITIONAL(WITHGUI, test x"$with_gui" != x"no")
  62
  63
  64 dnl Checks needed for psql reader
  65
  66 dnl The 8.x series postgres tarballs installs with a default prefix of
  67 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  68
  69 dnl If the libpq.so file is in a non standard path, (one which the linker
  70 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  71 dnl However, if the system happens to have more than one version of other
  72 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  73 dnl /usr and /usr/local) then the wrong one may get linked.
  74
  75 dnl To overcome this, we first check for libpq in the standard places, and
  76 dnl only set PG_LDFLAGS if it's not found.
  77
  78
  79 AC_ARG_WITH(
  80   libpq,
  81   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
  82
  83 if test x"$with_libpq" != x"no" ; then
  84  AC_SEARCH_LIBS([PQexec], [pq], [libpq_in_std_lib_path=yes])
  85
  86  AC_ARG_VAR([PG_CONFIG], [Full pathname of the pg_config program shipped with Postgresql])
  87  if test x"$cross_compiling" != x"yes" ; then
  88    AC_PATH_PROG([PG_CONFIG], [pg_config], [], [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
  89  fi
  90  if test -n "$PG_CONFIG" ; then
  91    AC_SUBST(PG_CONFIG)
  92    AC_DEFINE([PSQL_SUPPORT], 1,
  93    [Define to 1 if building in support for reading from postgres databases.])
  94    PG_CFLAGS=-I`$PG_CONFIG --includedir`
  95    AC_SUBST(PG_CFLAGS)
  96
  97    if test "x$libpq_in_std_lib_path" != x"yes" ; then
  98       PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"
  99    fi
 100    AC_SUBST(PG_LDFLAGS)
 101
 102    PG_LIBS=-lpq
 103    AC_SUBST(PG_LIBS)
 104    PKG_CHECK_EXISTS(libssl,
 105          AC_DEFINE([USE_SSL],1,
 106                     [Define to 1 if the openssl library is present.])
 107             ,)
 108  fi
 109 fi
 110 AM_CONDITIONAL(PSQL_SUPPORT, test -n "$PG_CONFIG")
 111
 112 dnl Checks needed for Gnumeric reader
 113 gnm_support=yes;
 114 PKG_CHECK_MODULES(LIBXML2, libxml-2.0,,
 115                            [PSPP_OPTIONAL_PREREQ([libxml2]); gnm_support=no;]);
 116 AC_SEARCH_LIBS(gzopen,z,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 117 AC_CHECK_HEADERS(zlib.h,,[PSPP_OPTIONAL_PREREQ([zlib]); gnm_support=no;])
 118
 119 if test x"$gnm_support" = x"yes" ; then
 120    AC_DEFINE([GNM_SUPPORT], 1,
 121    [Define to 1 if building in support for reading Gnumeric files.])
 122 fi
 123 AM_CONDITIONAL(GNM_SUPPORT, test x"$gnm_support" = x"yes")
 124
 125 AC_ARG_WITH(
 126   gui_tools,
 127   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 128 if test x"$with_gui_tools" = x"yes" ; then
 129         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 130 fi
 131 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 132
 133 AM_CONDITIONAL(WITH_PERL_MODULE, test x"$cross_compiling" != x"yes")
 134
 135 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 136 AC_SEARCH_LIBS([gsl_cdf_binomial_P], [gsl],,[PSPP_REQUIRED_PREREQ([libgsl (version 1.8 or later)])])
 137 PSPP_GSL_NEEDS_FGNU89_INLINE
 138
 139 dnl Recent versions of GNU ncurses install the curses header files into
 140 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 141 dnl enables us to discover where they are. Earlier versions don't have
 142 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 143 dnl we'll trust it to find the right information.  Otherwise, we'll
 144 dnl try to discover it ourselves.
 145 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 146 dnl to ncurses8-config !!!
 147 AC_ARG_WITH(
 148   libncurses,
 149   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 150
 151 if test x"$with_libncurses" != x"no" ; then
 152   if test x"$cross_compiling" != x"yes" ; then
 153           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 154   fi
 155   if test x"$NCURSES_CONFIG" = x ; then
 156           AC_SEARCH_LIBS([tgetent], [ncurses],
 157               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 158   else
 159           old_cflags=$CFLAGS
 160           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 161           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 162           CFLAGS=$old_cflags
 163           if test x"$curses_available" = x"yes" ; then
 164            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 165            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 166            AC_SUBST(NCURSES_CFLAGS)
 167            AC_SUBST(NCURSES_LIBS)
 168           fi
 169   fi
 170   if test x"$curses_available" = x"yes" ; then
 171           AC_DEFINE([LIBNCURSES_USABLE], 1,
 172               [Define to 1 if the libncurses is both present and usable.])
 173   fi
 174   AC_CHECK_HEADERS([termcap.h])
 175 fi
 176
 177 PSPP_READLINE
 178
 179 dnl Checks for header files.
 180 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h])
 181
 182 # For gnulib.
 183 gl_INIT
 184
 185 AC_C_INLINE
 186
 187 AC_CHECK_SIZEOF(double)
 188
 189 AC_C_BIGENDIAN
 190
 191 AC_CHECK_FUNCS([__setfpucw fork execl execlp isinf isnan finite getpid feholdexcept fpsetmask popen round])
 192
 193 AC_PROG_LN_S
 194
 195 AC_ARG_ENABLE(
 196   debug,
 197   [AS_HELP_STRING([--enable-debug],
 198                   [Turn on diagnostic features in the program])])
 199 if test x"$enable_debug" = x"yes"  ; then
 200   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 201 fi
 202
 203 # iconv is required
 204 if test "$am_cv_func_iconv" != "yes"; then
 205    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 206 fi
 207
 208 PSPP_CHECK_PREREQS
 209
 210 AC_CONFIG_FILES([Makefile gl/Makefile])
 211
 212 AC_OUTPUT
 213 echo "PSPP configured successfully."
 214
 215 dnl configure.ac ends here