pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX;
   5 use Fcntl;
   6 use File::Temp 'tempfile';
   7 use Getopt::Long qw(:config bundling);
   8
   9 # Command-line options.
  10 our ($start_time) = time ();
  11 our ($sim);                     # Simulator: bochs, qemu, or gsx.
  12 our ($debug) = "none";          # Debugger: none, monitor, or gdb.
  13 our ($mem) = 4;                 # Physical RAM in MB.
  14 our ($serial_out) = 1;          # Send output to serial port?
  15 our ($vga);                     # VGA output: window, terminal, or none.
  16 our ($jitter);                  # Seed for random timer interrupts, if set.
  17 our ($realtime);                # Synchronize timer interrupts with real time?
  18 our ($timeout);                 # Maximum runtime in seconds, if set.
  19 our (@puts);                    # Files to copy into the VM.
  20 our (@gets);                    # Files to copy out of the VM.
  21 our ($as_ref);                  # Reference to last addition to @gets or @puts.
  22 our (@kernel_args);             # Arguments to pass to kernel.
  23 our (%disks) = (OS => {DEF_FN => 'os.dsk'},             # Disks to give VM.
  24                 FS => {DEF_FN => 'fs.dsk'},
  25                 SCRATCH => {DEF_FN => 'scratch.dsk'},
  26                 SWAP => {DEF_FN => 'swap.dsk'});
  27 our (@disks_by_iface) = @disks{qw (OS FS SCRATCH SWAP)};
  28
  29 parse_command_line ();
  30 find_disks ();
  31 prepare_scratch_disk ();
  32 prepare_arguments ();
  33 run_vm ();
  34 finish_scratch_disk ();
  35
  36 exit 0;
  37 \f
  38 # Parses the command line.
  39 sub parse_command_line {
  40     usage (0) if @ARGV == 0 || (@ARGV == 1 && $ARGV[0] eq '--help');
  41
  42     @kernel_args = @ARGV;
  43     if (grep ($_ eq '--', @kernel_args)) {
  44         @ARGV = ();
  45         while ((my $arg = shift (@kernel_args)) ne '--') {
  46             push (@ARGV, $arg);
  47         }
  48         GetOptions ("sim=s" => sub { set_sim (@_) },
  49                     "bochs" => sub { set_sim ("bochs") },
  50                     "qemu" => sub { set_sim ("qemu") },
  51                     "gsx" => sub { set_sim ("gsx") },
  52
  53                     "debug=s" => sub { set_debug (@_) },
  54                     "no-debug" => sub { set_debug ("none") },
  55                     "monitor" => sub { set_debug ("monitor") },
  56                     "gdb" => sub { set_debug ("gdb") },
  57
  58                     "m|memory=i" => \$mem,
  59                     "j|jitter=i" => sub { set_jitter (@_) },
  60                     "r|realtime" => sub { set_realtime () },
  61                     "T|timeout=i" => \$timeout,
  62
  63                     "v|no-vga" => sub { set_vga ('none'); },
  64                     "s|no-serial" => sub { $serial_out = 0; },
  65                     "t|terminal" => sub { set_vga ('terminal'); },
  66
  67                     "p|put-file=s" => sub { add_file (\@puts, $_[1]); },
  68                     "g|get-file=s" => sub { add_file (\@gets, $_[1]); },
  69                     "a|as=s" => sub { set_as ($_[1]); },
  70
  71                     "h|help" => sub { usage (0); },
  72
  73                     "os-disk=s" => \$disks{OS}{FILE_NAME},
  74                     "fs-disk=s" => \$disks{FS}{FILE_NAME},
  75                     "scratch-disk=s" => \$disks{SCRATCH}{FILE_NAME},
  76                     "swap-disk=s" => \$disks{SWAP}{FILE_NAME},
  77
  78                     "0|disk-0|hda=s" => \$disks_by_iface[0]{FILE_NAME},
  79                     "1|disk-1|hdb=s" => \$disks_by_iface[1]{FILE_NAME},
  80                     "2|disk-2|hdc=s" => \$disks_by_iface[2]{FILE_NAME},
  81                     "3|disk-3|hdd=s" => \$disks_by_iface[3]{FILE_NAME})
  82           or exit 1;
  83     }
  84
  85     $sim = "bochs" if !defined $sim;
  86     $debug = "none" if !defined $debug;
  87     $vga = "window" if !defined $vga;
  88
  89     print "warning: -T or --timeout should not be used with --$debug\n"
  90       if defined ($timeout) && $debug ne 'none';
  91 }
  92
  93 # usage($exitcode).
  94 # Prints a usage message and exits with $exitcode.
  95 sub usage {
  96     my ($exitcode) = @_;
  97     $exitcode = 1 unless defined $exitcode;
  98     print <<'EOF';
  99 pintos, a utility for running Pintos in a simulator
 100 Usage: pintos [OPTION...] -- [ARGUMENT...]
 101 where each OPTION is one of the following options
 102   and each ARGUMENT is passed to Pintos kernel verbatim.
 103 Simulator selection:
 104   --bochs                  (default) Use Bochs as simulator
 105   --qemu                   Use qemu as simulator
 106   --gsx                    Use VMware GSX Server 3.x as simulator
 107 Debugger selection:
 108   --no-debug               (default) No debugger
 109   --monitor                Debug with simulator's monitor
 110   --gdb                    Debug with gdb
 111 Display options: (default is both VGA and serial)
 112   -v, --no-vga             No VGA display
 113   -s, --no-serial          No serial output
 114   -t, --terminal           Display VGA in terminal (Bochs only)
 115 Timing options: (Bochs only)
 116   -j SEED                  Randomize timer interrupts
 117   -r, --realtime           Use realistic, not reproducible, timings
 118   -T, --timeout=N          Kill Pintos after N seconds CPU time or N*load_avg
 119                            seconds wall-clock time (whichever comes first)
 120 Configuration options:
 121   -m, --mem=N              Give Pintos N MB physical RAM (default: 4)
 122 File system commands (for `run' command):
 123   -p, --put-file=HOSTFN    Copy HOSTFN into VM, by default under same name
 124   -g, --get-file=GUESTFN   Copy GUESTFN out of VM, by default under same name
 125   -a, --as=FILENAME        Specifies guest (for -p) or host (for -g) file name
 126 Disk options: (name an existing FILE or specify SIZE in MB for a temp disk)
 127   --os-disk=FILE           Set OS disk file (default: os.dsk)
 128   --fs-disk=FILE|SIZE      Set FS disk file (default: fs.dsk)
 129   --scratch-disk=FILE|SIZE Set scratch disk (default: scratch.dsk)
 130   --swap-disk=FILE|SIZE    Set swap disk file (default: swap.dsk)
 131 Other options:
 132   -h, --help               Display this help message.
 133 EOF
 134     exit $exitcode;
 135 }
 136
 137 # Sets the simulator.
 138 sub set_sim {
 139     my ($new_sim) = @_;
 140     die "--$new_sim conflicts with --$sim\n"
 141         if defined ($sim) && $sim ne $new_sim;
 142     $sim = $new_sim;
 143 }
 144
 145 # Sets the debugger.
 146 sub set_debug {
 147     my ($new_debug) = @_;
 148     die "--$new_debug conflicts with --$debug\n"
 149         if $debug ne 'none' && $new_debug ne 'none' && $debug ne $new_debug;
 150     $debug = $new_debug;
 151 }
 152
 153 # Sets VGA output destination.
 154 sub set_vga {
 155     my ($new_vga) = @_;
 156     if (defined ($vga) && $vga ne $new_vga) {
 157         print "warning: conflicting vga display options\n";
 158     }
 159     $vga = $new_vga;
 160 }
 161
 162 # Sets randomized timer interrupts.
 163 sub set_jitter {
 164     my ($new_jitter) = @_;
 165     die "--realtime conflicts with --jitter\n" if defined $realtime;
 166     die "different --jitter already defined\n"
 167         if defined $jitter && $jitter != $new_jitter;
 168     $jitter = $new_jitter;
 169 }
 170
 171 # Sets real-time timer interrupts.
 172 sub set_realtime {
 173     die "--realtime conflicts with --jitter\n" if defined $jitter;
 174     $realtime = 1;
 175 }
 176
 177 # add_file(\@list, $file)
 178 #
 179 # Adds [$file] to @list, which should be @puts or @gets.
 180 # Sets $as_ref to point to the added element.
 181 sub add_file {
 182     my ($list, $file) = @_;
 183     $as_ref = [$file];
 184     push (@$list, $as_ref);
 185 }
 186
 187 # Sets the guest/host name for the previous put/get.
 188 sub set_as {
 189     my ($as) = @_;
 190     die "-a (or --as) is only allowed after -p or -g\n" if !defined $as_ref;
 191     die "Only one -a (or --as) is allowed after -p or -g\n"
 192       if defined $as_ref->[1];
 193     $as_ref->[1] = $as;
 194 }
 195 \f
 196 # Locates the files used to back each of the virtual disks,
 197 # and creates temporary disks.
 198 sub find_disks {
 199     for my $disk (values %disks) {
 200         # If there's no assigned file name but the default file exists,
 201         # try to assign a default file name.
 202         if (!defined ($disk->{FILE_NAME})) {
 203             for my $try_fn ($disk->{DEF_FN}, "build/" . $disk->{DEF_FN}) {
 204                 $disk->{FILE_NAME} = $try_fn, last
 205                   if -e $try_fn;
 206             }
 207         }
 208
 209         # If there's no file name, we're done.
 210         next if !defined ($disk->{FILE_NAME});
 211
 212         if ($disk->{FILE_NAME} =~ /^\d+(\.\d+)?|\.\d+$/) {
 213             # Create a temporary disk of approximately the specified
 214             # size in megabytes.
 215             die "OS disk can't be temporary\n" if $disk == $disks{OS};
 216
 217             my ($mb) = $disk->{FILE_NAME};
 218             undef $disk->{FILE_NAME};
 219
 220             my ($cyl_size) = 512 * 16 * 63;
 221             extend_disk ($disk, ceil ($mb * 2) * $cyl_size);
 222         } else {
 223             # The file must exist and have nonzero size.
 224             -e $disk->{FILE_NAME} or die "$disk->{FILE_NAME}: stat: $!\n";
 225             -s _ or die "$disk->{FILE_NAME}: disk has zero size\n";
 226         }
 227     }
 228
 229     # Warn about (potentially) missing disks.
 230     die "Cannot find OS disk\n" if !defined $disks{OS}{FILE_NAME};
 231     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 232         if ((grep ($project eq $_, qw (userprog vm filesys)))
 233             && !defined ($disks{FS}{FILE_NAME})) {
 234             print STDERR "warning: it looks like you're running the $project ";
 235             print STDERR "project, but no file system disk is present\n";
 236         }
 237         if ($project eq 'vm' && !defined $disks{SWAP}{FILE_NAME}) {
 238             print STDERR "warning: it looks like you're running the $project ";
 239             print STDERR "project, but no swap disk is present\n";
 240         }
 241     }
 242 }
 243 \f
 244 # Prepare the scratch disk for gets and puts.
 245 sub prepare_scratch_disk {
 246     # Copy the files to put onto the scratch disk.
 247     put_scratch_file ($_->[0]) foreach @puts;
 248
 249     # Make sure the scratch disk is big enough to get big files.
 250     extend_disk ($disks{SCRATCH}, @gets * 1024 * 1024) if @gets;
 251 }
 252
 253 # Read "get" files from the scratch disk.
 254 sub finish_scratch_disk {
 255     # We need to start reading the scratch disk from the beginning again.
 256     if (@gets) {
 257         close ($disks{SCRATCH}{HANDLE});
 258         undef ($disks{SCRATCH}{HANDLE});
 259     }
 260
 261     # Read each file.
 262     get_scratch_file (defined ($_->[1]) ? $_->[1] : $_->[0]) foreach @gets;
 263 }
 264
 265 # put_scratch_file($file).
 266 #
 267 # Copies $file into the scratch disk.
 268 sub put_scratch_file {
 269     my ($put_file_name) = @_;
 270     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 271
 272     print "Copying $put_file_name into $disk_file_name...\n";
 273
 274     # Write metadata sector, which consists of a 4-byte signature
 275     # followed by the file size.
 276     stat $put_file_name or die "$put_file_name: stat: $!\n";
 277     my ($size) = -s _;
 278     my ($metadata) = pack ("a4 V x504", "PUT\0", $size);
 279     write_fully ($disk_handle, $disk_file_name, $metadata);
 280
 281     # Copy file data.
 282     my ($put_handle);
 283     sysopen ($put_handle, $put_file_name, O_RDONLY)
 284       or die "$put_file_name: open: $!\n";
 285     copy_file ($put_handle, $put_file_name, $disk_handle, $disk_file_name,
 286                $size);
 287     close ($put_handle);
 288
 289     # Round up disk data to beginning of next sector.
 290     write_fully ($disk_handle, $disk_file_name, "\0" x (512 - $size % 512))
 291       if $size % 512;
 292 }
 293
 294 # get_scratch_file($file).
 295 #
 296 # Copies from the scratch disk to $file.
 297 sub get_scratch_file {
 298     my ($get_file_name) = @_;
 299     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 300
 301     print "Copying $get_file_name out of $disk_file_name...\n";
 302
 303     # Read metadata sector, which has a 4-byte signature followed by
 304     # the file size.
 305     my ($metadata) = read_fully ($disk_handle, $disk_file_name, 512);
 306     my ($signature, $size) = unpack ("a4 V", $metadata);
 307     die "bad signature reading scratch disk--did Pintos run correctly?\n"
 308       if $signature ne "GET\0";
 309
 310     # Copy file data.
 311     my ($get_handle);
 312     sysopen ($get_handle, $get_file_name, O_WRONLY | O_CREAT | O_EXCL, 0666)
 313       or die "$get_file_name: create: $!\n";
 314     copy_file ($disk_handle, $disk_file_name, $get_handle, $get_file_name,
 315                $size);
 316     close ($get_handle);
 317
 318     # Skip forward in disk up to beginning of next sector.
 319     read_fully ($disk_handle, $disk_file_name, 512 - $size % 512)
 320       if $size % 512;
 321 }
 322 \f
 323 # Prepares the arguments to pass to the Pintos kernel,
 324 # and then write them into Pintos bootloader.
 325 sub prepare_arguments {
 326     my (@args);
 327     push (@args, shift (@kernel_args))
 328       while @kernel_args && $kernel_args[0] =~ /^-/;
 329     push (@args, 'put', defined $_->[1] ? $_->[1] : $_->[0]) foreach @puts;
 330     push (@args, @kernel_args);
 331     push (@args, 'get', $_->[0]) foreach @gets;
 332     write_cmd_line ($disks{OS}, @args);
 333 }
 334
 335 # Writes @args into the Pintos bootloader at the beginning of $disk.
 336 sub write_cmd_line {
 337     my ($disk, @args) = @_;
 338
 339     # Figure out command line to write.
 340     my ($arg_cnt) = pack ("V", scalar (@args));
 341     my ($args) = join ('', map ("$_\0", @args));
 342     die "command line exceeds 128 bytes" if length ($args) > 128;
 343     $args .= "\0" x (128 - length ($args));
 344
 345     # Write command line.
 346     my ($handle, $file_name) = open_disk_copy ($disk);
 347     print "Writing command line to $file_name...\n";
 348     sysseek ($handle, 0x17a, 0) == 0x17a or die "$file_name: seek: $!\n";
 349     syswrite ($handle, "$arg_cnt$args") or die "$file_name: write: $!\n";
 350 }
 351 \f
 352 # Running simulators.
 353
 354 # Runs the selected simulator.
 355 sub run_vm {
 356     if ($sim eq 'bochs') {
 357         run_bochs ();
 358     } elsif ($sim eq 'qemu') {
 359         run_qemu ();
 360     } elsif ($sim eq 'gsx') {
 361         run_gsx ();
 362     } else {
 363         die "unknown simulator `$sim'\n";
 364     }
 365 }
 366
 367 # Runs Bochs.
 368 sub run_bochs {
 369     # Select Bochs binary based on the chosen debugger.
 370     my ($bin) = $debug eq 'monitor' ? 'bochs-dbg' : 'bochs';
 371
 372     # Write bochsrc.txt configuration file.
 373     open (BOCHSRC, ">", "bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 374     print BOCHSRC <<EOF;
 375 romimage: file=\$BXSHARE/BIOS-bochs-latest, address=0xf0000
 376 vgaromimage: file=\$BXSHARE/VGABIOS-lgpl-latest
 377 boot: disk
 378 cpu: ips=1000000
 379 megs: $mem
 380 log: bochsout.txt
 381 panic: action=fatal
 382 EOF
 383     print BOCHSRC "gdbstub: enabled=1\n" if $debug eq 'gdb';
 384     print BOCHSRC "clock: sync=", $realtime ? 'realtime' : 'none',
 385       " time0=0\n";
 386     print_bochs_disk_line ("ata0-master", 0);
 387     print_bochs_disk_line ("ata0-slave", 1);
 388     if (defined ($disks_by_iface[2]{FILE_NAME})
 389         || defined ($disks_by_iface[3]{FILE_NAME})) {
 390         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ",
 391           "ioaddr2=0x370, irq=15\n";
 392         print_bochs_disk_line ("ata1-master", 2);
 393         print_bochs_disk_line ("ata1-slave", 3);
 394     }
 395     if ($vga ne 'terminal') {
 396         print BOCHSRC "com1: enabled=1, mode=file, dev=/dev/stdout\n"
 397           if $serial_out;
 398         print BOCHSRC "display_library: nogui\n" if $vga eq 'none';
 399     } else {
 400         print BOCHSRC "display_library: term\n";
 401     }
 402     close (BOCHSRC);
 403
 404     # Compose Bochs command line.
 405     my (@cmd) = ($bin, '-q');
 406     push (@cmd, '-j', $jitter) if defined $jitter;
 407
 408     # Run Bochs.
 409     print join (' ', @cmd), "\n";
 410     my ($exit) = xsystem (@cmd);
 411     if (WIFEXITED ($exit)) {
 412         # Bochs exited normally.
 413         # Ignore the exit code; Bochs normally exits with status 1,
 414         # which is weird.
 415     } elsif (WIFSIGNALED ($exit)) {
 416         die "Bochs died with signal ", WTERMSIG ($exit), "\n";
 417     } else {
 418         die "Bochs died: code $exit\n";
 419     }
 420 }
 421
 422 # print_bochs_disk_line($device, $iface)
 423 #
 424 # If IDE interface $iface has a disk attached, prints a bochsrc.txt
 425 # line for attaching it to $device.
 426 sub print_bochs_disk_line {
 427     my ($device, $iface) = @_;
 428     my ($disk) = $disks_by_iface[$iface];
 429     my ($file) = $disk->{FILE_NAME};
 430     if (defined $file) {
 431         my (%geom) = disk_geometry ($disk);
 432         print BOCHSRC "$device: type=disk, path=$file, mode=flat, ";
 433         print BOCHSRC "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, ";
 434         print BOCHSRC "translation=none\n";
 435     }
 436 }
 437
 438 # Runs qemu.
 439 sub run_qemu {
 440     print "warning: qemu doesn't support --terminal\n"
 441       if $vga eq 'terminal';
 442     print "warning: qemu doesn't support jitter\n"
 443       if defined $jitter;
 444     my (@cmd) = ('qemu');
 445     for my $iface (0...3) {
 446         my ($option) = ('-hda', '-hdb', '-hdc', '-hdd')[$iface];
 447         push (@cmd, $option, $disks_by_iface[$iface]{FILE_NAME})
 448           if defined $disks_by_iface[$iface]{FILE_NAME};
 449     }
 450     push (@cmd, '-m', $mem);
 451     push (@cmd, '-net', 'none');
 452     push (@cmd, '-nographic') if $vga eq 'none';
 453     push (@cmd, '-serial', 'stdio') if $serial_out && $vga ne 'none';
 454     push (@cmd, '-S') if $debug eq 'monitor';
 455     push (@cmd, '-s', '-S') if $debug eq 'gdb';
 456     push (@cmd, '-monitor', 'null') if $vga eq 'none' && $debug eq 'none';
 457     run_command (@cmd);
 458 }
 459
 460 # gsx_unsup($flag)
 461 #
 462 # Prints a message that $flag is unsupported by GSX Server.
 463 sub gsx_unsup {
 464     my ($flag) = @_;
 465     print "warning: no support for $flag with VMware GSX Server\n";
 466 }
 467
 468 # Runs VMware GSX Server.
 469 sub run_gsx {
 470     gsx_unsup ("--$debug") if $debug ne 'none';
 471     gsx_unsup ("--no-vga") if $vga eq 'none';
 472     gsx_unsup ("--terminal") if $vga eq 'terminal';
 473     gsx_unsup ("--jitter") if defined $jitter;
 474
 475     unlink ("pintos.out");
 476
 477     open (VMX, ">", "pintos.vmx") or die "pintos.vmx: create: $!\n";
 478     chmod 0777 & ~umask, "pintos.vmx";
 479     print VMX <<EOF;
 480 #! /usr/bin/vmware -G
 481 config.version = 6
 482 guestOS = "linux"
 483 floppy0.present = FALSE
 484 memsize = $mem
 485
 486 serial0.present = TRUE
 487 serial0.fileType = "file"
 488 serial0.fileName = "pintos.out"
 489 EOF
 490
 491     for (my ($i) = 0; $i < 4; $i++) {
 492         my ($disk) = $disks_by_iface[$i];
 493         my ($dsk) = $disk->{FILE_NAME};
 494         next if !defined $dsk;
 495
 496         my ($pln) = $dsk;
 497         $pln =~ s/\.dsk//;
 498         $pln .= ".pln";
 499
 500         my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 501         print VMX <<EOF;
 502
 503 $device.present = TRUE
 504 $device.deviceType = "plainDisk"
 505 $device.fileName = "$pln"
 506 EOF
 507
 508         my (%geom) = disk_geometry ($disk);
 509         open (PLN, ">", $pln) or die "$pln: create: $!\n";
 510         print PLN <<EOF;
 511 DRIVETYPE       ide
 512 #vm|VERSION     2
 513 #vm|TOOLSVERSION        2
 514 CYLINDERS       $geom{C}
 515 HEADS           $geom{H}
 516 SECTORS         $geom{S}
 517 #vm|CAPACITY    $geom{CAPACITY}
 518 ACCESS "$dsk" 0 $geom{CAPACITY}
 519 EOF
 520         close (PLN);
 521     }
 522     close (VMX);
 523
 524     my ($vmx) = getcwd () . "/pintos.vmx";
 525     system ("vmware-cmd -s register $vmx >&/dev/null");
 526     system ("vmware-cmd $vmx stop hard >&/dev/null");
 527     system ("vmware -l -G -x -q $vmx");
 528     system ("vmware-cmd $vmx stop hard >&/dev/null");
 529     system ("vmware-cmd -s unregister $vmx >&/dev/null");
 530 }
 531 \f
 532 # Disk utilities.
 533
 534 # open_disk($disk)
 535 #
 536 # Opens $disk, if it is not already open, and returns its file handle
 537 # and file name.
 538 sub open_disk {
 539     my ($disk) = @_;
 540     if (!defined ($disk->{HANDLE})) {
 541         if ($disk->{FILE_NAME}) {
 542             sysopen ($disk->{HANDLE}, $disk->{FILE_NAME}, O_RDWR)
 543               or die "$disk->{FILE_NAME}: open: $!\n";
 544         } else {
 545             ($disk->{HANDLE}, $disk->{FILE_NAME}) = tempfile (UNLINK => 1,
 546                                                              SUFFIX => '.dsk');
 547         }
 548     }
 549     return ($disk->{HANDLE}, $disk->{FILE_NAME});
 550 }
 551
 552 # open_disk_copy($disk)
 553 #
 554 # Makes a temporary copy of $disk and returns its file handle and file name.
 555 sub open_disk_copy {
 556     my ($disk) = @_;
 557     die if !$disk->{FILE_NAME};
 558
 559     my ($orig_handle, $orig_file_name) = open_disk ($disk);
 560     my ($cp_handle, $cp_file_name) = tempfile (UNLINK => 1, SUFFIX => '.dsk');
 561     copy_file ($orig_handle, $orig_file_name, $cp_handle, $cp_file_name,
 562                -s $orig_handle);
 563     return ($disk->{HANDLE}, $disk->{FILE_NAME}) = ($cp_handle, $cp_file_name);
 564 }
 565
 566 # extend_disk($disk, $size)
 567 #
 568 # Extends $disk, if necessary, so that it is at least $size bytes
 569 # long.
 570 sub extend_disk {
 571     my ($disk, $size) = @_;
 572     my ($handle, $file_name) = open_disk ($disk);
 573     if (-s ($handle) < $size) {
 574         sysseek ($handle, $size - 1, 0) == $size - 1
 575           or die "$file_name: seek: $!\n";
 576         syswrite ($handle, "\0") == 1
 577           or die "$file_name: write: $!\n";
 578     }
 579 }
 580
 581 # disk_geometry($file)
 582 #
 583 # Examines $file and returns a valid IDE disk geometry for it, as a
 584 # hash.
 585 sub disk_geometry {
 586     my ($disk) = @_;
 587     my ($file) = $disk->{FILE_NAME};
 588     my ($size) = -s $file;
 589     die "$file: stat: $!\n" if !defined $size;
 590     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 591     my ($cyl_size) = 512 * 16 * 63;
 592     my ($cylinders) = ceil ($size / $cyl_size);
 593     extend_disk ($disk, $cylinders * $cyl_size) if $size % $cyl_size;
 594
 595     return (CAPACITY => $size / 512,
 596             C => $cylinders,
 597             H => 16,
 598             S => 63);
 599 }
 600
 601 # copy_file($from_handle, $from_file_name, $to_handle, $to_file_name, $size)
 602 #
 603 # Copies $size bytes from $from_handle to $to_handle.
 604 # $from_file_name and $to_file_name are used in error messages.
 605 sub copy_file {
 606     my ($from_handle, $from_file_name, $to_handle, $to_file_name, $size) = @_;
 607
 608     while ($size > 0) {
 609         my ($chunk_size) = 4096;
 610         $chunk_size = $size if $chunk_size > $size;
 611         $size -= $chunk_size;
 612
 613         my ($data) = read_fully ($from_handle, $from_file_name, $chunk_size);
 614         write_fully ($to_handle, $to_file_name, $data);
 615     }
 616 }
 617
 618 # read_fully($handle, $file_name, $bytes)
 619 #
 620 # Reads exactly $bytes bytes from $handle and returns the data read.
 621 # $file_name is used in error messages.
 622 sub read_fully {
 623     my ($handle, $file_name, $bytes) = @_;
 624     my ($data);
 625     my ($read_bytes) = sysread ($handle, $data, $bytes);
 626     die "$file_name: read: $!\n" if !defined $read_bytes;
 627     die "$file_name: unexpected end of file\n" if $read_bytes != $bytes;
 628     return $data;
 629 }
 630
 631 # write_fully($handle, $file_name, $data)
 632 #
 633 # Write $data to $handle.
 634 # $file_name is used in error messages.
 635 sub write_fully {
 636     my ($handle, $file_name, $data) = @_;
 637     my ($written_bytes) = syswrite ($handle, $data);
 638     die "$file_name: write: $!\n" if !defined $written_bytes;
 639     die "$file_name: short write\n" if $written_bytes != length $data;
 640 }
 641 \f
 642 # Subprocess utilities.
 643
 644 # run_command(@args)
 645 #
 646 # Runs xsystem(@args).
 647 # Also prints the command it's running and checks that it succeeded.
 648 sub run_command {
 649     print join (' ', @_), "\n";
 650     die "command failed\n" if xsystem (@_);
 651 }
 652
 653 # xsystem(@args)
 654 #
 655 # Creates a subprocess via exec(@args) and waits for it to complete.
 656 # Relays common signals to the subprocess.
 657 # If $timeout is set then the subprocess will be killed after that long.
 658 sub xsystem {
 659     my ($pid) = fork;
 660     if (!defined ($pid)) {
 661         # Fork failed.
 662         die "fork: $!\n";
 663     } elsif (!$pid) {
 664         # Running in child process.
 665         exec_setitimer (@_);
 666     } else {
 667         # Running in parent process.
 668         local $SIG{ALRM} = sub { timeout ($pid); };
 669         local $SIG{INT} = sub { relay_signal ($pid, "INT"); };
 670         local $SIG{TERM} = sub { relay_signal ($pid, "TERM"); };
 671         alarm ($timeout * get_load_average () + 1) if defined ($timeout);
 672         waitpid ($pid, 0);
 673         alarm (0);
 674
 675         if (WIFSIGNALED ($?) && WTERMSIG ($?) == SIGVTALRM ()) {
 676             seek (STDOUT, 0, 2);
 677             print "\nTIMEOUT after $timeout seconds of host CPU time\n";
 678             exit 0;
 679         }
 680
 681         return $?;
 682     }
 683 }
 684
 685 # relay_signal($pid, $signal)
 686 #
 687 # Relays $signal to $pid and then reinvokes it for us with the default
 688 # handler.  Also cleans up temporary files.
 689 sub relay_signal {
 690     my ($pid, $signal) = @_;
 691     kill $signal, $pid;
 692     File::Temp::cleanup();
 693     $SIG{$signal} = 'DEFAULT';
 694     kill $signal, getpid ();
 695 }
 696
 697 # timeout($pid)
 698 #
 699 # Interrupts $pid and dies with a timeout error message.
 700 sub timeout {
 701     my ($pid) = @_;
 702     kill "INT", $pid;
 703     waitpid ($pid, 0);
 704     seek (STDOUT, 0, 2);
 705     my ($load_avg) = `uptime` =~ /(load average:.*)$/i;
 706     print "\nTIMEOUT after ", time () - $start_time,
 707       " seconds of wall-clock time";
 708     print  " - $load_avg" if defined $load_avg;
 709     print "\n";
 710     exit 0;
 711 }
 712
 713 # Returns the system load average over the last minute.
 714 # If the load average is less than 1.0 or cannot be determined, returns 1.0.
 715 sub get_load_average {
 716     my ($avg) = `uptime` =~ /load average:\s*([^,]+),/;
 717     return $avg >= 1.0 ? $avg : 1.0;
 718 }
 719
 720 # Calls setitimer to set a timeout, then execs what was passed to us.
 721 sub exec_setitimer {
 722     if (defined $timeout) {
 723         if ($\16 ge 5.8.0) {
 724             eval "
 725               use Time::HiRes qw(setitimer ITIMER_VIRTUAL);
 726               setitimer (ITIMER_VIRTUAL, $timeout, 0);
 727             ";
 728         } else {
 729             { exec ("setitimer-helper", $timeout, @_); };
 730             exit 1 if !$!{ENOENT};
 731             print STDERR "warning: setitimer-helper is not installed, so ",
 732               "CPU time limit will not be enforced\n";
 733         }
 734     }
 735     exec (@_);
 736     exit (1);
 737 }
 738
 739 sub SIGVTALRM {
 740     use Config;
 741     my $i = 0;
 742     foreach my $name (split(' ', $Config{sig_name})) {
 743         return $i if $name eq 'VTALRM';
 744         $i++;
 745     }
 746     return 0;
 747 }