pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4
   5 our ($mem) = 4;
   6 our ($serial_out) = 1;
   7 our (@disks) = ("os.dsk", "fs.dsk", "scratch.dsk", "swap.dsk");
   8 our ($sim);
   9 our ($debug);
  10 our ($vga);
  11 our ($jitter, $realtime);
  12
  13 use Getopt::Long qw(:config require_order bundling);
  14 GetOptions ("sim=s" => sub { set_sim (@_) },
  15             "bochs" => sub { set_sim ("bochs") },
  16             "qemu" => sub { set_sim ("qemu") },
  17             "gsx" => sub { set_sim ("gsx") },
  18
  19             "debug=s" => sub { set_debug (@_) },
  20             "no-debug" => sub { set_debug ("no-debug") },
  21             "monitor" => sub { set_debug ("monitor") },
  22             "gdb" => sub { set_debug ("gdb") },
  23
  24             "run|get|put|make-disk" => \&cmd_option,
  25
  26             "m|memory=i" => \$mem,
  27             "j|jitter=i" => sub { set_jitter (@_) },
  28             "r|realtime" => sub { set_realtime () },
  29
  30             "v|no-vga" => sub { set_vga ('none'); },
  31             "s|no-serial" => sub { $serial_out = 0; },
  32             "t|terminal" => sub { set_vga ('terminal'); },
  33
  34             "h|help" => sub { usage (0); },
  35
  36             "0|os-disk|disk-0|hda=s" => \$disks[0],
  37             "1|fs-disk|disk-1|hdb=s" => \$disks[1],
  38             "2|scratch-disk|disk-2|hdc=s" => \$disks[2],
  39             "3|swap-disk|disk-3|hdd=s" => \$disks[3])
  40     or exit 1;
  41
  42 $sim = "bochs" if !defined $sim;
  43 $debug = "no-debug" if !defined $debug;
  44 $vga = "window" if !defined $vga;
  45
  46 sub set_sim {
  47     my ($new_sim) = @_;
  48     die "--$new_sim conflicts with --$sim\n"
  49         if defined ($sim) && $sim ne $new_sim;
  50     $sim = $new_sim;
  51 }
  52
  53 sub set_debug {
  54     my ($new_debug) = @_;
  55     die "--$new_debug conflicts with --$debug\n"
  56         if defined ($debug) && $debug ne $new_debug;
  57     $debug = $new_debug;
  58 }
  59
  60 sub set_vga {
  61     my ($new_vga) = @_;
  62     if (defined ($vga) && $vga ne $new_vga) {
  63         print "warning: conflicting vga display options\n";
  64     }
  65     $vga = $new_vga;
  66 }
  67
  68 sub set_jitter {
  69     my ($new_jitter) = @_;
  70     die "--realtime conflicts with --jitter\n" if defined $realtime;
  71     die "different --jitter already defined\n"
  72         if defined $jitter && $jitter != $new_jitter;
  73     $jitter = $new_jitter;
  74 }
  75
  76 sub set_realtime {
  77     die "--realtime conflicts with --jitter\n" if defined $jitter;
  78     $realtime = 1;
  79 }
  80
  81 sub cmd_option {
  82     # Force an end to option processing, as with --.
  83     die ("!FINISH");
  84 }
  85
  86 die "no command specified; use --help for help\n"
  87     if @ARGV < 1;
  88 my ($cmd) = shift @ARGV;
  89 if ($cmd eq 'run') {
  90     run_vm ('EXEC', @ARGV);
  91 } elsif ($cmd eq 'make-disk') {
  92     usage () if @ARGV != 2;
  93     my ($file, $mb) = @ARGV;
  94     usage () if $mb !~ /^\d+(\.\d+)?|\.\d+$/;
  95     die "$file: already exists\n" if -e $file;
  96
  97     create_disk ($file, int ($mb * 1008));
  98 } elsif ($cmd eq 'put') {
  99     # Take a -f option to combine formatting with putting.
 100     my ($format) = 0;
 101     if (@ARGV > 0 && $ARGV[0] eq '-f') {
 102         shift @ARGV;
 103         $format = 1;
 104     }
 105
 106     usage () if @ARGV != 1 && @ARGV != 2;
 107     my ($hostfn, $guestfn) = @ARGV;
 108     $guestfn = $hostfn if !defined $guestfn;
 109
 110     # Create scratch disk from file.
 111     die "$hostfn: $!\n" if ! -e $hostfn;
 112     my ($size) = -s _;
 113     if ($size) {
 114         copy_pad ($hostfn, "scratch.dsk", 512);
 115     } else {
 116         open (SCRATCH, ">scratch.dsk") or die "scratch.dsk: create: $!\n";
 117         syswrite (SCRATCH, "\0" x 512);
 118         close (SCRATCH);
 119     }
 120
 121     # Do copy.
 122     my (@cmd) = ("-ci", $guestfn, $size, "-q");
 123     unshift (@cmd, "-f") if $format;
 124     run_vm ('EXEC', @cmd);
 125 } elsif ($cmd eq 'get') {
 126     usage () if @ARGV != 1 && @ARGV != 2;
 127     my ($guestfn, $hostfn) = @ARGV;
 128     $hostfn = $guestfn if !defined $hostfn;
 129     die "$hostfn: already exists\n" if -e $hostfn;
 130
 131     # Create scratch disk big enough for any file in the filesystem
 132     # (modulo sparse files).
 133     die "$disks[1]: $!\n" if ! -e $disks[1];
 134     my ($fs_size) = -s _;
 135     my ($scratch_size) = -s $disks[2];
 136     $scratch_size = 0 if !defined $scratch_size;
 137     create_disk ($disks[2], $fs_size / 1024 + 16)
 138         if $scratch_size < $fs_size + 16384;
 139
 140     # Do copy.
 141     run_vm ('FORK', "-co", $guestfn, "-q");
 142
 143     # Read out scratch disk.
 144     print "copying $guestfn from $disks[2] to $hostfn...\n";
 145     open (SRC, "<$disks[2]") or die "$disks[2]: open: $!\n";
 146     open (DST, ">$hostfn") or die "$hostfn: create: $!\n";
 147     my ($input);
 148     read (SRC, $input, 512) == 512 or die "$disks[2]: read error\n";
 149     my ($size) = unpack ("V", $input);
 150     $size != 0xffffffff or die "$guestfn: too big for $disks[2]?";
 151     my ($src);
 152     read (SRC, $src, $size) == $size or die "$disks[2]: read error\n";
 153     print DST $src or die "$hostfn: write error\n";
 154     close (DST);
 155     close (SRC);
 156 } elsif ($cmd eq 'help') {
 157     usage (0);
 158 } else {
 159     die "unknown command `$cmd'; use --help for help\n";
 160 }
 161 exit 0;
 162
 163 sub usage {
 164     my ($exitcode) = @_;
 165     $exitcode = 1 unless defined $exitcode;
 166     print "pintos, a utility for invoking Pintos in a simulator\n";
 167     print "Usage: pintos [OPTION...] COMMAND [ARG...]\n";
 168     print "where COMMAND is one of the following:\n";
 169     print "  run [CMDLINE...]        run a VM in the simulator\n";
 170     print "  make-disk FILE.DSK SIZE create FILE.DSK as empty SIZE MB disk\n";
 171     print "  put HOSTFN [GUESTFN]    copy HOSTFN into VM (as GUESTFN)\n";
 172     print "  get GUESTFN [HOSTFN]    copy GUESTFN out of VM (to HOSTFN)\n";
 173     print "  help                    print this help message and exit\n";
 174     print "Simulator options:\n";
 175     print "  --bochs          (default) Use Bochs as simulator\n";
 176     print "  --qemu           Use qemu as simulator\n";
 177     print "  --gsx            Use VMware GSX Server 3.x as simulator\n";
 178     print "Debugger options:\n";
 179     print "  --no-debug       (default) No debugger\n";
 180     print "  --monitor        Debug with simulator's monitor\n";
 181     print "  --gdb            Debug with gdb\n";
 182     print "Display options: (default is VGA + serial)\n";
 183     print "  -v, --no-vga     No VGA display\n";
 184     print "  -s, --no-serial  No serial output\n";
 185     print "  -t, --terminal   Display VGA in terminal (Bochs only)\n";
 186     print "VM options:\n";
 187     print "  -j SEED          Randomize timer interrupts (Bochs only)\n";
 188     print "  -r, --realtime   Use realistic, but not reproducible, timings\n";
 189     print "  -m, --mem=MB     Run VM with MB megabytes of physical memory\n";
 190     print "Disk options:\n";
 191     print "  --os-disk=DISK    Set OS disk file (default: os.dsk)\n";
 192     print "  --fs-disk=DISK    Set FS disk file (default: fs.dsk)\n";
 193     print "  --scratch-disk=DISK   Set scratch disk (default: scratch.dsk)\n";
 194     print "  --swap-disk=DISK  Set swap disk file (default: swap.dsk)\n";
 195     exit $exitcode;
 196 }
 197
 198 sub copy_pad {
 199     my ($src, $dst, $blocksize) = @_;
 200     run_command ("dd", "if=$src", "of=$dst", "bs=$blocksize", "conv=sync");
 201 }
 202
 203 sub create_disk {
 204     my ($disk, $kb) = @_;
 205     run_command ("dd", "if=/dev/zero", "of=$disk", "bs=1024", "count=$kb");
 206 }
 207
 208 sub run_vm {
 209     my ($fork) = shift;
 210     $fork eq 'FORK' || $fork eq 'EXEC' or die;
 211
 212     our (@disks);
 213
 214     die "$disks[0]: can't find OS disk\n" if ! -e $disks[0];
 215     for my $i (1...3) {
 216         undef $disks[$i] if ! -e $disks[$i];
 217     }
 218
 219     my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/;
 220     if (($project eq 'userprog' || $project eq 'vm' || $project eq 'filesys')
 221         && !defined $disks[1]) {
 222         print STDERR "warning: it looks like you're running the $project project, "
 223             . "but no file system disk is present\n";
 224     }
 225     if ($project eq 'vm' && !defined $disks[3]) {
 226         print STDERR "warning: it looks like you're running the $project project, "
 227             . "but no swap disk is present\n";
 228     }
 229
 230     write_cmd_line ($disks[0], @_);
 231
 232     if ($sim eq 'bochs') {
 233         my ($bin);
 234         if ($debug eq 'no-debug') {
 235             $bin = 'bochs';
 236         } elsif ($debug eq 'monitor') {
 237             $bin = 'bochs-dbg';
 238         } elsif ($debug eq 'gdb') {
 239             $bin = 'bochs-gdb';
 240         }
 241
 242         my ($bochsbin) = search_path ($bin);
 243         my ($bochsshare) = "$bochsbin/../share/bochs";
 244
 245         open (BOCHSRC, ">bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 246         print BOCHSRC "romimage: file=$bochsshare/BIOS-bochs-latest, "
 247             . "address=0xf0000\n";
 248         print BOCHSRC "vgaromimage: $bochsshare/VGABIOS-lgpl-latest\n";
 249         print BOCHSRC bochs_disk_line ("ata0-master", $disks[0]);
 250         print BOCHSRC bochs_disk_line ("ata0-slave", $disks[1]);
 251         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ioaddr2=0x370, irq=15\n"
 252             if defined ($disks[2]) || defined ($disks[3]);
 253         print BOCHSRC bochs_disk_line ("ata1-master", $disks[2]);
 254         print BOCHSRC bochs_disk_line ("ata1-slave", $disks[3]);
 255         print BOCHSRC "boot: c\n";
 256         print BOCHSRC "ips: 1000000\n";
 257         if (!$realtime) {
 258             print BOCHSRC "clock: sync=none, time0=0\n";
 259         } else {
 260             print BOCHSRC "clock: sync=realtime, time0=0\n";
 261         }
 262         print BOCHSRC "megs: $mem\n";
 263         print BOCHSRC "log: bochsout.txt\n";
 264         if ($vga ne 'terminal') {
 265             print BOCHSRC "com1: enabled=1, dev=/dev/stdout\n"
 266                 if $serial_out;
 267             print BOCHSRC "display_library: nogui\n"
 268                 if $vga eq 'none';
 269         } else {
 270             print BOCHSRC "display_library: term\n";
 271         }
 272         close (BOCHSRC);
 273
 274         my (@cmd) = ($bin, '-q');
 275         push (@cmd, '-j', $jitter) if defined $jitter;
 276         print join (' ', @cmd), "\n";
 277         $fork eq 'EXEC' ? exec (@cmd) : system (@cmd);
 278     } elsif ($sim eq 'qemu') {
 279         print "warning: qemu doesn't support --terminal\n"
 280             if $vga eq 'terminal';
 281         print "warning: qemu doesn't support jitter\n"
 282             if defined $jitter;
 283         my (@cmd) = ('qemu');
 284         push (@cmd, '-hda', $disks[0]) if defined $disks[0];
 285         push (@cmd, '-hdb', $disks[1]) if defined $disks[1];
 286         push (@cmd, '-hdc', $disks[2]) if defined $disks[2];
 287         push (@cmd, '-hdd', $disks[3]) if defined $disks[3];
 288         push (@cmd, '-m', $mem);
 289         push (@cmd, '-nographic') if $vga eq 'none';
 290         push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 291         push (@cmd, '-S') if $debug eq 'monitor';
 292         push (@cmd, '-s') if $debug eq 'gdb';
 293         run_command (@cmd);
 294     } elsif ($sim eq 'gsx') {
 295         print "warning: VMware GSX Server doesn't support --$debug\n"
 296             if $debug ne 'no-debug';
 297         print "warning: VMware GSX Server doesn't support --no-vga\n"
 298             if $vga eq 'none';
 299         print "warning: VMware GSX Server doesn't support --terminal\n"
 300             if $vga eq 'terminal';
 301         print "warning: VMware GSX Server doesn't support jitter\n"
 302             if defined $jitter;
 303
 304         open (VMX, ">pintos.vmx") or die "pintos.vmx: create: $!\n";
 305         chmod 0777 & ~umask, "pintos.vmx";
 306         print VMX "#! /usr/bin/vmware -G\n";
 307         print VMX "config.version = 6\n";
 308         print VMX "guestOS = \"linux\"\n";
 309         print VMX "floppy0.present = FALSE\n";
 310
 311         if (! -e 'null.bin') {
 312             open (NULL, ">null.bin") or die "null.bin: create: $!\n";
 313             close (NULL);
 314         }
 315
 316         for (my ($i) = 0; $i < 4; $i++) {
 317             my ($dsk) = $disks[$i];
 318             next if !defined $dsk;
 319
 320             my ($pln) = $dsk;
 321             $pln =~ s/\.dsk//;
 322             $pln .= ".pln";
 323
 324             my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 325             print VMX "\n$device.present = TRUE\n";
 326             print VMX "$device.deviceType = \"plainDisk\"\n";
 327             print VMX "$device.fileName = \"$pln\"\n";
 328
 329             my (%geom) = disk_geometry ($dsk);
 330             open (PLN, ">$pln") or die "$pln: create: $!\n";
 331             print PLN "DRIVETYPE        ide\n";
 332             print PLN "#vm|VERSION      2\n";
 333             print PLN "#vm|TOOLSVERSION 2\n";
 334             print PLN "CYLINDERS        $geom{C}\n";
 335             print PLN "HEADS            $geom{H}\n";
 336             print PLN "SECTORS          $geom{S}\n";
 337             print PLN "#vm|CAPACITY     $geom{CAPACITY}\n";
 338             print PLN "ACCESS \"$dsk\" 0 $geom{CAPACITY}\n";
 339             close (PLN);
 340         }
 341         close (VMX);
 342
 343         use Cwd;
 344         my ($vmx) = getcwd () . "/pintos.vmx";
 345         system ("vmware-cmd -s register $vmx >&/dev/null");
 346         system ("vmware-cmd $vmx stop hard >&/dev/null");
 347         system ("vmware -l -G -x -q $vmx");
 348         system ("vmware-cmd $vmx stop hard >&/dev/null");
 349     }
 350 }
 351
 352 sub write_cmd_line {
 353     my ($disk, @args) = @_;
 354
 355     die "command line includes empty string" if grep (/^$/, @args);
 356     my ($args) = join ("\0", @args) . "\0\0";
 357     die "command line exceeds 128 bytes" if length ($args) > 128;
 358     $args .= "\0" x (128 - length ($args));
 359
 360     print "writing command line to $disk...\n";
 361     open (DISK, "+<$disk") or die "$disk: open: $!\n";
 362     seek (DISK, 0x17e, 0) or die "$disk: seek: $!\n";
 363     syswrite (DISK, $args) or die "$disk: write: $!\n";
 364     close (DISK) or die "$disk: close: $!\n";
 365 }
 366
 367 sub run_command {
 368     print join (' ', @_), "\n";
 369     die "command failed\n" if system (@_);
 370 }
 371
 372 sub search_path {
 373     my ($target) = @_;
 374     for my $dir (split (':', $ENV{PATH})) {
 375         return $dir if -e "$dir/$target";
 376     }
 377     die "$target not in PATH\n";
 378 }
 379
 380 sub bochs_disk_line {
 381     my ($device, $file) = @_;
 382     return "" if !defined $file;
 383     my (%geom) = disk_geometry ($file);
 384     return "$device: type=disk, path=$file, mode=flat, "
 385         . "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, "
 386         . "translation=none\n";
 387 }
 388
 389 sub disk_geometry {
 390     my ($file) = @_;
 391     my ($size) = -s $file;
 392     die "$file: stat: $!\n" if !defined $size;
 393     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 394     my ($cylinders) = int ($size / (512 * 16 * 63));
 395     $cylinders++ if $size % (512 * 16 * 63);
 396
 397     return (CAPACITY => $size / 512,
 398             C => $cylinders,
 399             H => 16,
 400             S => 63);
 401 }