pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX;
   5 use Fcntl;
   6 use File::Temp 'tempfile';
   7 use Getopt::Long qw(:config bundling);
   8
   9 # Command-line options.
  10 our ($start_time) = time ();
  11 our ($sim);                     # Simulator: bochs, qemu, or gsx.
  12 our ($debug) = "none";          # Debugger: none, monitor, or gdb.
  13 our ($mem) = 4;                 # Physical RAM in MB.
  14 our ($serial_out) = 1;          # Send output to serial port?
  15 our ($vga);                     # VGA output: window, terminal, or none.
  16 our ($jitter);                  # Seed for random timer interrupts, if set.
  17 our ($realtime);                # Synchronize timer interrupts with real time?
  18 our ($timeout);                 # Maximum runtime in seconds, if set.
  19 our (@puts);                    # Files to copy into the VM.
  20 our (@gets);                    # Files to copy out of the VM.
  21 our ($as_ref);                  # Reference to last addition to @gets or @puts.
  22 our (@kernel_args);             # Arguments to pass to kernel.
  23 our (%disks) = (OS => {DEF_FN => 'os.dsk'},             # Disks to give VM.
  24                 FS => {DEF_FN => 'fs.dsk'},
  25                 SCRATCH => {DEF_FN => 'scratch.dsk'},
  26                 SWAP => {DEF_FN => 'swap.dsk'});
  27 our (@disks_by_iface) = @disks{qw (OS FS SCRATCH SWAP)};
  28
  29 parse_command_line ();
  30 find_disks ();
  31 prepare_scratch_disk ();
  32 prepare_arguments ();
  33 run_vm ();
  34 finish_scratch_disk ();
  35
  36 exit 0;
  37 \f
  38 # Parses the command line.
  39 sub parse_command_line {
  40     usage (0) if @ARGV == 0 || (@ARGV == 1 && $ARGV[0] eq '--help');
  41
  42     @kernel_args = @ARGV;
  43     if (grep ($_ eq '--', @kernel_args)) {
  44         @ARGV = ();
  45         while ((my $arg = shift (@kernel_args)) ne '--') {
  46             push (@ARGV, $arg);
  47         }
  48         GetOptions ("sim=s" => sub { set_sim (@_) },
  49                     "bochs" => sub { set_sim ("bochs") },
  50                     "qemu" => sub { set_sim ("qemu") },
  51                     "gsx" => sub { set_sim ("gsx") },
  52
  53                     "debug=s" => sub { set_debug (@_) },
  54                     "no-debug" => sub { set_debug ("none") },
  55                     "monitor" => sub { set_debug ("monitor") },
  56                     "gdb" => sub { set_debug ("gdb") },
  57
  58                     "m|memory=i" => \$mem,
  59                     "j|jitter=i" => sub { set_jitter (@_) },
  60                     "r|realtime" => sub { set_realtime () },
  61                     "T|timeout=i" => \$timeout,
  62
  63                     "v|no-vga" => sub { set_vga ('none'); },
  64                     "s|no-serial" => sub { $serial_out = 0; },
  65                     "t|terminal" => sub { set_vga ('terminal'); },
  66
  67                     "p|put-file=s" => sub { add_file (\@puts, $_[1]); },
  68                     "g|get-file=s" => sub { add_file (\@gets, $_[1]); },
  69                     "a|as=s" => sub { set_as ($_[1]); },
  70
  71                     "h|help" => sub { usage (0); },
  72
  73                     "os-disk=s" => \$disks{OS}{FILENAME},
  74                     "fs-disk=s" => \$disks{FS}{FILENAME},
  75                     "scratch-disk=s" => \$disks{SCRATCH}{FILENAME},
  76                     "swap-disk=s" => \$disks{SWAP}{FILENAME},
  77
  78                     "0|disk-0|hda=s" => \$disks_by_iface[0]{FILENAME},
  79                     "1|disk-1|hdb=s" => \$disks_by_iface[1]{FILENAME},
  80                     "2|disk-2|hdc=s" => \$disks_by_iface[2]{FILENAME},
  81                     "3|disk-3|hdd=s" => \$disks_by_iface[3]{FILENAME})
  82           or exit 1;
  83     }
  84
  85     $sim = "bochs" if !defined $sim;
  86     $debug = "none" if !defined $debug;
  87     $vga = "window" if !defined $vga;
  88 }
  89
  90 # usage($exitcode).
  91 # Prints a usage message and exits with $exitcode.
  92 sub usage {
  93     my ($exitcode) = @_;
  94     $exitcode = 1 unless defined $exitcode;
  95     print <<'EOF';
  96 pintos, a utility for running Pintos in a simulator
  97 Usage: pintos [OPTION...] -- [ARGUMENT...]
  98 where each OPTION is one of the following options
  99   and each ARGUMENT is passed to Pintos kernel verbatim.
 100 Simulator selection:
 101   --bochs                  (default) Use Bochs as simulator
 102   --qemu                   Use qemu as simulator
 103   --gsx                    Use VMware GSX Server 3.x as simulator
 104 Debugger selection:
 105   --no-debug               (default) No debugger
 106   --monitor                Debug with simulator's monitor
 107   --gdb                    Debug with gdb
 108 Display options: (default is both VGA and serial)
 109   -v, --no-vga             No VGA display
 110   -s, --no-serial          No serial output
 111   -t, --terminal           Display VGA in terminal (Bochs only)
 112 Timing options: (Bochs only)
 113   -j SEED                  Randomize timer interrupts
 114   -r, --realtime           Use realistic, not reproducible, timings
 115   -T, --timeout=N          Kill Pintos after N seconds CPU time or N*load_avg
 116                            seconds wall-clock time (whichever comes first)
 117 Configuration options:
 118   -m, --mem=N              Give Pintos N MB physical RAM (default: 4)
 119 File system commands (for `run' command):
 120   -p, --put-file=HOSTFN    Copy HOSTFN into VM, by default under same name
 121   -g, --get-file=GUESTFN   Copy GUESTFN out of VM, by default under same name
 122   -a, --as=FILENAME        Specifies guest (for -p) or host (for -g) file name
 123 Disk options: (name an existing FILE or specify SIZE in MB for a temp disk)
 124   --os-disk=FILE           Set OS disk file (default: os.dsk)
 125   --fs-disk=FILE|SIZE      Set FS disk file (default: fs.dsk)
 126   --scratch-disk=FILE|SIZE Set scratch disk (default: scratch.dsk)
 127   --swap-disk=FILE|SIZE    Set swap disk file (default: swap.dsk)
 128 Other options:
 129   -h, --help               Display this help message.
 130 EOF
 131     exit $exitcode;
 132 }
 133
 134 # Sets the simulator.
 135 sub set_sim {
 136     my ($new_sim) = @_;
 137     die "--$new_sim conflicts with --$sim\n"
 138         if defined ($sim) && $sim ne $new_sim;
 139     $sim = $new_sim;
 140 }
 141
 142 # Sets the debugger.
 143 sub set_debug {
 144     my ($new_debug) = @_;
 145     die "--$new_debug conflicts with --$debug\n"
 146         if $debug ne 'none' && $new_debug ne 'none' && $debug ne $new_debug;
 147     $debug = $new_debug;
 148 }
 149
 150 # Sets VGA output destination.
 151 sub set_vga {
 152     my ($new_vga) = @_;
 153     if (defined ($vga) && $vga ne $new_vga) {
 154         print "warning: conflicting vga display options\n";
 155     }
 156     $vga = $new_vga;
 157 }
 158
 159 # Sets randomized timer interrupts.
 160 sub set_jitter {
 161     my ($new_jitter) = @_;
 162     die "--realtime conflicts with --jitter\n" if defined $realtime;
 163     die "different --jitter already defined\n"
 164         if defined $jitter && $jitter != $new_jitter;
 165     $jitter = $new_jitter;
 166 }
 167
 168 # Sets real-time timer interrupts.
 169 sub set_realtime {
 170     die "--realtime conflicts with --jitter\n" if defined $jitter;
 171     $realtime = 1;
 172 }
 173
 174 # add_file(\@list, $file)
 175 #
 176 # Adds [$file] to @list, which should be @puts or @gets.
 177 # Sets $as_ref to point to the added element.
 178 sub add_file {
 179     my ($list, $file) = @_;
 180     $as_ref = [$file];
 181     push (@$list, $as_ref);
 182 }
 183
 184 # Sets the guest/host name for the previous put/get.
 185 sub set_as {
 186     my ($as) = @_;
 187     die "-a (or --as) is only allowed after -p or -g\n" if !defined $as_ref;
 188     die "Only one -a (or --as) is allowed after -p or -g\n"
 189       if defined $as_ref->[1];
 190     $as_ref->[1] = $as;
 191 }
 192 \f
 193 # Locates the files used to back each of the virtual disks,
 194 # and creates temporary disks.
 195 sub find_disks {
 196     for my $disk (values %disks) {
 197         # If there's no assigned file name but the default file exists,
 198         # try to assign a default file name.
 199         if (!defined ($disk->{FILENAME})) {
 200             for my $try_fn ($disk->{DEF_FN}, "build/" . $disk->{DEF_FN}) {
 201                 $disk->{FILENAME} = $try_fn, last
 202                   if -e $try_fn;
 203             }
 204         }
 205
 206         # If there's no file name, we're done.
 207         next if !defined ($disk->{FILENAME});
 208
 209         if ($disk->{FILENAME} =~ /^\d+(\.\d+)?|\.\d+$/) {
 210             # Create a temporary disk of approximately the specified
 211             # size in megabytes.
 212             die "OS disk can't be temporary\n" if $disk == $disks{OS};
 213
 214             my ($mb) = $disk->{FILENAME};
 215             undef $disk->{FILENAME};
 216
 217             my ($cyl_size) = 512 * 16 * 63;
 218             extend_disk ($disk, ceil ($mb * 2) * $cyl_size);
 219         } else {
 220             # The file must exist and have nonzero size.
 221             -e $disk->{FILENAME} or die "$disk->{FILENAME}: stat: $!\n";
 222             -s _ or die "$disk->{FILENAME}: disk has zero size\n";
 223         }
 224     }
 225
 226     # Warn about (potentially) missing disks.
 227     die "Cannot find OS disk\n" if !defined $disks{OS}{FILENAME};
 228     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 229         if ((grep ($project eq $_, qw (userprog vm filesys)))
 230             && !defined ($disks{FS}{FILENAME})) {
 231             print STDERR "warning: it looks like you're running the $project ";
 232             print STDERR "project, but no file system disk is present\n";
 233         }
 234         if ($project eq 'vm' && !defined $disks{SWAP}{FILENAME}) {
 235             print STDERR "warning: it looks like you're running the $project ";
 236             print STDERR "project, but no swap disk is present\n";
 237         }
 238     }
 239 }
 240 \f
 241 # Prepare the scratch disk for gets and puts.
 242 sub prepare_scratch_disk {
 243     # Copy the files to put onto the scratch disk.
 244     put_scratch_file ($_->[0]) foreach @puts;
 245
 246     # Make sure the scratch disk is big enough to get big files.
 247     extend_disk ($disks{SCRATCH}, @gets * 1024 * 1024) if @gets;
 248 }
 249
 250 # Read "get" files from the scratch disk.
 251 sub finish_scratch_disk {
 252     # We need to start reading the scratch disk from the beginning again.
 253     if (@gets) {
 254         close ($disks{SCRATCH}{HANDLE});
 255         undef ($disks{SCRATCH}{HANDLE});
 256     }
 257
 258     # Read each file.
 259     get_scratch_file (defined ($_->[1]) ? $_->[1] : $_->[0]) foreach @gets;
 260 }
 261
 262 # put_scratch_file($file).
 263 #
 264 # Copies $file into the scratch disk.
 265 sub put_scratch_file {
 266     my ($put_filename) = @_;
 267     my ($disk_handle, $disk_filename) = open_disk ($disks{SCRATCH});
 268
 269     print "Copying $put_filename into $disk_filename...\n";
 270
 271     # Write metadata sector, which consists of a 4-byte signature
 272     # followed by the file size.
 273     stat $put_filename or die "$put_filename: stat: $!\n";
 274     my ($size) = -s _;
 275     my ($metadata) = pack ("a4 V x504", "PUT\0", $size);
 276     write_fully ($disk_handle, $disk_filename, $metadata);
 277
 278     # Copy file data.
 279     my ($put_handle);
 280     sysopen ($put_handle, $put_filename, O_RDONLY)
 281       or die "$put_filename: open: $!\n";
 282     copy_file ($put_handle, $put_filename, $disk_handle, $disk_filename,
 283                $size);
 284     close ($put_handle);
 285
 286     # Round up disk data to beginning of next sector.
 287     write_fully ($disk_handle, $disk_filename, "\0" x (512 - $size % 512))
 288       if $size % 512;
 289 }
 290
 291 # get_scratch_file($file).
 292 #
 293 # Copies from the scratch disk to $file.
 294 sub get_scratch_file {
 295     my ($get_filename) = @_;
 296     my ($disk_handle, $disk_filename) = open_disk ($disks{SCRATCH});
 297
 298     print "Copying $get_filename out of $disk_filename...\n";
 299
 300     # Read metadata sector, which has a 4-byte signature followed by
 301     # the file size.
 302     my ($metadata) = read_fully ($disk_handle, $disk_filename, 512);
 303     my ($signature, $size) = unpack ("a4 V", $metadata);
 304     die "bad signature reading scratch disk--did Pintos run correctly?\n"
 305       if $signature ne "GET\0";
 306
 307     # Copy file data.
 308     my ($get_handle);
 309     sysopen ($get_handle, $get_filename, O_WRONLY | O_CREAT | O_EXCL, 0666)
 310       or die "$get_filename: create: $!\n";
 311     copy_file ($disk_handle, $disk_filename, $get_handle, $get_filename,
 312                $size);
 313     close ($get_handle);
 314
 315     # Skip forward in disk up to beginning of next sector.
 316     read_fully ($disk_handle, $disk_filename, 512 - $size % 512)
 317       if $size % 512;
 318 }
 319 \f
 320 # Prepares the arguments to pass to the Pintos kernel,
 321 # and then write them into Pintos bootloader.
 322 sub prepare_arguments {
 323     my (@args);
 324     push (@args, shift (@kernel_args))
 325       while @kernel_args && $kernel_args[0] =~ /^-/;
 326     push (@args, 'put', defined $_->[1] ? $_->[1] : $_->[0]) foreach @puts;
 327     push (@args, @kernel_args);
 328     push (@args, 'get', $_->[0]) foreach @gets;
 329     write_cmd_line ($disks{OS}, @args);
 330 }
 331
 332 # Writes @args into the Pintos bootloader at the beginning of $disk.
 333 sub write_cmd_line {
 334     my ($disk, @args) = @_;
 335
 336     # Figure out command line to write.
 337     my ($arg_cnt) = pack ("V", scalar (@args));
 338     my ($args) = join ('', map ("$_\0", @args));
 339     die "command line exceeds 128 bytes" if length ($args) > 128;
 340     $args .= "\0" x (128 - length ($args));
 341
 342     # Write command line.
 343     my ($handle, $filename) = open_disk_copy ($disk);
 344     print "Writing command line to $filename...\n";
 345     sysseek ($handle, 0x17a, 0) == 0x17a or die "$filename: seek: $!\n";
 346     syswrite ($handle, "$arg_cnt$args") or die "$filename: write: $!\n";
 347 }
 348 \f
 349 # Running simulators.
 350
 351 # Runs the selected simulator.
 352 sub run_vm {
 353     if ($sim eq 'bochs') {
 354         run_bochs ();
 355     } elsif ($sim eq 'qemu') {
 356         run_qemu ();
 357     } elsif ($sim eq 'gsx') {
 358         run_gsx ();
 359     } else {
 360         die "unknown simulator `$sim'\n";
 361     }
 362 }
 363
 364 # Runs Bochs.
 365 sub run_bochs {
 366     # Select Bochs binary based on the chosen debugger.
 367     my ($bin) = $debug eq 'monitor' ? 'bochs-dbg' : 'bochs';
 368
 369     # Write bochsrc.txt configuration file.
 370     open (BOCHSRC, ">", "bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 371     print BOCHSRC <<EOF;
 372 romimage: file=\$BXSHARE/BIOS-bochs-latest, address=0xf0000
 373 vgaromimage: file=\$BXSHARE/VGABIOS-lgpl-latest
 374 boot: disk
 375 cpu: ips=1000000
 376 megs: $mem
 377 log: bochsout.txt
 378 panic: action=fatal
 379 EOF
 380     print BOCHSRC "gdbstub: enabled=1\n" if $debug eq 'gdb';
 381     print BOCHSRC "clock: sync=", $realtime ? 'realtime' : 'none', "time0=0\n";
 382     print_bochs_disk_line ("ata0-master", 0);
 383     print_bochs_disk_line ("ata0-slave", 1);
 384     if (defined ($disks_by_iface[2]{FILENAME})
 385         || defined ($disks_by_iface[3]{FILENAME})) {
 386         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ",
 387           "ioaddr2=0x370, irq=15\n";
 388         print_bochs_disk_line ("ata1-master", 2);
 389         print_bochs_disk_line ("ata1-slave", 3);
 390     }
 391     if ($vga ne 'terminal') {
 392         print BOCHSRC "com1: enabled=1, mode=file, dev=/dev/stdout\n"
 393           if $serial_out;
 394         print BOCHSRC "display_library: nogui\n" if $vga eq 'none';
 395     } else {
 396         print BOCHSRC "display_library: term\n";
 397     }
 398     close (BOCHSRC);
 399
 400     # Compose Bochs command line.
 401     my (@cmd) = ($bin, '-q');
 402     push (@cmd, '-j', $jitter) if defined $jitter;
 403
 404     # Run Bochs.
 405     print join (' ', @cmd), "\n";
 406     my ($exit) = xsystem (@cmd);
 407     if (WIFEXITED ($exit)) {
 408         # Bochs exited normally.
 409         # Ignore the exit code; Bochs normally exits with status 1,
 410         # which is weird.
 411     } elsif (WIFSIGNALED ($exit)) {
 412         die "Bochs died with signal ", WTERMSIG ($exit), "\n";
 413     } else {
 414         die "Bochs died: code $exit\n";
 415     }
 416 }
 417
 418 # print_bochs_disk_line($device, $iface)
 419 #
 420 # If IDE interface $iface has a disk attached, prints a bochsrc.txt
 421 # line for attaching it to $device.
 422 sub print_bochs_disk_line {
 423     my ($device, $iface) = @_;
 424     my ($disk) = $disks_by_iface[$iface];
 425     my ($file) = $disk->{FILENAME};
 426     if (defined $file) {
 427         my (%geom) = disk_geometry ($disk);
 428         print BOCHSRC "$device: type=disk, path=$file, mode=flat, ";
 429         print BOCHSRC "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, ";
 430         print BOCHSRC "translation=none\n";
 431     }
 432 }
 433
 434 # Runs qemu.
 435 sub run_qemu {
 436     print "warning: qemu doesn't support --terminal\n"
 437       if $vga eq 'terminal';
 438     print "warning: qemu doesn't support jitter\n"
 439       if defined $jitter;
 440     my (@cmd) = ('qemu');
 441     for my $iface (0...3) {
 442         my ($option) = ('-hda', '-hdb', '-hdc', '-hdd')[$iface];
 443         push (@cmd, $option, $disks_by_iface[$iface]{FILENAME})
 444           if defined $disks_by_iface[$iface]{FILENAME};
 445     }
 446     push (@cmd, '-m', $mem, '-nics', '0');
 447     push (@cmd, '-nographic') if $vga eq 'none';
 448     push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 449     push (@cmd, '-S') if $debug eq 'monitor';
 450     push (@cmd, '-s', '-S') if $debug eq 'gdb';
 451     push (@cmd, '-monitor', 'null') if $vga eq 'none' && $debug eq 'none';
 452     run_command (@cmd);
 453 }
 454
 455 # gsx_unsup($flag)
 456 #
 457 # Prints a message that $flag is unsupported by GSX Server.
 458 sub gsx_unsup {
 459     my ($flag) = @_;
 460     print "warning: no support for $flag with VMware GSX Server\n";
 461 }
 462
 463 # Runs VMware GSX Server.
 464 sub run_gsx {
 465     gsx_unsup ("--$debug") if $debug ne 'none';
 466     gsx_unsup ("--no-vga") if $vga eq 'none';
 467     gsx_unsup ("--terminal") if $vga eq 'terminal';
 468     gsx_unsup ("--jitter") if defined $jitter;
 469
 470     unlink ("pintos.out");
 471
 472     open (VMX, ">", "pintos.vmx") or die "pintos.vmx: create: $!\n";
 473     chmod 0777 & ~umask, "pintos.vmx";
 474     print VMX <<EOF;
 475 #! /usr/bin/vmware -G
 476 config.version = 6
 477 guestOS = "linux"
 478 floppy0.present = FALSE
 479 memsize = $mem
 480
 481 serial0.present = TRUE
 482 serial0.fileType = "file"
 483 serial0.fileName = "pintos.out"
 484 EOF
 485
 486     for (my ($i) = 0; $i < 4; $i++) {
 487         my ($disk) = $disks_by_iface[$i];
 488         my ($dsk) = $disk->{FILENAME};
 489         next if !defined $dsk;
 490
 491         my ($pln) = $dsk;
 492         $pln =~ s/\.dsk//;
 493         $pln .= ".pln";
 494
 495         my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 496         print VMX <<EOF;
 497
 498 $device.present = TRUE
 499 $device.deviceType = "plainDisk"
 500 $device.fileName = "$pln"
 501 EOF
 502
 503         my (%geom) = disk_geometry ($disk);
 504         open (PLN, ">", $pln) or die "$pln: create: $!\n";
 505         print PLN <<EOF;
 506 DRIVETYPE       ide
 507 #vm|VERSION     2
 508 #vm|TOOLSVERSION        2
 509 CYLINDERS       $geom{C}
 510 HEADS           $geom{H}
 511 SECTORS         $geom{S}
 512 #vm|CAPACITY    $geom{CAPACITY}
 513 ACCESS "$dsk" 0 $geom{CAPACITY}
 514 EOF
 515         close (PLN);
 516     }
 517     close (VMX);
 518
 519     my ($vmx) = getcwd () . "/pintos.vmx";
 520     system ("vmware-cmd -s register $vmx >&/dev/null");
 521     system ("vmware-cmd $vmx stop hard >&/dev/null");
 522     system ("vmware -l -G -x -q $vmx");
 523     system ("vmware-cmd $vmx stop hard >&/dev/null");
 524     system ("vmware-cmd -s unregister $vmx >&/dev/null");
 525 }
 526 \f
 527 # Disk utilities.
 528
 529 # open_disk($disk)
 530 #
 531 # Opens $disk, if it is not already open, and returns its file handle
 532 # and file name.
 533 sub open_disk {
 534     my ($disk) = @_;
 535     if (!defined ($disk->{HANDLE})) {
 536         if ($disk->{FILENAME}) {
 537             sysopen ($disk->{HANDLE}, $disk->{FILENAME}, O_RDWR)
 538               or die "$disk->{FILENAME}: open: $!\n";
 539         } else {
 540             ($disk->{HANDLE}, $disk->{FILENAME}) = tempfile (UNLINK => 1,
 541                                                              SUFFIX => '.dsk');
 542         }
 543     }
 544     return ($disk->{HANDLE}, $disk->{FILENAME});
 545 }
 546
 547 # open_disk_copy($disk)
 548 #
 549 # Makes a temporary copy of $disk and returns its file handle and file name.
 550 sub open_disk_copy {
 551     my ($disk) = @_;
 552     die if !$disk->{FILENAME};
 553
 554     my ($orig_handle, $orig_filename) = open_disk ($disk);
 555     my ($cp_handle, $cp_filename) = tempfile (UNLINK => 1, SUFFIX => '.dsk');
 556     copy_file ($orig_handle, $orig_filename, $cp_handle, $cp_filename,
 557                -s $orig_handle);
 558     return ($disk->{HANDLE}, $disk->{FILENAME}) = ($cp_handle, $cp_filename);
 559 }
 560
 561 # extend_disk($disk, $size)
 562 #
 563 # Extends $disk, if necessary, so that it is at least $size bytes
 564 # long.
 565 sub extend_disk {
 566     my ($disk, $size) = @_;
 567     my ($handle, $filename) = open_disk ($disk);
 568     if (-s ($handle) < $size) {
 569         sysseek ($handle, $size - 1, 0) == $size - 1
 570           or die "$filename: seek: $!\n";
 571         syswrite ($handle, "\0") == 1
 572           or die "$filename: write: $!\n";
 573     }
 574 }
 575
 576 # disk_geometry($file)
 577 #
 578 # Examines $file and returns a valid IDE disk geometry for it, as a
 579 # hash.
 580 sub disk_geometry {
 581     my ($disk) = @_;
 582     my ($file) = $disk->{FILENAME};
 583     my ($size) = -s $file;
 584     die "$file: stat: $!\n" if !defined $size;
 585     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 586     my ($cyl_size) = 512 * 16 * 63;
 587     my ($cylinders) = ceil ($size / $cyl_size);
 588     extend_disk ($disk, $cylinders * $cyl_size) if $size % $cyl_size;
 589
 590     return (CAPACITY => $size / 512,
 591             C => $cylinders,
 592             H => 16,
 593             S => 63);
 594 }
 595
 596 # copy_file($from_handle, $from_filename, $to_handle, $to_filename, $size)
 597 #
 598 # Copies $size bytes from $from_handle to $to_handle.
 599 # $from_filename and $to_filename are used in error messages.
 600 sub copy_file {
 601     my ($from_handle, $from_filename, $to_handle, $to_filename, $size) = @_;
 602
 603     while ($size > 0) {
 604         my ($chunk_size) = 4096;
 605         $chunk_size = $size if $chunk_size > $size;
 606         $size -= $chunk_size;
 607
 608         my ($data) = read_fully ($from_handle, $from_filename, $chunk_size);
 609         write_fully ($to_handle, $to_filename, $data);
 610     }
 611 }
 612
 613 # read_fully($handle, $filename, $bytes)
 614 #
 615 # Reads exactly $bytes bytes from $handle and returns the data read.
 616 # $filename is used in error messages.
 617 sub read_fully {
 618     my ($handle, $filename, $bytes) = @_;
 619     my ($data);
 620     my ($read_bytes) = sysread ($handle, $data, $bytes);
 621     die "$filename: read: $!\n" if !defined $read_bytes;
 622     die "$filename: unexpected end of file\n" if $read_bytes != $bytes;
 623     return $data;
 624 }
 625
 626 # write_fully($handle, $filename, $data)
 627 #
 628 # Write $data to $handle.
 629 # $filename is used in error messages.
 630 sub write_fully {
 631     my ($handle, $filename, $data) = @_;
 632     my ($written_bytes) = syswrite ($handle, $data);
 633     die "$filename: write: $!\n" if !defined $written_bytes;
 634     die "$filename: short write\n" if $written_bytes != length $data;
 635 }
 636 \f
 637 # Subprocess utilities.
 638
 639 # run_command(@args)
 640 #
 641 # Runs xsystem(@args).
 642 # Also prints the command it's running and checks that it succeeded.
 643 sub run_command {
 644     print join (' ', @_), "\n";
 645     die "command failed\n" if xsystem (@_);
 646 }
 647
 648 # xsystem(@args)
 649 #
 650 # Creates a subprocess via exec(@args) and waits for it to complete.
 651 # Relays common signals to the subprocess.
 652 # If $timeout is set then the subprocess will be killed after that long.
 653 sub xsystem {
 654     my ($pid) = fork;
 655     if (!defined ($pid)) {
 656         # Fork failed.
 657         die "fork: $!\n";
 658     } elsif (!$pid) {
 659         # Running in child process.
 660         exec_setitimer (@_);
 661     } else {
 662         # Running in parent process.
 663         local $SIG{ALRM} = sub { timeout ($pid); };
 664         local $SIG{INT} = sub { relay_signal ($pid, "INT"); };
 665         local $SIG{TERM} = sub { relay_signal ($pid, "TERM"); };
 666         alarm ($timeout * get_load_average () + 1) if defined ($timeout);
 667         waitpid ($pid, 0);
 668         alarm (0);
 669
 670         if (WIFSIGNALED ($?) && WTERMSIG ($?) == SIGVTALRM ()) {
 671             seek (STDOUT, 0, 2);
 672             print "\nTIMEOUT after $timeout seconds of host CPU time\n";
 673             exit 0;
 674         }
 675
 676         return $?;
 677     }
 678 }
 679
 680 # relay_signal($pid, $signal)
 681 #
 682 # Relays $signal to $pid and then reinvokes it for us with the default
 683 # handler.  Also cleans up temporary files.
 684 sub relay_signal {
 685     my ($pid, $signal) = @_;
 686     kill $signal, $pid;
 687     File::Temp::cleanup();
 688     $SIG{$signal} = 'DEFAULT';
 689     kill $signal, getpid ();
 690 }
 691
 692 # timeout($pid)
 693 #
 694 # Interrupts $pid and dies with a timeout error message.
 695 sub timeout {
 696     my ($pid) = @_;
 697     kill "INT", $pid;
 698     waitpid ($pid, 0);
 699     seek (STDOUT, 0, 2);
 700     my ($load_avg) = `uptime` =~ /(load average:.*)$/i;
 701     print "\nTIMEOUT after ", time () - $start_time,
 702       " seconds of wall-clock time";
 703     print  " - $load_avg" if defined $load_avg;
 704     print "\n";
 705     exit 0;
 706 }
 707
 708 # Returns the system load average over the last minute.
 709 # If the load average is less than 1.0 or cannot be determined, returns 1.0.
 710 sub get_load_average {
 711     my ($avg) = `uptime` =~ /load average:\s*([^,]+),/;
 712     return $avg >= 1.0 ? $avg : 1.0;
 713 }
 714
 715 # Calls setitimer to set a timeout, then execs what was passed to us.
 716 sub exec_setitimer {
 717     if (defined $timeout) {
 718         if ($\16 ge 5.8.0) {
 719             eval "
 720               use Time::HiRes qw(setitimer ITIMER_VIRTUAL);
 721               setitimer (ITIMER_VIRTUAL, $timeout, 0);
 722             ";
 723         } else {
 724             { exec ("setitimer-helper", $timeout, @_); };
 725             exit 1 if !$!{ENOENT};
 726             print STDERR "warning: setitimer-helper is not installed, so ",
 727               "CPU time limit will not be enforced\n";
 728         }
 729     }
 730     exec (@_);
 731     exit (1);
 732 }
 733
 734 sub SIGVTALRM {
 735     use Config;
 736     my $i = 0;
 737     foreach my $name (split(' ', $Config{sig_name})) {
 738         return $i if $name eq 'VTALRM';
 739         $i++;
 740     }
 741     return 0;
 742 }