pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4
   5 our ($mem) = 4;
   6 our ($serial_out) = 1;
   7 our (@disks) = ("os.dsk", "fs.dsk", "scratch.dsk", "swap.dsk");
   8 our ($sim);
   9 our ($debug);
  10 our ($vga);
  11 our ($jitter, $realtime);
  12
  13 use Getopt::Long qw(:config require_order bundling);
  14 unshift (@ARGV, split (' ', $ENV{PINTOSOPTS}))
  15     if defined $ENV{PINTOSOPTS};
  16 GetOptions ("sim=s" => sub { set_sim (@_) },
  17             "bochs" => sub { set_sim ("bochs") },
  18             "qemu" => sub { set_sim ("qemu") },
  19             "gsx" => sub { set_sim ("gsx") },
  20
  21             "debug=s" => sub { set_debug (@_) },
  22             "no-debug" => sub { set_debug ("no-debug") },
  23             "monitor" => sub { set_debug ("monitor") },
  24             "gdb" => sub { set_debug ("gdb") },
  25
  26             "run|get|put|make-disk" => \&cmd_option,
  27
  28             "m|memory=i" => \$mem,
  29             "j|jitter=i" => sub { set_jitter (@_) },
  30             "r|realtime" => sub { set_realtime () },
  31
  32             "v|no-vga" => sub { set_vga ('none'); },
  33             "s|no-serial" => sub { $serial_out = 0; },
  34             "t|terminal" => sub { set_vga ('terminal'); },
  35
  36             "h|help" => sub { usage (0); },
  37
  38             "0|os-disk|disk-0|hda=s" => \$disks[0],
  39             "1|fs-disk|disk-1|hdb=s" => \$disks[1],
  40             "2|scratch-disk|disk-2|hdc=s" => \$disks[2],
  41             "3|swap-disk|disk-3|hdd=s" => \$disks[3])
  42     or exit 1;
  43
  44 $sim = "bochs" if !defined $sim;
  45 $debug = "no-debug" if !defined $debug;
  46 $vga = "window" if !defined $vga;
  47
  48 sub set_sim {
  49     my ($new_sim) = @_;
  50     die "--$new_sim conflicts with --$sim\n"
  51         if defined ($sim) && $sim ne $new_sim;
  52     $sim = $new_sim;
  53 }
  54
  55 sub set_debug {
  56     my ($new_debug) = @_;
  57     die "--$new_debug conflicts with --$debug\n"
  58         if defined ($debug) && $debug ne $new_debug;
  59     $debug = $new_debug;
  60 }
  61
  62 sub set_vga {
  63     my ($new_vga) = @_;
  64     if (defined ($vga) && $vga ne $new_vga) {
  65         print "warning: conflicting vga display options\n";
  66     }
  67     $vga = $new_vga;
  68 }
  69
  70 sub set_jitter {
  71     my ($new_jitter) = @_;
  72     die "--realtime conflicts with --jitter\n" if defined $realtime;
  73     die "different --jitter already defined\n"
  74         if defined $jitter && $jitter != $new_jitter;
  75     $jitter = $new_jitter;
  76 }
  77
  78 sub set_realtime {
  79     die "--realtime conflicts with --jitter\n" if defined $jitter;
  80     $realtime = 1;
  81 }
  82
  83 sub cmd_option {
  84     # Force an end to option processing, as with --.
  85     die ("!FINISH");
  86 }
  87
  88 die "no command specified; use --help for help\n"
  89     if @ARGV < 1;
  90 my ($cmd) = shift @ARGV;
  91 if ($cmd eq 'run') {
  92     run_vm ('EXEC', @ARGV);
  93 } elsif ($cmd eq 'make-disk') {
  94     usage () if @ARGV != 2;
  95     my ($file, $mb) = @ARGV;
  96     usage () if $mb !~ /^\d+(\.\d+)?|\.\d+$/;
  97     die "$file: already exists\n" if -e $file;
  98
  99     create_disk ($file, int ($mb * 1008));
 100 } elsif ($cmd eq 'put') {
 101     # Take a -f option to combine formatting with putting.
 102     my ($format) = 0;
 103     if (@ARGV > 0 && $ARGV[0] eq '-f') {
 104         shift @ARGV;
 105         $format = 1;
 106     }
 107
 108     usage () if @ARGV != 1 && @ARGV != 2;
 109     my ($hostfn, $guestfn) = @ARGV;
 110     $guestfn = $hostfn if !defined $guestfn;
 111
 112     # Create scratch disk from file.
 113     die "$hostfn: $!\n" if ! -e $hostfn;
 114     my ($size) = -s _;
 115     if ($size) {
 116         copy_pad ($hostfn, "scratch.dsk", 512);
 117     } else {
 118         open (SCRATCH, ">scratch.dsk") or die "scratch.dsk: create: $!\n";
 119         syswrite (SCRATCH, "\0" x 512);
 120         close (SCRATCH);
 121     }
 122
 123     # Do copy.
 124     my (@cmd) = ("-ci", $guestfn, $size, "-q");
 125     unshift (@cmd, "-f") if $format;
 126     run_vm ('EXEC', @cmd);
 127
 128     exit 1;
 129 } elsif ($cmd eq 'get') {
 130     usage () if @ARGV != 1 && @ARGV != 2;
 131     my ($guestfn, $hostfn) = @ARGV;
 132     $hostfn = $guestfn if !defined $hostfn;
 133     die "$hostfn: already exists\n" if -e $hostfn;
 134
 135     # Create scratch disk big enough for any file in the filesystem
 136     # (modulo sparse files).
 137     die "$disks[1]: $!\n" if ! -e $disks[1];
 138     my ($fs_size) = -s _;
 139     my ($scratch_size) = -s $disks[2];
 140     $scratch_size = 0 if !defined $scratch_size;
 141     create_disk ($disks[2], $fs_size / 1024 + 16)
 142         if $scratch_size < $fs_size + 16384;
 143
 144     # Do copy.
 145     run_vm ('FORK', "-co", $guestfn, "-q");
 146
 147     # Read out scratch disk.
 148     print "copying $guestfn from $disks[2] to $hostfn...\n";
 149     open (SRC, "<$disks[2]") or die "$disks[2]: open: $!\n";
 150     open (DST, ">$hostfn") or die "$hostfn: create: $!\n";
 151     my ($input);
 152     read (SRC, $input, 512) == 512 or die "$disks[2]: read error\n";
 153     my ($size) = unpack ("V", $input);
 154     $size != 0xffffffff or die "$guestfn: too big for $disks[2]?";
 155     my ($src);
 156     read (SRC, $src, $size) == $size or die "$disks[2]: read error\n";
 157     print DST $src or die "$hostfn: write error\n";
 158     close (DST);
 159     close (SRC);
 160
 161     exit 1;
 162 } elsif ($cmd eq 'help') {
 163     usage (0);
 164 } else {
 165     die "unknown command `$cmd'; use --help for help\n";
 166 }
 167 exit 0;
 168
 169 sub usage {
 170     my ($exitcode) = @_;
 171     $exitcode = 1 unless defined $exitcode;
 172     print "pintos, a utility for invoking Pintos in a simulator\n";
 173     print "Usage: pintos [OPTION...] COMMAND [ARG...]\n";
 174     print "where COMMAND is one of the following:\n";
 175     print "  run [CMDLINE...]        run a VM in the simulator\n";
 176     print "  make-disk FILE.DSK SIZE create FILE.DSK as empty SIZE MB disk\n";
 177     print "  put HOSTFN [GUESTFN]    copy HOSTFN into VM (as GUESTFN)\n";
 178     print "  get GUESTFN [HOSTFN]    copy GUESTFN out of VM (to HOSTFN)\n";
 179     print "  help                    print this help message and exit\n";
 180     print "Simulator options:\n";
 181     print "  --bochs          (default) Use Bochs as simulator\n";
 182     print "  --qemu           Use qemu as simulator\n";
 183     print "  --gsx            Use VMware GSX Server 3.x as simulator\n";
 184     print "Debugger options:\n";
 185     print "  --no-debug       (default) No debugger\n";
 186     print "  --monitor        Debug with simulator's monitor\n";
 187     print "  --gdb            Debug with gdb\n";
 188     print "Display options: (default is VGA + serial)\n";
 189     print "  -v, --no-vga     No VGA display\n";
 190     print "  -s, --no-serial  No serial output\n";
 191     print "  -t, --terminal   Display VGA in terminal (Bochs only)\n";
 192     print "VM options:\n";
 193     print "  -j SEED          Randomize timer interrupts (Bochs only)\n";
 194     print "  -r, --realtime   Use realistic, but not reproducible, timings\n";
 195     print "  -m, --mem=MB     Run VM with MB megabytes of physical memory\n";
 196     print "Disk options:\n";
 197     print "  --os-disk=DISK    Set OS disk file (default: os.dsk)\n";
 198     print "  --fs-disk=DISK    Set FS disk file (default: fs.dsk)\n";
 199     print "  --scratch-disk=DISK   Set scratch disk (default: scratch.dsk)\n";
 200     print "  --swap-disk=DISK  Set swap disk file (default: swap.dsk)\n";
 201     exit $exitcode;
 202 }
 203
 204 sub copy_pad {
 205     my ($src, $dst, $blocksize) = @_;
 206     run_command ("dd", "if=$src", "of=$dst", "bs=$blocksize", "conv=sync");
 207 }
 208
 209 sub create_disk {
 210     my ($disk, $kb) = @_;
 211     run_command ("dd", "if=/dev/zero", "of=$disk", "bs=1024", "count=$kb");
 212 }
 213
 214 sub run_vm {
 215     my ($fork) = shift;
 216     $fork eq 'FORK' || $fork eq 'EXEC' or die;
 217
 218     our (@disks);
 219
 220     die "$disks[0]: can't find OS disk\n" if ! -e $disks[0];
 221     for my $i (1...3) {
 222         undef $disks[$i] if ! -e $disks[$i];
 223     }
 224
 225     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 226         if ((grep ($project eq $_, qw (userprog vm filesys)))
 227             && !defined ($disks[1])) {
 228             print STDERR "warning: it looks like you're running the $project ";
 229             print STDERR "project, but no file system disk is present\n";
 230         }
 231         if ($project eq 'vm' && !defined $disks[3]) {
 232             print STDERR "warning: it looks like you're running the $project ";
 233             print STDERR "project, but no swap disk is present\n";
 234         }
 235     }
 236
 237     write_cmd_line ($disks[0], @_);
 238
 239     if ($sim eq 'bochs') {
 240         my ($bin);
 241         if ($debug eq 'no-debug') {
 242             $bin = 'bochs';
 243         } elsif ($debug eq 'monitor') {
 244             $bin = 'bochs-dbg';
 245         } elsif ($debug eq 'gdb') {
 246             $bin = 'bochs-gdb';
 247         }
 248
 249         my ($bochsbin) = search_path ($bin);
 250         my ($bochsshare) = "$bochsbin/../share/bochs";
 251
 252         open (BOCHSRC, ">bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 253         print BOCHSRC "romimage: file=$bochsshare/BIOS-bochs-latest, "
 254             . "address=0xf0000\n";
 255         print BOCHSRC "vgaromimage: $bochsshare/VGABIOS-lgpl-latest\n";
 256         print BOCHSRC bochs_disk_line ("ata0-master", $disks[0]);
 257         print BOCHSRC bochs_disk_line ("ata0-slave", $disks[1]);
 258         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ioaddr2=0x370, irq=15\n"
 259             if defined ($disks[2]) || defined ($disks[3]);
 260         print BOCHSRC bochs_disk_line ("ata1-master", $disks[2]);
 261         print BOCHSRC bochs_disk_line ("ata1-slave", $disks[3]);
 262         print BOCHSRC "boot: c\n";
 263         print BOCHSRC "ips: 1000000\n";
 264         if (!$realtime) {
 265             print BOCHSRC "clock: sync=none, time0=0\n";
 266         } else {
 267             print BOCHSRC "clock: sync=realtime, time0=0\n";
 268         }
 269         print BOCHSRC "megs: $mem\n";
 270         print BOCHSRC "log: bochsout.txt\n";
 271         if ($vga ne 'terminal') {
 272             print BOCHSRC "com1: enabled=1, dev=/dev/stdout\n"
 273                 if $serial_out;
 274             print BOCHSRC "display_library: nogui\n"
 275                 if $vga eq 'none';
 276         } else {
 277             print BOCHSRC "display_library: term\n";
 278         }
 279         close (BOCHSRC);
 280
 281         my (@cmd) = ($bin, '-q');
 282         push (@cmd, '-j', $jitter) if defined $jitter;
 283         print join (' ', @cmd), "\n";
 284         $fork eq 'EXEC' ? exec (@cmd) : system (@cmd);
 285     } elsif ($sim eq 'qemu') {
 286         print "warning: qemu doesn't support --terminal\n"
 287             if $vga eq 'terminal';
 288         print "warning: qemu doesn't support jitter\n"
 289             if defined $jitter;
 290         my (@cmd) = ('qemu');
 291         push (@cmd, '-hda', $disks[0]) if defined $disks[0];
 292         push (@cmd, '-hdb', $disks[1]) if defined $disks[1];
 293         push (@cmd, '-hdc', $disks[2]) if defined $disks[2];
 294         push (@cmd, '-hdd', $disks[3]) if defined $disks[3];
 295         push (@cmd, '-m', $mem);
 296         push (@cmd, '-nographic') if $vga eq 'none';
 297         push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 298         push (@cmd, '-S') if $debug eq 'monitor';
 299         push (@cmd, '-s') if $debug eq 'gdb';
 300         run_command (@cmd);
 301         exit 1;
 302     } elsif ($sim eq 'gsx') {
 303         print "warning: VMware GSX Server doesn't support --$debug\n"
 304             if $debug ne 'no-debug';
 305         print "warning: VMware GSX Server doesn't support --no-vga\n"
 306             if $vga eq 'none';
 307         print "warning: VMware GSX Server doesn't support --terminal\n"
 308             if $vga eq 'terminal';
 309         print "warning: VMware GSX Server doesn't support jitter\n"
 310             if defined $jitter;
 311
 312         open (VMX, ">pintos.vmx") or die "pintos.vmx: create: $!\n";
 313         chmod 0777 & ~umask, "pintos.vmx";
 314         print VMX "#! /usr/bin/vmware -G\n";
 315         print VMX "config.version = 6\n";
 316         print VMX "guestOS = \"linux\"\n";
 317         print VMX "floppy0.present = FALSE\n";
 318
 319         unlink ("pintos.out");
 320         print VMX "serial0.present = TRUE\n";
 321         print VMX "serial0.fileType = \"file\"\n";
 322         print VMX "serial0.fileName = \"pintos.out\"\n";
 323
 324         if (! -e 'null.bin') {
 325             open (NULL, ">null.bin") or die "null.bin: create: $!\n";
 326             close (NULL);
 327         }
 328
 329         for (my ($i) = 0; $i < 4; $i++) {
 330             my ($dsk) = $disks[$i];
 331             next if !defined $dsk;
 332
 333             my ($pln) = $dsk;
 334             $pln =~ s/\.dsk//;
 335             $pln .= ".pln";
 336
 337             my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 338             print VMX "\n$device.present = TRUE\n";
 339             print VMX "$device.deviceType = \"plainDisk\"\n";
 340             print VMX "$device.fileName = \"$pln\"\n";
 341
 342             my (%geom) = disk_geometry ($dsk);
 343             open (PLN, ">$pln") or die "$pln: create: $!\n";
 344             print PLN "DRIVETYPE        ide\n";
 345             print PLN "#vm|VERSION      2\n";
 346             print PLN "#vm|TOOLSVERSION 2\n";
 347             print PLN "CYLINDERS        $geom{C}\n";
 348             print PLN "HEADS            $geom{H}\n";
 349             print PLN "SECTORS          $geom{S}\n";
 350             print PLN "#vm|CAPACITY     $geom{CAPACITY}\n";
 351             print PLN "ACCESS \"$dsk\" 0 $geom{CAPACITY}\n";
 352             close (PLN);
 353         }
 354         close (VMX);
 355
 356         use Cwd;
 357         my ($vmx) = getcwd () . "/pintos.vmx";
 358         system ("vmware-cmd -s register $vmx >&/dev/null");
 359         system ("vmware-cmd $vmx stop hard >&/dev/null");
 360         system ("vmware -l -G -x -q $vmx");
 361         system ("vmware-cmd $vmx stop hard >&/dev/null");
 362
 363         exit 1;
 364     }
 365 }
 366
 367 sub write_cmd_line {
 368     my ($disk, @args) = @_;
 369
 370     die "command line includes empty string" if grep (/^$/, @args);
 371     my ($args) = join ("\0", @args) . "\0\0";
 372     die "command line exceeds 128 bytes" if length ($args) > 128;
 373     $args .= "\0" x (128 - length ($args));
 374
 375     print "writing command line to $disk...\n";
 376     open (DISK, "+<$disk") or die "$disk: open: $!\n";
 377     seek (DISK, 0x17e, 0) or die "$disk: seek: $!\n";
 378     syswrite (DISK, $args) or die "$disk: write: $!\n";
 379     close (DISK) or die "$disk: close: $!\n";
 380 }
 381
 382 sub run_command {
 383     print join (' ', @_), "\n";
 384     die "command failed\n" if system (@_);
 385 }
 386
 387 sub search_path {
 388     my ($target) = @_;
 389     for my $dir (split (':', $ENV{PATH})) {
 390         return $dir if -e "$dir/$target";
 391     }
 392     die "$target not in PATH\n";
 393 }
 394
 395 sub bochs_disk_line {
 396     my ($device, $file) = @_;
 397     return "" if !defined $file;
 398     my (%geom) = disk_geometry ($file);
 399     return "$device: type=disk, path=$file, mode=flat, "
 400         . "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, "
 401         . "translation=none\n";
 402 }
 403
 404 sub disk_geometry {
 405     my ($file) = @_;
 406     my ($size) = -s $file;
 407     die "$file: stat: $!\n" if !defined $size;
 408     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 409     my ($cylinders) = int ($size / (512 * 16 * 63));
 410     $cylinders++ if $size % (512 * 16 * 63);
 411
 412     return (CAPACITY => $size / 512,
 413             C => $cylinders,
 414             H => 16,
 415             S => 63);
 416 }