pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX;
   5 use Fcntl;
   6 use File::Temp 'tempfile';
   7 use Getopt::Long qw(:config bundling);
   8
   9 # Command-line options.
  10 our ($start_time) = time ();
  11 our ($sim);                     # Simulator: bochs, qemu, or gsx.
  12 our ($debug) = "none";          # Debugger: none, monitor, or gdb.
  13 our ($mem) = 4;                 # Physical RAM in MB.
  14 our ($serial_out) = 1;          # Send output to serial port?
  15 our ($vga);                     # VGA output: window, terminal, or none.
  16 our ($jitter);                  # Seed for random timer interrupts, if set.
  17 our ($realtime);                # Synchronize timer interrupts with real time?
  18 our ($timeout);                 # Maximum runtime in seconds, if set.
  19 our ($kill_on_failure);         # Abort quickly on test failure?
  20 our (@puts);                    # Files to copy into the VM.
  21 our (@gets);                    # Files to copy out of the VM.
  22 our ($as_ref);                  # Reference to last addition to @gets or @puts.
  23 our (@kernel_args);             # Arguments to pass to kernel.
  24 our (%disks) = (OS => {DEF_FN => 'os.dsk'},             # Disks to give VM.
  25                 FS => {DEF_FN => 'fs.dsk'},
  26                 SCRATCH => {DEF_FN => 'scratch.dsk'},
  27                 SWAP => {DEF_FN => 'swap.dsk'});
  28 our (@disks_by_iface) = @disks{qw (OS FS SCRATCH SWAP)};
  29
  30 parse_command_line ();
  31 find_disks ();
  32 prepare_scratch_disk ();
  33 prepare_arguments ();
  34 run_vm ();
  35 finish_scratch_disk ();
  36
  37 exit 0;
  38 \f
  39 # Parses the command line.
  40 sub parse_command_line {
  41     usage (0) if @ARGV == 0 || (@ARGV == 1 && $ARGV[0] eq '--help');
  42
  43     @kernel_args = @ARGV;
  44     if (grep ($_ eq '--', @kernel_args)) {
  45         @ARGV = ();
  46         while ((my $arg = shift (@kernel_args)) ne '--') {
  47             push (@ARGV, $arg);
  48         }
  49         GetOptions ("sim=s" => sub { set_sim (@_) },
  50                     "bochs" => sub { set_sim ("bochs") },
  51                     "qemu" => sub { set_sim ("qemu") },
  52                     "gsx" => sub { set_sim ("gsx") },
  53
  54                     "debug=s" => sub { set_debug (@_) },
  55                     "no-debug" => sub { set_debug ("none") },
  56                     "monitor" => sub { set_debug ("monitor") },
  57                     "gdb" => sub { set_debug ("gdb") },
  58
  59                     "m|memory=i" => \$mem,
  60                     "j|jitter=i" => sub { set_jitter (@_) },
  61                     "r|realtime" => sub { set_realtime () },
  62
  63                     "T|timeout=i" => \$timeout,
  64                     "k|kill-on-failure" => \$kill_on_failure,
  65
  66                     "v|no-vga" => sub { set_vga ('none'); },
  67                     "s|no-serial" => sub { $serial_out = 0; },
  68                     "t|terminal" => sub { set_vga ('terminal'); },
  69
  70                     "p|put-file=s" => sub { add_file (\@puts, $_[1]); },
  71                     "g|get-file=s" => sub { add_file (\@gets, $_[1]); },
  72                     "a|as=s" => sub { set_as ($_[1]); },
  73
  74                     "h|help" => sub { usage (0); },
  75
  76                     "os-disk=s" => \$disks{OS}{FILE_NAME},
  77                     "fs-disk=s" => \$disks{FS}{FILE_NAME},
  78                     "scratch-disk=s" => \$disks{SCRATCH}{FILE_NAME},
  79                     "swap-disk=s" => \$disks{SWAP}{FILE_NAME},
  80
  81                     "0|disk-0|hda=s" => \$disks_by_iface[0]{FILE_NAME},
  82                     "1|disk-1|hdb=s" => \$disks_by_iface[1]{FILE_NAME},
  83                     "2|disk-2|hdc=s" => \$disks_by_iface[2]{FILE_NAME},
  84                     "3|disk-3|hdd=s" => \$disks_by_iface[3]{FILE_NAME})
  85           or exit 1;
  86     }
  87
  88     $sim = "bochs" if !defined $sim;
  89     $debug = "none" if !defined $debug;
  90     $vga = "window" if !defined $vga;
  91
  92     undef $timeout, print "warning: disabling timeout with --$debug\n"
  93       if defined ($timeout) && $debug ne 'none';
  94
  95     print "warning: enabling serial output for -k or --kill-on-failure\n"
  96       if $kill_on_failure && !$serial_out;
  97 }
  98
  99 # usage($exitcode).
 100 # Prints a usage message and exits with $exitcode.
 101 sub usage {
 102     my ($exitcode) = @_;
 103     $exitcode = 1 unless defined $exitcode;
 104     print <<'EOF';
 105 pintos, a utility for running Pintos in a simulator
 106 Usage: pintos [OPTION...] -- [ARGUMENT...]
 107 where each OPTION is one of the following options
 108   and each ARGUMENT is passed to Pintos kernel verbatim.
 109 Simulator selection:
 110   --bochs                  (default) Use Bochs as simulator
 111   --qemu                   Use qemu as simulator
 112   --gsx                    Use VMware GSX Server 3.x as simulator
 113 Debugger selection:
 114   --no-debug               (default) No debugger
 115   --monitor                Debug with simulator's monitor
 116   --gdb                    Debug with gdb
 117 Display options: (default is both VGA and serial)
 118   -v, --no-vga             No VGA display
 119   -s, --no-serial          No serial output
 120   -t, --terminal           Display VGA in terminal (Bochs only)
 121 Timing options: (Bochs only)
 122   -j SEED                  Randomize timer interrupts
 123   -r, --realtime           Use realistic, not reproducible, timings
 124 Testing options:
 125   -T, --timeout=N          Kill Pintos after N seconds CPU time or N*load_avg
 126                            seconds wall-clock time (whichever comes first)
 127   -k, --kill-on-failure    Kill Pintos a few seconds after a kernel or user
 128                            panic, test failure, or triple fault
 129 Configuration options:
 130   -m, --mem=N              Give Pintos N MB physical RAM (default: 4)
 131 File system commands (for `run' command):
 132   -p, --put-file=HOSTFN    Copy HOSTFN into VM, by default under same name
 133   -g, --get-file=GUESTFN   Copy GUESTFN out of VM, by default under same name
 134   -a, --as=FILENAME        Specifies guest (for -p) or host (for -g) file name
 135 Disk options: (name an existing FILE or specify SIZE in MB for a temp disk)
 136   --os-disk=FILE           Set OS disk file (default: os.dsk)
 137   --fs-disk=FILE|SIZE      Set FS disk file (default: fs.dsk)
 138   --scratch-disk=FILE|SIZE Set scratch disk (default: scratch.dsk)
 139   --swap-disk=FILE|SIZE    Set swap disk file (default: swap.dsk)
 140 Other options:
 141   -h, --help               Display this help message.
 142 EOF
 143     exit $exitcode;
 144 }
 145
 146 # Sets the simulator.
 147 sub set_sim {
 148     my ($new_sim) = @_;
 149     die "--$new_sim conflicts with --$sim\n"
 150         if defined ($sim) && $sim ne $new_sim;
 151     $sim = $new_sim;
 152 }
 153
 154 # Sets the debugger.
 155 sub set_debug {
 156     my ($new_debug) = @_;
 157     die "--$new_debug conflicts with --$debug\n"
 158         if $debug ne 'none' && $new_debug ne 'none' && $debug ne $new_debug;
 159     $debug = $new_debug;
 160 }
 161
 162 # Sets VGA output destination.
 163 sub set_vga {
 164     my ($new_vga) = @_;
 165     if (defined ($vga) && $vga ne $new_vga) {
 166         print "warning: conflicting vga display options\n";
 167     }
 168     $vga = $new_vga;
 169 }
 170
 171 # Sets randomized timer interrupts.
 172 sub set_jitter {
 173     my ($new_jitter) = @_;
 174     die "--realtime conflicts with --jitter\n" if defined $realtime;
 175     die "different --jitter already defined\n"
 176         if defined $jitter && $jitter != $new_jitter;
 177     $jitter = $new_jitter;
 178 }
 179
 180 # Sets real-time timer interrupts.
 181 sub set_realtime {
 182     die "--realtime conflicts with --jitter\n" if defined $jitter;
 183     $realtime = 1;
 184 }
 185
 186 # add_file(\@list, $file)
 187 #
 188 # Adds [$file] to @list, which should be @puts or @gets.
 189 # Sets $as_ref to point to the added element.
 190 sub add_file {
 191     my ($list, $file) = @_;
 192     $as_ref = [$file];
 193     push (@$list, $as_ref);
 194 }
 195
 196 # Sets the guest/host name for the previous put/get.
 197 sub set_as {
 198     my ($as) = @_;
 199     die "-a (or --as) is only allowed after -p or -g\n" if !defined $as_ref;
 200     die "Only one -a (or --as) is allowed after -p or -g\n"
 201       if defined $as_ref->[1];
 202     $as_ref->[1] = $as;
 203 }
 204 \f
 205 # Locates the files used to back each of the virtual disks,
 206 # and creates temporary disks.
 207 sub find_disks {
 208     for my $disk (values %disks) {
 209         # If there's no assigned file name but the default file exists,
 210         # try to assign a default file name.
 211         if (!defined ($disk->{FILE_NAME})) {
 212             for my $try_fn ($disk->{DEF_FN}, "build/" . $disk->{DEF_FN}) {
 213                 $disk->{FILE_NAME} = $try_fn, last
 214                   if -e $try_fn;
 215             }
 216         }
 217
 218         # If there's no file name, we're done.
 219         next if !defined ($disk->{FILE_NAME});
 220
 221         if ($disk->{FILE_NAME} =~ /^\d+(\.\d+)?|\.\d+$/) {
 222             # Create a temporary disk of approximately the specified
 223             # size in megabytes.
 224             die "OS disk can't be temporary\n" if $disk == $disks{OS};
 225
 226             my ($mb) = $disk->{FILE_NAME};
 227             undef $disk->{FILE_NAME};
 228
 229             my ($cyl_size) = 512 * 16 * 63;
 230             extend_disk ($disk, ceil ($mb * 2) * $cyl_size);
 231         } else {
 232             # The file must exist and have nonzero size.
 233             -e $disk->{FILE_NAME} or die "$disk->{FILE_NAME}: stat: $!\n";
 234             -s _ or die "$disk->{FILE_NAME}: disk has zero size\n";
 235         }
 236     }
 237
 238     # Warn about (potentially) missing disks.
 239     die "Cannot find OS disk\n" if !defined $disks{OS}{FILE_NAME};
 240     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 241         if ((grep ($project eq $_, qw (userprog vm filesys)))
 242             && !defined ($disks{FS}{FILE_NAME})) {
 243             print STDERR "warning: it looks like you're running the $project ";
 244             print STDERR "project, but no file system disk is present\n";
 245         }
 246         if ($project eq 'vm' && !defined $disks{SWAP}{FILE_NAME}) {
 247             print STDERR "warning: it looks like you're running the $project ";
 248             print STDERR "project, but no swap disk is present\n";
 249         }
 250     }
 251 }
 252 \f
 253 # Prepare the scratch disk for gets and puts.
 254 sub prepare_scratch_disk {
 255     # Copy the files to put onto the scratch disk.
 256     put_scratch_file ($_->[0]) foreach @puts;
 257
 258     # Make sure the scratch disk is big enough to get big files.
 259     extend_disk ($disks{SCRATCH}, @gets * 1024 * 1024) if @gets;
 260 }
 261
 262 # Read "get" files from the scratch disk.
 263 sub finish_scratch_disk {
 264     # We need to start reading the scratch disk from the beginning again.
 265     if (@gets) {
 266         close ($disks{SCRATCH}{HANDLE});
 267         undef ($disks{SCRATCH}{HANDLE});
 268     }
 269
 270     # Read each file.
 271     get_scratch_file (defined ($_->[1]) ? $_->[1] : $_->[0]) foreach @gets;
 272 }
 273
 274 # put_scratch_file($file).
 275 #
 276 # Copies $file into the scratch disk.
 277 sub put_scratch_file {
 278     my ($put_file_name) = @_;
 279     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 280
 281     print "Copying $put_file_name into $disk_file_name...\n";
 282
 283     # Write metadata sector, which consists of a 4-byte signature
 284     # followed by the file size.
 285     stat $put_file_name or die "$put_file_name: stat: $!\n";
 286     my ($size) = -s _;
 287     my ($metadata) = pack ("a4 V x504", "PUT\0", $size);
 288     write_fully ($disk_handle, $disk_file_name, $metadata);
 289
 290     # Copy file data.
 291     my ($put_handle);
 292     sysopen ($put_handle, $put_file_name, O_RDONLY)
 293       or die "$put_file_name: open: $!\n";
 294     copy_file ($put_handle, $put_file_name, $disk_handle, $disk_file_name,
 295                $size);
 296     close ($put_handle);
 297
 298     # Round up disk data to beginning of next sector.
 299     write_fully ($disk_handle, $disk_file_name, "\0" x (512 - $size % 512))
 300       if $size % 512;
 301 }
 302
 303 # get_scratch_file($file).
 304 #
 305 # Copies from the scratch disk to $file.
 306 sub get_scratch_file {
 307     my ($get_file_name) = @_;
 308     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 309
 310     print "Copying $get_file_name out of $disk_file_name...\n";
 311
 312     # Read metadata sector, which has a 4-byte signature followed by
 313     # the file size.
 314     my ($metadata) = read_fully ($disk_handle, $disk_file_name, 512);
 315     my ($signature, $size) = unpack ("a4 V", $metadata);
 316     die "bad signature reading scratch disk--did Pintos run correctly?\n"
 317       if $signature ne "GET\0";
 318
 319     # Copy file data.
 320     my ($get_handle);
 321     sysopen ($get_handle, $get_file_name, O_WRONLY | O_CREAT | O_EXCL, 0666)
 322       or die "$get_file_name: create: $!\n";
 323     copy_file ($disk_handle, $disk_file_name, $get_handle, $get_file_name,
 324                $size);
 325     close ($get_handle);
 326
 327     # Skip forward in disk up to beginning of next sector.
 328     read_fully ($disk_handle, $disk_file_name, 512 - $size % 512)
 329       if $size % 512;
 330 }
 331 \f
 332 # Prepares the arguments to pass to the Pintos kernel,
 333 # and then write them into Pintos bootloader.
 334 sub prepare_arguments {
 335     my (@args);
 336     push (@args, shift (@kernel_args))
 337       while @kernel_args && $kernel_args[0] =~ /^-/;
 338     push (@args, 'put', defined $_->[1] ? $_->[1] : $_->[0]) foreach @puts;
 339     push (@args, @kernel_args);
 340     push (@args, 'get', $_->[0]) foreach @gets;
 341     write_cmd_line ($disks{OS}, @args);
 342 }
 343
 344 # Writes @args into the Pintos bootloader at the beginning of $disk.
 345 sub write_cmd_line {
 346     my ($disk, @args) = @_;
 347
 348     # Figure out command line to write.
 349     my ($arg_cnt) = pack ("V", scalar (@args));
 350     my ($args) = join ('', map ("$_\0", @args));
 351     die "command line exceeds 128 bytes" if length ($args) > 128;
 352     $args .= "\0" x (128 - length ($args));
 353
 354     # Write command line.
 355     my ($handle, $file_name) = open_disk_copy ($disk);
 356     print "Writing command line to $file_name...\n";
 357     sysseek ($handle, 0x17a, 0) == 0x17a or die "$file_name: seek: $!\n";
 358     syswrite ($handle, "$arg_cnt$args") or die "$file_name: write: $!\n";
 359 }
 360 \f
 361 # Running simulators.
 362
 363 # Runs the selected simulator.
 364 sub run_vm {
 365     if ($sim eq 'bochs') {
 366         run_bochs ();
 367     } elsif ($sim eq 'qemu') {
 368         run_qemu ();
 369     } elsif ($sim eq 'gsx') {
 370         run_gsx ();
 371     } else {
 372         die "unknown simulator `$sim'\n";
 373     }
 374 }
 375
 376 # Runs Bochs.
 377 sub run_bochs {
 378     # Select Bochs binary based on the chosen debugger.
 379     my ($bin) = $debug eq 'monitor' ? 'bochs-dbg' : 'bochs';
 380
 381     # Write bochsrc.txt configuration file.
 382     open (BOCHSRC, ">", "bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 383     print BOCHSRC <<EOF;
 384 romimage: file=\$BXSHARE/BIOS-bochs-latest, address=0xf0000
 385 vgaromimage: file=\$BXSHARE/VGABIOS-lgpl-latest
 386 boot: disk
 387 cpu: ips=1000000
 388 megs: $mem
 389 log: bochsout.txt
 390 panic: action=fatal
 391 EOF
 392     print BOCHSRC "gdbstub: enabled=1\n" if $debug eq 'gdb';
 393     print BOCHSRC "clock: sync=", $realtime ? 'realtime' : 'none',
 394       " time0=0\n";
 395     print_bochs_disk_line ("ata0-master", 0);
 396     print_bochs_disk_line ("ata0-slave", 1);
 397     if (defined ($disks_by_iface[2]{FILE_NAME})
 398         || defined ($disks_by_iface[3]{FILE_NAME})) {
 399         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ",
 400           "ioaddr2=0x370, irq=15\n";
 401         print_bochs_disk_line ("ata1-master", 2);
 402         print_bochs_disk_line ("ata1-slave", 3);
 403     }
 404     if ($vga ne 'terminal') {
 405         print BOCHSRC "com1: enabled=1, mode=file, dev=/dev/stdout\n"
 406           if $serial_out;
 407         print BOCHSRC "display_library: nogui\n" if $vga eq 'none';
 408     } else {
 409         print BOCHSRC "display_library: term\n";
 410     }
 411     close (BOCHSRC);
 412
 413     # Compose Bochs command line.
 414     my (@cmd) = ($bin, '-q');
 415     push (@cmd, '-j', $jitter) if defined $jitter;
 416
 417     # Run Bochs.
 418     print join (' ', @cmd), "\n";
 419     my ($exit) = xsystem (@cmd);
 420     if (WIFEXITED ($exit)) {
 421         # Bochs exited normally.
 422         # Ignore the exit code; Bochs normally exits with status 1,
 423         # which is weird.
 424     } elsif (WIFSIGNALED ($exit)) {
 425         die "Bochs died with signal ", WTERMSIG ($exit), "\n";
 426     } else {
 427         die "Bochs died: code $exit\n";
 428     }
 429 }
 430
 431 # print_bochs_disk_line($device, $iface)
 432 #
 433 # If IDE interface $iface has a disk attached, prints a bochsrc.txt
 434 # line for attaching it to $device.
 435 sub print_bochs_disk_line {
 436     my ($device, $iface) = @_;
 437     my ($disk) = $disks_by_iface[$iface];
 438     my ($file) = $disk->{FILE_NAME};
 439     if (defined $file) {
 440         my (%geom) = disk_geometry ($disk);
 441         print BOCHSRC "$device: type=disk, path=$file, mode=flat, ";
 442         print BOCHSRC "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, ";
 443         print BOCHSRC "translation=none\n";
 444     }
 445 }
 446
 447 # Runs qemu.
 448 sub run_qemu {
 449     print "warning: qemu doesn't support --terminal\n"
 450       if $vga eq 'terminal';
 451     print "warning: qemu doesn't support jitter\n"
 452       if defined $jitter;
 453     my (@cmd) = ('qemu');
 454     for my $iface (0...3) {
 455         my ($option) = ('-hda', '-hdb', '-hdc', '-hdd')[$iface];
 456         push (@cmd, $option, $disks_by_iface[$iface]{FILE_NAME})
 457           if defined $disks_by_iface[$iface]{FILE_NAME};
 458     }
 459     push (@cmd, '-m', $mem);
 460     push (@cmd, '-net', 'none');
 461     push (@cmd, '-nographic') if $vga eq 'none';
 462     push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 463     push (@cmd, '-S') if $debug eq 'monitor';
 464     push (@cmd, '-s', '-S') if $debug eq 'gdb';
 465     push (@cmd, '-monitor', 'null') if $vga eq 'none' && $debug eq 'none';
 466     run_command (@cmd);
 467 }
 468
 469 # gsx_unsup($flag)
 470 #
 471 # Prints a message that $flag is unsupported by GSX Server.
 472 sub gsx_unsup {
 473     my ($flag) = @_;
 474     print "warning: no support for $flag with VMware GSX Server\n";
 475 }
 476
 477 # Runs VMware GSX Server.
 478 sub run_gsx {
 479     gsx_unsup ("--$debug") if $debug ne 'none';
 480     gsx_unsup ("--no-vga") if $vga eq 'none';
 481     gsx_unsup ("--terminal") if $vga eq 'terminal';
 482     gsx_unsup ("--jitter") if defined $jitter;
 483     gsx_unsup ("--kill-on-failure") if defined $kill_on_failure;
 484
 485     unlink ("pintos.out");
 486
 487     open (VMX, ">", "pintos.vmx") or die "pintos.vmx: create: $!\n";
 488     chmod 0777 & ~umask, "pintos.vmx";
 489     print VMX <<EOF;
 490 #! /usr/bin/vmware -G
 491 config.version = 6
 492 guestOS = "linux"
 493 floppy0.present = FALSE
 494 memsize = $mem
 495
 496 serial0.present = TRUE
 497 serial0.fileType = "file"
 498 serial0.fileName = "pintos.out"
 499 EOF
 500
 501     for (my ($i) = 0; $i < 4; $i++) {
 502         my ($disk) = $disks_by_iface[$i];
 503         my ($dsk) = $disk->{FILE_NAME};
 504         next if !defined $dsk;
 505
 506         my ($pln) = $dsk;
 507         $pln =~ s/\.dsk//;
 508         $pln .= ".pln";
 509
 510         my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 511         print VMX <<EOF;
 512
 513 $device.present = TRUE
 514 $device.deviceType = "plainDisk"
 515 $device.fileName = "$pln"
 516 EOF
 517
 518         my (%geom) = disk_geometry ($disk);
 519         open (PLN, ">", $pln) or die "$pln: create: $!\n";
 520         print PLN <<EOF;
 521 DRIVETYPE       ide
 522 #vm|VERSION     2
 523 #vm|TOOLSVERSION        2
 524 CYLINDERS       $geom{C}
 525 HEADS           $geom{H}
 526 SECTORS         $geom{S}
 527 #vm|CAPACITY    $geom{CAPACITY}
 528 ACCESS "$dsk" 0 $geom{CAPACITY}
 529 EOF
 530         close (PLN);
 531     }
 532     close (VMX);
 533
 534     my ($vmx) = getcwd () . "/pintos.vmx";
 535     system ("vmware-cmd -s register $vmx >&/dev/null");
 536     system ("vmware-cmd $vmx stop hard >&/dev/null");
 537     system ("vmware -l -G -x -q $vmx");
 538     system ("vmware-cmd $vmx stop hard >&/dev/null");
 539     system ("vmware-cmd -s unregister $vmx >&/dev/null");
 540 }
 541 \f
 542 # Disk utilities.
 543
 544 # open_disk($disk)
 545 #
 546 # Opens $disk, if it is not already open, and returns its file handle
 547 # and file name.
 548 sub open_disk {
 549     my ($disk) = @_;
 550     if (!defined ($disk->{HANDLE})) {
 551         if ($disk->{FILE_NAME}) {
 552             sysopen ($disk->{HANDLE}, $disk->{FILE_NAME}, O_RDWR)
 553               or die "$disk->{FILE_NAME}: open: $!\n";
 554         } else {
 555             ($disk->{HANDLE}, $disk->{FILE_NAME}) = tempfile (UNLINK => 1,
 556                                                              SUFFIX => '.dsk');
 557         }
 558     }
 559     return ($disk->{HANDLE}, $disk->{FILE_NAME});
 560 }
 561
 562 # open_disk_copy($disk)
 563 #
 564 # Makes a temporary copy of $disk and returns its file handle and file name.
 565 sub open_disk_copy {
 566     my ($disk) = @_;
 567     die if !$disk->{FILE_NAME};
 568
 569     my ($orig_handle, $orig_file_name) = open_disk ($disk);
 570     my ($cp_handle, $cp_file_name) = tempfile (UNLINK => 1, SUFFIX => '.dsk');
 571     copy_file ($orig_handle, $orig_file_name, $cp_handle, $cp_file_name,
 572                -s $orig_handle);
 573     return ($disk->{HANDLE}, $disk->{FILE_NAME}) = ($cp_handle, $cp_file_name);
 574 }
 575
 576 # extend_disk($disk, $size)
 577 #
 578 # Extends $disk, if necessary, so that it is at least $size bytes
 579 # long.
 580 sub extend_disk {
 581     my ($disk, $size) = @_;
 582     my ($handle, $file_name) = open_disk ($disk);
 583     if (-s ($handle) < $size) {
 584         sysseek ($handle, $size - 1, 0) == $size - 1
 585           or die "$file_name: seek: $!\n";
 586         syswrite ($handle, "\0") == 1
 587           or die "$file_name: write: $!\n";
 588     }
 589 }
 590
 591 # disk_geometry($file)
 592 #
 593 # Examines $file and returns a valid IDE disk geometry for it, as a
 594 # hash.
 595 sub disk_geometry {
 596     my ($disk) = @_;
 597     my ($file) = $disk->{FILE_NAME};
 598     my ($size) = -s $file;
 599     die "$file: stat: $!\n" if !defined $size;
 600     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 601     my ($cyl_size) = 512 * 16 * 63;
 602     my ($cylinders) = ceil ($size / $cyl_size);
 603     extend_disk ($disk, $cylinders * $cyl_size) if $size % $cyl_size;
 604
 605     return (CAPACITY => $size / 512,
 606             C => $cylinders,
 607             H => 16,
 608             S => 63);
 609 }
 610
 611 # copy_file($from_handle, $from_file_name, $to_handle, $to_file_name, $size)
 612 #
 613 # Copies $size bytes from $from_handle to $to_handle.
 614 # $from_file_name and $to_file_name are used in error messages.
 615 sub copy_file {
 616     my ($from_handle, $from_file_name, $to_handle, $to_file_name, $size) = @_;
 617
 618     while ($size > 0) {
 619         my ($chunk_size) = 4096;
 620         $chunk_size = $size if $chunk_size > $size;
 621         $size -= $chunk_size;
 622
 623         my ($data) = read_fully ($from_handle, $from_file_name, $chunk_size);
 624         write_fully ($to_handle, $to_file_name, $data);
 625     }
 626 }
 627
 628 # read_fully($handle, $file_name, $bytes)
 629 #
 630 # Reads exactly $bytes bytes from $handle and returns the data read.
 631 # $file_name is used in error messages.
 632 sub read_fully {
 633     my ($handle, $file_name, $bytes) = @_;
 634     my ($data);
 635     my ($read_bytes) = sysread ($handle, $data, $bytes);
 636     die "$file_name: read: $!\n" if !defined $read_bytes;
 637     die "$file_name: unexpected end of file\n" if $read_bytes != $bytes;
 638     return $data;
 639 }
 640
 641 # write_fully($handle, $file_name, $data)
 642 #
 643 # Write $data to $handle.
 644 # $file_name is used in error messages.
 645 sub write_fully {
 646     my ($handle, $file_name, $data) = @_;
 647     my ($written_bytes) = syswrite ($handle, $data);
 648     die "$file_name: write: $!\n" if !defined $written_bytes;
 649     die "$file_name: short write\n" if $written_bytes != length $data;
 650 }
 651 \f
 652 # Subprocess utilities.
 653
 654 # run_command(@args)
 655 #
 656 # Runs xsystem(@args).
 657 # Also prints the command it's running and checks that it succeeded.
 658 sub run_command {
 659     print join (' ', @_), "\n";
 660     die "command failed\n" if xsystem (@_);
 661 }
 662
 663 # xsystem(@args)
 664 #
 665 # Creates a subprocess via exec(@args) and waits for it to complete.
 666 # Relays common signals to the subprocess.
 667 # If $timeout is set then the subprocess will be killed after that long.
 668 sub xsystem {
 669     # qemu turns off local echo and does not restore it if killed by a signal.
 670     # We compensate by restoring it ourselves.
 671     my $cleanup = sub {};
 672     if (isatty (0)) {
 673         my $termios = POSIX::Termios->new;
 674         $termios->getattr (0);
 675         $cleanup = sub { $termios->setattr (0, &POSIX::TCSANOW); }
 676     }
 677
 678     # Create pipe for filtering output.
 679     pipe (my $in, my $out) or die "pipe: $!\n" if $kill_on_failure;
 680
 681     my ($pid) = fork;
 682     if (!defined ($pid)) {
 683         # Fork failed.
 684         die "fork: $!\n";
 685     } elsif (!$pid) {
 686         # Running in child process.
 687         dup2 (fileno ($out), STDOUT_FILENO) or die "dup2: $!\n"
 688           if $kill_on_failure;
 689         exec_setitimer (@_);
 690     } else {
 691         # Running in parent process.
 692         close $out if $kill_on_failure;
 693
 694         my ($cause);
 695         local $SIG{ALRM} = sub { timeout ($pid, $cause, $cleanup); };
 696         local $SIG{INT} = sub { relay_signal ($pid, "INT", $cleanup); };
 697         local $SIG{TERM} = sub { relay_signal ($pid, "TERM", $cleanup); };
 698         alarm ($timeout * get_load_average () + 1) if defined ($timeout);
 699
 700         if ($kill_on_failure) {
 701             # Filter output.
 702             my ($buf) = "";
 703             my ($boots) = 0;
 704             while (waitpid ($pid, WNOHANG) == 0) {
 705                 # Read and print out pipe data.
 706                 my ($len) = length ($buf);
 707                 waitpid ($pid, 0), last
 708                   if sysread ($in, $buf, 4096, $len) <= 0;
 709                 print STDOUT substr ($buf, $len);
 710
 711                 # Remove full lines from $buf and scan them for keywords.
 712                 while ((my $idx = index ($buf, "\n")) >= 0) {
 713                     local $_ = substr ($buf, 0, $idx + 1, '');
 714                     next if defined ($cause);
 715                     if (/(Kernel PANIC|User process ABORT)/ ) {
 716                         $cause = "\L$1\E";
 717                         alarm (5);
 718                     } elsif (/Pintos booting/ && ++$boots > 1) {
 719                         $cause = "triple fault";
 720                         alarm (5);
 721                     } elsif (/FAILED/) {
 722                         $cause = "test failure";
 723                         alarm (5);
 724                     }
 725                 }
 726             }
 727         } else {
 728             waitpid ($pid, 0);
 729         }
 730         alarm (0);
 731         &$cleanup ();
 732
 733         if (WIFSIGNALED ($?) && WTERMSIG ($?) == SIGVTALRM ()) {
 734             seek (STDOUT, 0, 2);
 735             print "\nTIMEOUT after $timeout seconds of host CPU time\n";
 736             exit 0;
 737         }
 738
 739         return $?;
 740     }
 741 }
 742
 743 # relay_signal($pid, $signal, &$cleanup)
 744 #
 745 # Relays $signal to $pid and then reinvokes it for us with the default
 746 # handler.  Also cleans up temporary files and invokes $cleanup.
 747 sub relay_signal {
 748     my ($pid, $signal, $cleanup) = @_;
 749     kill $signal, $pid;
 750     File::Temp::cleanup();
 751     &$cleanup ();
 752     $SIG{$signal} = 'DEFAULT';
 753     kill $signal, getpid ();
 754 }
 755
 756 # timeout($pid, $cause, &$cleanup)
 757 #
 758 # Interrupts $pid and dies with a timeout error message,
 759 # after invoking $cleanup.
 760 sub timeout {
 761     my ($pid, $cause, $cleanup) = @_;
 762     kill "INT", $pid;
 763     waitpid ($pid, 0);
 764     &$cleanup ();
 765     seek (STDOUT, 0, 2);
 766     if (!defined ($cause)) {
 767         my ($load_avg) = `uptime` =~ /(load average:.*)$/i;
 768         print "\nTIMEOUT after ", time () - $start_time,
 769           " seconds of wall-clock time";
 770         print  " - $load_avg" if defined $load_avg;
 771         print "\n";
 772     } else {
 773         print "Simulation terminated due to $cause.\n";
 774     }
 775     exit 0;
 776 }
 777
 778 # Returns the system load average over the last minute.
 779 # If the load average is less than 1.0 or cannot be determined, returns 1.0.
 780 sub get_load_average {
 781     my ($avg) = `uptime` =~ /load average:\s*([^,]+),/;
 782     return $avg >= 1.0 ? $avg : 1.0;
 783 }
 784
 785 # Calls setitimer to set a timeout, then execs what was passed to us.
 786 sub exec_setitimer {
 787     if (defined $timeout) {
 788         if ($\16 ge 5.8.0) {
 789             eval "
 790               use Time::HiRes qw(setitimer ITIMER_VIRTUAL);
 791               setitimer (ITIMER_VIRTUAL, $timeout, 0);
 792             ";
 793         } else {
 794             { exec ("setitimer-helper", $timeout, @_); };
 795             exit 1 if !$!{ENOENT};
 796             print STDERR "warning: setitimer-helper is not installed, so ",
 797               "CPU time limit will not be enforced\n";
 798         }
 799     }
 800     exec (@_);
 801     exit (1);
 802 }
 803
 804 sub SIGVTALRM {
 805     use Config;
 806     my $i = 0;
 807     foreach my $name (split(' ', $Config{sig_name})) {
 808         return $i if $name eq 'VTALRM';
 809         $i++;
 810     }
 811     return 0;
 812 }