pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX;
   5 use Fcntl;
   6 use File::Temp 'tempfile';
   7 use Getopt::Long qw(:config bundling);
   8
   9 # Command-line options.
  10 our ($sim);                     # Simulator: bochs, qemu, or gsx.
  11 our ($debug) = "none";          # Debugger: none, monitor, or gdb.
  12 our ($mem) = 4;                 # Physical RAM in MB.
  13 our ($serial_out) = 1;          # Send output to serial port?
  14 our ($vga);                     # VGA output: window, terminal, or none.
  15 our ($jitter);                  # Seed for random timer interrupts, if set.
  16 our ($realtime);                # Synchronize timer interrupts with real time?
  17 our ($timeout);                 # Maximum runtime in seconds, if set.
  18 our (@puts);                    # Files to copy into the VM.
  19 our (@gets);                    # Files to copy out of the VM.
  20 our ($as_ref);                  # Reference to last addition to @gets or @puts.
  21 our (@kernel_args);             # Arguments to pass to kernel.
  22 our (%disks) = (OS => {DEF_FN => 'os.dsk'},             # Disks to give VM.
  23                 FS => {DEF_FN => 'fs.dsk'},
  24                 SCRATCH => {DEF_FN => 'scratch.dsk'},
  25                 SWAP => {DEF_FN => 'swap.dsk'});
  26 our (@disks_by_iface) = @disks{qw (OS FS SCRATCH SWAP)};
  27
  28 parse_command_line ();
  29 find_disks ();
  30 prepare_scratch_disk ();
  31 prepare_arguments ();
  32 run_vm ();
  33 finish_scratch_disk ();
  34
  35 exit 0;
  36 \f
  37 # Parses the command line.
  38 sub parse_command_line {
  39     usage (0) if @ARGV == 0 || (@ARGV == 1 && $ARGV[0] eq '--help');
  40
  41     @kernel_args = @ARGV;
  42     if (grep ($_ eq '--', @kernel_args)) {
  43         @ARGV = ();
  44         while ((my $arg = shift (@kernel_args)) ne '--') {
  45             push (@ARGV, $arg);
  46         }
  47         GetOptions ("sim=s" => sub { set_sim (@_) },
  48                     "bochs" => sub { set_sim ("bochs") },
  49                     "qemu" => sub { set_sim ("qemu") },
  50                     "gsx" => sub { set_sim ("gsx") },
  51
  52                     "debug=s" => sub { set_debug (@_) },
  53                     "no-debug" => sub { set_debug ("none") },
  54                     "monitor" => sub { set_debug ("monitor") },
  55                     "gdb" => sub { set_debug ("gdb") },
  56
  57                     "m|memory=i" => \$mem,
  58                     "j|jitter=i" => sub { set_jitter (@_) },
  59                     "r|realtime" => sub { set_realtime () },
  60                     "T|timeout=i" => \$timeout,
  61
  62                     "v|no-vga" => sub { set_vga ('none'); },
  63                     "s|no-serial" => sub { $serial_out = 0; },
  64                     "t|terminal" => sub { set_vga ('terminal'); },
  65
  66                     "p|put-file=s" => sub { add_file (\@puts, $_[1]); },
  67                     "g|get-file=s" => sub { add_file (\@gets, $_[1]); },
  68                     "a|as=s" => sub { set_as ($_[1]); },
  69
  70                     "h|help" => sub { usage (0); },
  71
  72                     "os-disk=s" => \$disks{OS}{FILENAME},
  73                     "fs-disk=s" => \$disks{FS}{FILENAME},
  74                     "scratch-disk=s" => \$disks{SCRATCH}{FILENAME},
  75                     "swap-disk=s" => \$disks{SWAP}{FILENAME},
  76
  77                     "0|disk-0|hda=s" => \$disks_by_iface[0]{FILENAME},
  78                     "1|disk-1|hdb=s" => \$disks_by_iface[1]{FILENAME},
  79                     "2|disk-2|hdc=s" => \$disks_by_iface[2]{FILENAME},
  80                     "3|disk-3|hdd=s" => \$disks_by_iface[3]{FILENAME})
  81           or exit 1;
  82     }
  83
  84     $sim = "bochs" if !defined $sim;
  85     $debug = "none" if !defined $debug;
  86     $vga = "window" if !defined $vga;
  87 }
  88
  89 # usage($exitcode).
  90 # Prints a usage message and exits with $exitcode.
  91 sub usage {
  92     my ($exitcode) = @_;
  93     $exitcode = 1 unless defined $exitcode;
  94     print <<'EOF';
  95 pintos, a utility for running Pintos in a simulator
  96 Usage: pintos [OPTION...] -- [ARGUMENT...]
  97 where each OPTION is one of the following options
  98   and each ARGUMENT is passed to Pintos kernel verbatim.
  99 Simulator selection:
 100   --bochs                  (default) Use Bochs as simulator
 101   --qemu                   Use qemu as simulator
 102   --gsx                    Use VMware GSX Server 3.x as simulator
 103 Debugger selection:
 104   --no-debug               (default) No debugger
 105   --monitor                Debug with simulator's monitor
 106   --gdb                    Debug with gdb
 107 Display options: (default is both VGA and serial)
 108   -v, --no-vga             No VGA display
 109   -s, --no-serial          No serial output
 110   -t, --terminal           Display VGA in terminal (Bochs only)
 111 Timing options: (Bochs only)
 112   -j SEED                  Randomize timer interrupts
 113   -r, --realtime           Use realistic, not reproducible, timings
 114   -T, --timeout=N          Time out and kill Pintos after N seconds
 115 Configuration options:
 116   -m, --mem=N              Give Pintos N MB physical RAM (default: 4)
 117 File system commands (for `run' command):
 118   -p, --put-file=HOSTFN    Copy HOSTFN into VM, by default under same name
 119   -g, --get-file=GUESTFN   Copy GUESTFN out of VM, by default under same name
 120   -a, --as=FILENAME        Specifies guest (for -p) or host (for -g) file name
 121 Disk options: (name an existing FILE or specify SIZE in MB for a temp disk)
 122   --os-disk=FILE           Set OS disk file (default: os.dsk)
 123   --fs-disk=FILE|SIZE      Set FS disk file (default: fs.dsk)
 124   --scratch-disk=FILE|SIZE Set scratch disk (default: scratch.dsk)
 125   --swap-disk=FILE|SIZE    Set swap disk file (default: swap.dsk)
 126 Other options:
 127   -h, --help               Display this help message.
 128 EOF
 129     exit $exitcode;
 130 }
 131
 132 # Sets the simulator.
 133 sub set_sim {
 134     my ($new_sim) = @_;
 135     die "--$new_sim conflicts with --$sim\n"
 136         if defined ($sim) && $sim ne $new_sim;
 137     $sim = $new_sim;
 138 }
 139
 140 # Sets the debugger.
 141 sub set_debug {
 142     my ($new_debug) = @_;
 143     die "--$new_debug conflicts with --$debug\n"
 144         if $debug ne 'none' && $new_debug ne 'none' && $debug ne $new_debug;
 145     $debug = $new_debug;
 146 }
 147
 148 # Sets VGA output destination.
 149 sub set_vga {
 150     my ($new_vga) = @_;
 151     if (defined ($vga) && $vga ne $new_vga) {
 152         print "warning: conflicting vga display options\n";
 153     }
 154     $vga = $new_vga;
 155 }
 156
 157 # Sets randomized timer interrupts.
 158 sub set_jitter {
 159     my ($new_jitter) = @_;
 160     die "--realtime conflicts with --jitter\n" if defined $realtime;
 161     die "different --jitter already defined\n"
 162         if defined $jitter && $jitter != $new_jitter;
 163     $jitter = $new_jitter;
 164 }
 165
 166 # Sets real-time timer interrupts.
 167 sub set_realtime {
 168     die "--realtime conflicts with --jitter\n" if defined $jitter;
 169     $realtime = 1;
 170 }
 171
 172 # add_file(\@list, $file)
 173 #
 174 # Adds [$file] to @list, which should be @puts or @gets.
 175 # Sets $as_ref to point to the added element.
 176 sub add_file {
 177     my ($list, $file) = @_;
 178     $as_ref = [$file];
 179     push (@$list, $as_ref);
 180 }
 181
 182 # Sets the guest/host name for the previous put/get.
 183 sub set_as {
 184     my ($as) = @_;
 185     die "-a (or --as) is only allowed after -p or -g\n" if !defined $as_ref;
 186     die "Only one -a (or --as) is allowed after -p or -g\n"
 187       if defined $as_ref->[1];
 188     $as_ref->[1] = $as;
 189 }
 190 \f
 191 # Locates the files used to back each of the virtual disks,
 192 # and creates temporary disks.
 193 sub find_disks {
 194     for my $disk (values %disks) {
 195         # If there's no assigned file name but the default file exists,
 196         # try to assign a default file name.
 197         if (!defined ($disk->{FILENAME})) {
 198             for my $try_fn ($disk->{DEF_FN}, "build/" . $disk->{DEF_FN}) {
 199                 $disk->{FILENAME} = $try_fn, last
 200                   if -e $try_fn;
 201             }
 202         }
 203
 204         # If there's no file name, we're done.
 205         next if !defined ($disk->{FILENAME});
 206
 207         if ($disk->{FILENAME} =~ /^\d+(\.\d+)?|\.\d+$/) {
 208             # Create a temporary disk of approximately the specified
 209             # size in megabytes.
 210             die "OS disk can't be temporary\n" if $disk == $disks{OS};
 211
 212             my ($mb) = $disk->{FILENAME};
 213             undef $disk->{FILENAME};
 214
 215             my ($cyl_size) = 512 * 16 * 63;
 216             extend_disk ($disk, ceil ($mb * 2) * $cyl_size);
 217         } else {
 218             # The file must exist and have nonzero size.
 219             -e $disk->{FILENAME} or die "$disk->{FILENAME}: stat: $!\n";
 220             -s _ or die "$disk->{FILENAME}: disk has zero size\n";
 221         }
 222     }
 223
 224     # Warn about (potentially) missing disks.
 225     die "Cannot find OS disk\n" if !defined $disks{OS}{FILENAME};
 226     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 227         if ((grep ($project eq $_, qw (userprog vm filesys)))
 228             && !defined ($disks{FS}{FILENAME})) {
 229             print STDERR "warning: it looks like you're running the $project ";
 230             print STDERR "project, but no file system disk is present\n";
 231         }
 232         if ($project eq 'vm' && !defined $disks{SWAP}{FILENAME}) {
 233             print STDERR "warning: it looks like you're running the $project ";
 234             print STDERR "project, but no swap disk is present\n";
 235         }
 236     }
 237 }
 238 \f
 239 # Prepare the scratch disk for gets and puts.
 240 sub prepare_scratch_disk {
 241     # Copy the files to put onto the scratch disk.
 242     put_scratch_file ($_->[0]) foreach @puts;
 243
 244     # Make sure the scratch disk is big enough to get big files.
 245     extend_disk ($disks{SCRATCH}, @gets * 1024 * 1024) if @gets;
 246 }
 247
 248 # Read "get" files from the scratch disk.
 249 sub finish_scratch_disk {
 250     # We need to start reading the scratch disk from the beginning again.
 251     if (@gets) {
 252         close ($disks{SCRATCH}{HANDLE});
 253         undef ($disks{SCRATCH}{HANDLE});
 254     }
 255
 256     # Read each file.
 257     get_scratch_file (defined ($_->[1]) ? $_->[1] : $_->[0]) foreach @gets;
 258 }
 259
 260 # put_scratch_file($file).
 261 #
 262 # Copies $file into the scratch disk.
 263 sub put_scratch_file {
 264     my ($put_filename) = @_;
 265     my ($disk_handle, $disk_filename) = open_disk ($disks{SCRATCH});
 266
 267     print "Copying $put_filename into $disk_filename...\n";
 268
 269     # Write metadata sector, which consists of a 4-byte signature
 270     # followed by the file size.
 271     stat $put_filename or die "$put_filename: stat: $!\n";
 272     my ($size) = -s _;
 273     my ($metadata) = pack ("a4 V x504", "PUT\0", $size);
 274     write_fully ($disk_handle, $disk_filename, $metadata);
 275
 276     # Copy file data.
 277     my ($put_handle);
 278     sysopen ($put_handle, $put_filename, O_RDONLY)
 279       or die "$put_filename: open: $!\n";
 280     copy_file ($put_handle, $put_filename, $disk_handle, $disk_filename,
 281                $size);
 282     close ($put_handle);
 283
 284     # Round up disk data to beginning of next sector.
 285     write_fully ($disk_handle, $disk_filename, "\0" x (512 - $size % 512))
 286       if $size % 512;
 287 }
 288
 289 # get_scratch_file($file).
 290 #
 291 # Copies from the scratch disk to $file.
 292 sub get_scratch_file {
 293     my ($get_filename) = @_;
 294     my ($disk_handle, $disk_filename) = open_disk ($disks{SCRATCH});
 295
 296     print "Copying $get_filename out of $disk_filename...\n";
 297
 298     # Read metadata sector, which has a 4-byte signature followed by
 299     # the file size.
 300     my ($metadata) = read_fully ($disk_handle, $disk_filename, 512);
 301     my ($signature, $size) = unpack ("a4 V", $metadata);
 302     die "bad signature reading scratch disk--did Pintos run correctly?\n"
 303       if $signature ne "GET\0";
 304
 305     # Copy file data.
 306     my ($get_handle);
 307     sysopen ($get_handle, $get_filename, O_WRONLY | O_CREAT | O_EXCL, 0666)
 308       or die "$get_filename: create: $!\n";
 309     copy_file ($disk_handle, $disk_filename, $get_handle, $get_filename,
 310                $size);
 311     close ($get_handle);
 312
 313     # Skip forward in disk up to beginning of next sector.
 314     read_fully ($disk_handle, $disk_filename, 512 - $size % 512)
 315       if $size % 512;
 316 }
 317 \f
 318 # Prepares the arguments to pass to the Pintos kernel,
 319 # and then write them into Pintos bootloader.
 320 sub prepare_arguments {
 321     my (@args);
 322     push (@args, shift (@kernel_args))
 323       while @kernel_args && $kernel_args[0] =~ /^-/;
 324     push (@args, 'put', defined $_->[1] ? $_->[1] : $_->[0]) foreach @puts;
 325     push (@args, @kernel_args);
 326     push (@args, 'get', $_->[0]) foreach @gets;
 327     write_cmd_line ($disks{OS}, @args);
 328 }
 329
 330 # Writes @args into the Pintos bootloader at the beginning of $disk.
 331 sub write_cmd_line {
 332     my ($disk, @args) = @_;
 333
 334     # Figure out command line to write.
 335     my ($arg_cnt) = pack ("V", scalar (@args));
 336     my ($args) = join ('', map ("$_\0", @args));
 337     die "command line exceeds 128 bytes" if length ($args) > 128;
 338     $args .= "\0" x (128 - length ($args));
 339
 340     # Write command line.
 341     my ($handle, $filename) = open_disk_copy ($disk);
 342     print "Writing command line to $filename...\n";
 343     sysseek ($handle, 0x17a, 0) == 0x17a or die "$filename: seek: $!\n";
 344     syswrite ($handle, "$arg_cnt$args") or die "$filename: write: $!\n";
 345 }
 346 \f
 347 # Running simulators.
 348
 349 # Runs the selected simulator.
 350 sub run_vm {
 351     if ($sim eq 'bochs') {
 352         run_bochs ();
 353     } elsif ($sim eq 'qemu') {
 354         run_qemu ();
 355     } elsif ($sim eq 'gsx') {
 356         run_gsx ();
 357     } else {
 358         die "unknown simulator `$sim'\n";
 359     }
 360 }
 361
 362 # Runs Bochs.
 363 sub run_bochs {
 364     # Select Bochs binary based on the chosen debugger.
 365     my ($bin);
 366     if ($debug eq 'none') {
 367         $bin = 'bochs';
 368     } elsif ($debug eq 'monitor') {
 369         $bin = 'bochs-dbg';
 370     } elsif ($debug eq 'gdb') {
 371         $bin = 'bochs-gdb';
 372     }
 373
 374     # Write bochsrc.txt configuration file.
 375     open (BOCHSRC, ">", "bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 376     print BOCHSRC <<EOF;
 377 romimage: file=\$BXSHARE/BIOS-bochs-latest, address=0xf0000
 378 vgaromimage: \$BXSHARE/VGABIOS-lgpl-latest
 379 boot: c
 380 ips: 1000000
 381 megs: $mem
 382 log: bochsout.txt
 383 EOF
 384     print BOCHSRC "clock: sync=", $realtime ? 'realtime' : 'none', "time0=0\n";
 385     print_bochs_disk_line ("ata0-master", 0);
 386     print_bochs_disk_line ("ata0-slave", 1);
 387     if (defined ($disks_by_iface[2]{FILENAME})
 388         || defined ($disks_by_iface[3]{FILENAME})) {
 389         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ",
 390           "ioaddr2=0x370, irq=15\n";
 391         print_bochs_disk_line ("ata1-master", 2);
 392         print_bochs_disk_line ("ata1-slave", 3);
 393     }
 394     if ($vga ne 'terminal') {
 395         print BOCHSRC "com1: enabled=1, dev=/dev/stdout\n" if $serial_out;
 396         print BOCHSRC "display_library: nogui\n" if $vga eq 'none';
 397     } else {
 398         print BOCHSRC "display_library: term\n";
 399     }
 400     close (BOCHSRC);
 401
 402     # Compose Bochs command line.
 403     my (@cmd) = ($bin, '-q');
 404     push (@cmd, '-j', $jitter) if defined $jitter;
 405
 406     # Run Bochs.
 407     print join (' ', @cmd), "\n";
 408     my ($exit) = xsystem (@cmd);
 409     if (WIFEXITED ($exit)) {
 410         # Bochs exited normally.
 411         # Ignore the exit code; Bochs normally exits with status 1,
 412         # which is weird.
 413     } elsif (WIFSIGNALED ($exit)) {
 414         die "Bochs died with signal ", WTERMSIG ($exit), "\n";
 415     } else {
 416         die "Bochs died: code $exit\n";
 417     }
 418 }
 419
 420 # print_bochs_disk_line($device, $iface)
 421 #
 422 # If IDE interface $iface has a disk attached, prints a bochsrc.txt
 423 # line for attaching it to $device.
 424 sub print_bochs_disk_line {
 425     my ($device, $iface) = @_;
 426     my ($disk) = $disks_by_iface[$iface];
 427     my ($file) = $disk->{FILENAME};
 428     if (defined $file) {
 429         my (%geom) = disk_geometry ($disk);
 430         print BOCHSRC "$device: type=disk, path=$file, mode=flat, ";
 431         print BOCHSRC "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, ";
 432         print BOCHSRC "translation=none\n";
 433     }
 434 }
 435
 436 # Runs qemu.
 437 sub run_qemu {
 438     print "warning: qemu doesn't support --terminal\n"
 439       if $vga eq 'terminal';
 440     print "warning: qemu doesn't support jitter\n"
 441       if defined $jitter;
 442     my (@cmd) = ('qemu');
 443     for my $iface (0...3) {
 444         my ($option) = ('-hda', '-hdb', '-hdc', '-hdd')[$iface];
 445         push (@cmd, $option, $disks_by_iface[$iface]{FILENAME})
 446           if defined $disks_by_iface[$iface]{FILENAME};
 447     }
 448     push (@cmd, '-m', $mem, '-nics', '0');
 449     push (@cmd, '-nographic') if $vga eq 'none';
 450     push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 451     push (@cmd, '-S') if $debug eq 'monitor';
 452     push (@cmd, '-s', '-S') if $debug eq 'gdb';
 453     push (@cmd, '-monitor', 'null') if $vga eq 'none' && $debug eq 'none';
 454     run_command (@cmd);
 455 }
 456
 457 # gsx_unsup($flag)
 458 #
 459 # Prints a message that $flag is unsupported by GSX Server.
 460 sub gsx_unsup {
 461     my ($flag) = @_;
 462     print "warning: no support for $flag with VMware GSX Server\n";
 463 }
 464
 465 # Runs VMware GSX Server.
 466 sub run_gsx {
 467     gsx_unsup ("--$debug") if $debug ne 'none';
 468     gsx_unsup ("--no-vga") if $vga eq 'none';
 469     gsx_unsup ("--terminal") if $vga eq 'terminal';
 470     gsx_unsup ("--jitter") if defined $jitter;
 471
 472     unlink ("pintos.out");
 473
 474     open (VMX, ">", "pintos.vmx") or die "pintos.vmx: create: $!\n";
 475     chmod 0777 & ~umask, "pintos.vmx";
 476     print VMX <<EOF;
 477 #! /usr/bin/vmware -G
 478 config.version = 6
 479 guestOS = "linux"
 480 floppy0.present = FALSE
 481 memsize = $mem
 482
 483 serial0.present = TRUE
 484 serial0.fileType = "file"
 485 serial0.fileName = "pintos.out"
 486 EOF
 487
 488     for (my ($i) = 0; $i < 4; $i++) {
 489         my ($disk) = $disks_by_iface[$i];
 490         my ($dsk) = $disk->{FILENAME};
 491         next if !defined $dsk;
 492
 493         my ($pln) = $dsk;
 494         $pln =~ s/\.dsk//;
 495         $pln .= ".pln";
 496
 497         my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 498         print VMX <<EOF;
 499
 500 $device.present = TRUE
 501 $device.deviceType = "plainDisk"
 502 $device.fileName = "$pln"
 503 EOF
 504
 505         my (%geom) = disk_geometry ($disk);
 506         open (PLN, ">", $pln) or die "$pln: create: $!\n";
 507         print PLN <<EOF;
 508 DRIVETYPE       ide
 509 #vm|VERSION     2
 510 #vm|TOOLSVERSION        2
 511 CYLINDERS       $geom{C}
 512 HEADS           $geom{H}
 513 SECTORS         $geom{S}
 514 #vm|CAPACITY    $geom{CAPACITY}
 515 ACCESS "$dsk" 0 $geom{CAPACITY}
 516 EOF
 517         close (PLN);
 518     }
 519     close (VMX);
 520
 521     my ($vmx) = getcwd () . "/pintos.vmx";
 522     system ("vmware-cmd -s register $vmx >&/dev/null");
 523     system ("vmware-cmd $vmx stop hard >&/dev/null");
 524     system ("vmware -l -G -x -q $vmx");
 525     system ("vmware-cmd $vmx stop hard >&/dev/null");
 526     system ("vmware-cmd -s unregister $vmx >&/dev/null");
 527 }
 528 \f
 529 # Disk utilities.
 530
 531 # open_disk($disk)
 532 #
 533 # Opens $disk, if it is not already open, and returns its file handle
 534 # and file name.
 535 sub open_disk {
 536     my ($disk) = @_;
 537     if (!defined ($disk->{HANDLE})) {
 538         if ($disk->{FILENAME}) {
 539             sysopen ($disk->{HANDLE}, $disk->{FILENAME}, O_RDWR)
 540               or die "$disk->{FILENAME}: open: $!\n";
 541         } else {
 542             ($disk->{HANDLE}, $disk->{FILENAME}) = tempfile (UNLINK => 1,
 543                                                              SUFFIX => '.dsk');
 544         }
 545     }
 546     return ($disk->{HANDLE}, $disk->{FILENAME});
 547 }
 548
 549 # open_disk_copy($disk)
 550 #
 551 # Makes a temporary copy of $disk and returns its file handle and file name.
 552 sub open_disk_copy {
 553     my ($disk) = @_;
 554     die if !$disk->{FILENAME};
 555
 556     my ($orig_handle, $orig_filename) = open_disk ($disk);
 557     my ($cp_handle, $cp_filename) = tempfile (UNLINK => 1, SUFFIX => '.dsk');
 558     copy_file ($orig_handle, $orig_filename, $cp_handle, $cp_filename,
 559                -s $orig_handle);
 560     return ($disk->{HANDLE}, $disk->{FILENAME}) = ($cp_handle, $cp_filename);
 561 }
 562
 563 # extend_disk($disk, $size)
 564 #
 565 # Extends $disk, if necessary, so that it is at least $size bytes
 566 # long.
 567 sub extend_disk {
 568     my ($disk, $size) = @_;
 569     my ($handle, $filename) = open_disk ($disk);
 570     if (-s ($handle) < $size) {
 571         sysseek ($handle, $size - 1, 0) == $size - 1
 572           or die "$filename: seek: $!\n";
 573         syswrite ($handle, "\0") == 1
 574           or die "$filename: write: $!\n";
 575     }
 576 }
 577
 578 # disk_geometry($file)
 579 #
 580 # Examines $file and returns a valid IDE disk geometry for it, as a
 581 # hash.
 582 sub disk_geometry {
 583     my ($disk) = @_;
 584     my ($file) = $disk->{FILENAME};
 585     my ($size) = -s $file;
 586     die "$file: stat: $!\n" if !defined $size;
 587     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 588     my ($cyl_size) = 512 * 16 * 63;
 589     my ($cylinders) = ceil ($size / $cyl_size);
 590     extend_disk ($disk, $cylinders * $cyl_size) if $size % $cyl_size;
 591
 592     return (CAPACITY => $size / 512,
 593             C => $cylinders,
 594             H => 16,
 595             S => 63);
 596 }
 597
 598 # copy_file($from_handle, $from_filename, $to_handle, $to_filename, $size)
 599 #
 600 # Copies $size bytes from $from_handle to $to_handle.
 601 # $from_filename and $to_filename are used in error messages.
 602 sub copy_file {
 603     my ($from_handle, $from_filename, $to_handle, $to_filename, $size) = @_;
 604
 605     while ($size > 0) {
 606         my ($chunk_size) = 4096;
 607         $chunk_size = $size if $chunk_size > $size;
 608         $size -= $chunk_size;
 609
 610         my ($data) = read_fully ($from_handle, $from_filename, $chunk_size);
 611         write_fully ($to_handle, $to_filename, $data);
 612     }
 613 }
 614
 615 # read_fully($handle, $filename, $bytes)
 616 #
 617 # Reads exactly $bytes bytes from $handle and returns the data read.
 618 # $filename is used in error messages.
 619 sub read_fully {
 620     my ($handle, $filename, $bytes) = @_;
 621     my ($data);
 622     my ($read_bytes) = sysread ($handle, $data, $bytes);
 623     die "$filename: read: $!\n" if !defined $read_bytes;
 624     die "$filename: unexpected end of file\n" if $read_bytes != $bytes;
 625     return $data;
 626 }
 627
 628 # write_fully($handle, $filename, $data)
 629 #
 630 # Write $data to $handle.
 631 # $filename is used in error messages.
 632 sub write_fully {
 633     my ($handle, $filename, $data) = @_;
 634     my ($written_bytes) = syswrite ($handle, $data);
 635     die "$filename: write: $!\n" if !defined $written_bytes;
 636     die "$filename: short write\n" if $written_bytes != length $data;
 637 }
 638 \f
 639 # Subprocess utilities.
 640
 641 # run_command(@args)
 642 #
 643 # Runs xsystem(@args).
 644 # Also prints the command it's running and checks that it succeeded.
 645 sub run_command {
 646     print join (' ', @_), "\n";
 647     die "command failed\n" if xsystem (@_);
 648 }
 649
 650 # xsystem(@args)
 651 #
 652 # Creates a subprocess via exec(@args) and waits for it to complete.
 653 # Relays common signals to the subprocess.
 654 # If $timeout is set then the subprocess will be killed after that long.
 655 sub xsystem {
 656     my ($pid) = fork;
 657     if (!defined ($pid)) {
 658         # Fork failed.
 659         die "fork: $!\n";
 660     } elsif (!$pid) {
 661         # Running in child process.
 662         exec (@_);
 663         exit (1);
 664     } else {
 665         # Running in parent process.
 666         local $SIG{ALRM} = sub { timeout ($pid); };
 667         local $SIG{INT} = sub { relay_signal ($pid, "INT"); };
 668         local $SIG{TERM} = sub { relay_signal ($pid, "TERM"); };
 669         alarm ($timeout) if defined ($timeout);
 670         waitpid ($pid, 0);
 671         alarm (0);
 672         return $?;
 673     }
 674 }
 675
 676 # relay_signal($pid, $signal)
 677 #
 678 # Relays $signal to $pid and then reinvokes it for us with the default
 679 # handler.
 680 sub relay_signal {
 681     my ($pid, $signal) = @_;
 682     kill $signal, $pid;
 683     $SIG{$signal} = 'DEFAULT';
 684     kill $signal, getpid ();
 685 }
 686
 687 # timeout($pid)
 688 #
 689 # Interrupts $pid and dies with a timeout error message.
 690 sub timeout {
 691     my ($pid) = @_;
 692     kill "INT", $pid;
 693     waitpid ($pid, 0);
 694     seek (STDOUT, 0, 2);
 695     my ($load_avg) = `uptime` =~ /(load average:.*)$/i;
 696     print "\nTIMEOUT after $timeout seconds";
 697     print  " - $load_avg" if defined $load_avg;
 698     print "\n";
 699     exit 0;
 700 }