pintos-os.org Git - pintos-anon/blob - src/utils/pintos

   1 #! /usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX;
   5 use Fcntl;
   6 use File::Temp 'tempfile';
   7 use Getopt::Long qw(:config bundling);
   8
   9 # Command-line options.
  10 our ($start_time) = time ();
  11 our ($sim);                     # Simulator: bochs, qemu, or player.
  12 our ($debug) = "none";          # Debugger: none, monitor, or gdb.
  13 our ($mem) = 4;                 # Physical RAM in MB.
  14 our ($serial) = 1;              # Use serial port for input and output?
  15 our ($vga);                     # VGA output: window, terminal, or none.
  16 our ($jitter);                  # Seed for random timer interrupts, if set.
  17 our ($realtime);                # Synchronize timer interrupts with real time?
  18 our ($timeout);                 # Maximum runtime in seconds, if set.
  19 our ($kill_on_failure);         # Abort quickly on test failure?
  20 our (@puts);                    # Files to copy into the VM.
  21 our (@gets);                    # Files to copy out of the VM.
  22 our ($as_ref);                  # Reference to last addition to @gets or @puts.
  23 our (@kernel_args);             # Arguments to pass to kernel.
  24 our (%disks) = (OS => {DEF_FN => 'os.dsk'},             # Disks to give VM.
  25                 FS => {DEF_FN => 'fs.dsk'},
  26                 SCRATCH => {DEF_FN => 'scratch.dsk'},
  27                 SWAP => {DEF_FN => 'swap.dsk'});
  28 our (@disks_by_iface) = @disks{qw (OS FS SCRATCH SWAP)};
  29
  30 parse_command_line ();
  31 find_disks ();
  32 prepare_scratch_disk ();
  33 prepare_arguments ();
  34 run_vm ();
  35 finish_scratch_disk ();
  36
  37 exit 0;
  38 \f
  39 # Parses the command line.
  40 sub parse_command_line {
  41     usage (0) if @ARGV == 0 || (@ARGV == 1 && $ARGV[0] eq '--help');
  42
  43     @kernel_args = @ARGV;
  44     if (grep ($_ eq '--', @kernel_args)) {
  45         @ARGV = ();
  46         while ((my $arg = shift (@kernel_args)) ne '--') {
  47             push (@ARGV, $arg);
  48         }
  49         GetOptions ("sim=s" => sub { set_sim ($_[1]) },
  50                     "bochs" => sub { set_sim ("bochs") },
  51                     "qemu" => sub { set_sim ("qemu") },
  52                     "player" => sub { set_sim ("player") },
  53
  54                     "debug=s" => sub { set_debug ($_[1]) },
  55                     "no-debug" => sub { set_debug ("none") },
  56                     "monitor" => sub { set_debug ("monitor") },
  57                     "gdb" => sub { set_debug ("gdb") },
  58
  59                     "m|memory=i" => \$mem,
  60                     "j|jitter=i" => sub { set_jitter ($_[1]) },
  61                     "r|realtime" => sub { set_realtime () },
  62
  63                     "T|timeout=i" => \$timeout,
  64                     "k|kill-on-failure" => \$kill_on_failure,
  65
  66                     "v|no-vga" => sub { set_vga ('none'); },
  67                     "s|no-serial" => sub { $serial = 0; },
  68                     "t|terminal" => sub { set_vga ('terminal'); },
  69
  70                     "p|put-file=s" => sub { add_file (\@puts, $_[1]); },
  71                     "g|get-file=s" => sub { add_file (\@gets, $_[1]); },
  72                     "a|as=s" => sub { set_as ($_[1]); },
  73
  74                     "h|help" => sub { usage (0); },
  75
  76                     "os-disk=s" => \$disks{OS}{FILE_NAME},
  77                     "fs-disk=s" => \$disks{FS}{FILE_NAME},
  78                     "scratch-disk=s" => \$disks{SCRATCH}{FILE_NAME},
  79                     "swap-disk=s" => \$disks{SWAP}{FILE_NAME},
  80
  81                     "0|disk-0|hda=s" => \$disks_by_iface[0]{FILE_NAME},
  82                     "1|disk-1|hdb=s" => \$disks_by_iface[1]{FILE_NAME},
  83                     "2|disk-2|hdc=s" => \$disks_by_iface[2]{FILE_NAME},
  84                     "3|disk-3|hdd=s" => \$disks_by_iface[3]{FILE_NAME})
  85           or exit 1;
  86     }
  87
  88     $sim = "bochs" if !defined $sim;
  89     $debug = "none" if !defined $debug;
  90     $vga = "window" if !defined $vga;
  91
  92     undef $timeout, print "warning: disabling timeout with --$debug\n"
  93       if defined ($timeout) && $debug ne 'none';
  94
  95     print "warning: enabling serial port for -k or --kill-on-failure\n"
  96       if $kill_on_failure && !$serial;
  97 }
  98
  99 # usage($exitcode).
 100 # Prints a usage message and exits with $exitcode.
 101 sub usage {
 102     my ($exitcode) = @_;
 103     $exitcode = 1 unless defined $exitcode;
 104     print <<'EOF';
 105 pintos, a utility for running Pintos in a simulator
 106 Usage: pintos [OPTION...] -- [ARGUMENT...]
 107 where each OPTION is one of the following options
 108   and each ARGUMENT is passed to Pintos kernel verbatim.
 109 Simulator selection:
 110   --bochs                  (default) Use Bochs as simulator
 111   --qemu                   Use QEMU as simulator
 112   --player                 Use VMware Player as simulator
 113 Debugger selection:
 114   --no-debug               (default) No debugger
 115   --monitor                Debug with simulator's monitor
 116   --gdb                    Debug with gdb
 117 Display options: (default is both VGA and serial)
 118   -v, --no-vga             No VGA display or keyboard
 119   -s, --no-serial          No serial input or output
 120   -t, --terminal           Display VGA in terminal (Bochs only)
 121 Timing options: (Bochs only)
 122   -j SEED                  Randomize timer interrupts
 123   -r, --realtime           Use realistic, not reproducible, timings
 124 Testing options:
 125   -T, --timeout=N          Kill Pintos after N seconds CPU time or N*load_avg
 126                            seconds wall-clock time (whichever comes first)
 127   -k, --kill-on-failure    Kill Pintos a few seconds after a kernel or user
 128                            panic, test failure, or triple fault
 129 Configuration options:
 130   -m, --mem=N              Give Pintos N MB physical RAM (default: 4)
 131 File system commands (for `run' command):
 132   -p, --put-file=HOSTFN    Copy HOSTFN into VM, by default under same name
 133   -g, --get-file=GUESTFN   Copy GUESTFN out of VM, by default under same name
 134   -a, --as=FILENAME        Specifies guest (for -p) or host (for -g) file name
 135 Disk options: (name an existing FILE or specify SIZE in MB for a temp disk)
 136   --os-disk=FILE           Set OS disk file (default: os.dsk)
 137   --fs-disk=FILE|SIZE      Set FS disk file (default: fs.dsk)
 138   --scratch-disk=FILE|SIZE Set scratch disk (default: scratch.dsk)
 139   --swap-disk=FILE|SIZE    Set swap disk file (default: swap.dsk)
 140 Other options:
 141   -h, --help               Display this help message.
 142 EOF
 143     exit $exitcode;
 144 }
 145
 146 # Sets the simulator.
 147 sub set_sim {
 148     my ($new_sim) = @_;
 149     die "--$new_sim conflicts with --$sim\n"
 150         if defined ($sim) && $sim ne $new_sim;
 151     $sim = $new_sim;
 152 }
 153
 154 # Sets the debugger.
 155 sub set_debug {
 156     my ($new_debug) = @_;
 157     die "--$new_debug conflicts with --$debug\n"
 158         if $debug ne 'none' && $new_debug ne 'none' && $debug ne $new_debug;
 159     $debug = $new_debug;
 160 }
 161
 162 # Sets VGA output destination.
 163 sub set_vga {
 164     my ($new_vga) = @_;
 165     if (defined ($vga) && $vga ne $new_vga) {
 166         print "warning: conflicting vga display options\n";
 167     }
 168     $vga = $new_vga;
 169 }
 170
 171 # Sets randomized timer interrupts.
 172 sub set_jitter {
 173     my ($new_jitter) = @_;
 174     die "--realtime conflicts with --jitter\n" if defined $realtime;
 175     die "different --jitter already defined\n"
 176         if defined $jitter && $jitter != $new_jitter;
 177     $jitter = $new_jitter;
 178 }
 179
 180 # Sets real-time timer interrupts.
 181 sub set_realtime {
 182     die "--realtime conflicts with --jitter\n" if defined $jitter;
 183     $realtime = 1;
 184 }
 185
 186 # add_file(\@list, $file)
 187 #
 188 # Adds [$file] to @list, which should be @puts or @gets.
 189 # Sets $as_ref to point to the added element.
 190 sub add_file {
 191     my ($list, $file) = @_;
 192     $as_ref = [$file];
 193     push (@$list, $as_ref);
 194 }
 195
 196 # Sets the guest/host name for the previous put/get.
 197 sub set_as {
 198     my ($as) = @_;
 199     die "-a (or --as) is only allowed after -p or -g\n" if !defined $as_ref;
 200     die "Only one -a (or --as) is allowed after -p or -g\n"
 201       if defined $as_ref->[1];
 202     $as_ref->[1] = $as;
 203 }
 204 \f
 205 # Locates the files used to back each of the virtual disks,
 206 # and creates temporary disks.
 207 sub find_disks {
 208     for my $disk (values %disks) {
 209         # If there's no assigned file name but the default file exists,
 210         # try to assign a default file name.
 211         if (!defined ($disk->{FILE_NAME})) {
 212             for my $try_fn ($disk->{DEF_FN}, "build/" . $disk->{DEF_FN}) {
 213                 $disk->{FILE_NAME} = $try_fn, last
 214                   if -e $try_fn;
 215             }
 216         }
 217
 218         # If there's no file name, we're done.
 219         next if !defined ($disk->{FILE_NAME});
 220
 221         if ($disk->{FILE_NAME} =~ /^\d+(\.\d+)?|\.\d+$/) {
 222             # Create a temporary disk of approximately the specified
 223             # size in megabytes.
 224             die "OS disk can't be temporary\n" if $disk == $disks{OS};
 225
 226             my ($mb) = $disk->{FILE_NAME};
 227             undef $disk->{FILE_NAME};
 228
 229             my ($cyl_size) = 512 * 16 * 63;
 230             extend_disk ($disk, ceil ($mb * 2) * $cyl_size);
 231         } else {
 232             # The file must exist and have nonzero size.
 233             -e $disk->{FILE_NAME} or die "$disk->{FILE_NAME}: stat: $!\n";
 234             -s _ or die "$disk->{FILE_NAME}: disk has zero size\n";
 235         }
 236     }
 237
 238     # Warn about (potentially) missing disks.
 239     die "Cannot find OS disk\n" if !defined $disks{OS}{FILE_NAME};
 240     if (my ($project) = `pwd` =~ /\b(threads|userprog|vm|filesys)\b/) {
 241         if ((grep ($project eq $_, qw (userprog vm filesys)))
 242             && !defined ($disks{FS}{FILE_NAME})) {
 243             print STDERR "warning: it looks like you're running the $project ";
 244             print STDERR "project, but no file system disk is present\n";
 245         }
 246         if ($project eq 'vm' && !defined $disks{SWAP}{FILE_NAME}) {
 247             print STDERR "warning: it looks like you're running the $project ";
 248             print STDERR "project, but no swap disk is present\n";
 249         }
 250     }
 251 }
 252 \f
 253 # Prepare the scratch disk for gets and puts.
 254 sub prepare_scratch_disk {
 255     if (@puts) {
 256         # Write ustar header and data for each file.
 257         put_scratch_file ($_->[0],
 258                           defined $_->[1] ? $_->[1] : $_->[0])
 259           foreach @puts;
 260
 261         # Write end-of-archive marker.
 262         print { $disks{SCRATCH}{HANDLE} } "\0" x 1024;
 263     }
 264
 265     # Make sure the scratch disk is big enough to get big files.
 266     extend_disk ($disks{SCRATCH}, @gets * 1024 * 1024) if @gets;
 267 }
 268
 269 # Read "get" files from the scratch disk.
 270 sub finish_scratch_disk {
 271     # We need to start reading the scratch disk from the beginning again.
 272     if (@gets) {
 273         close ($disks{SCRATCH}{HANDLE});
 274         undef ($disks{SCRATCH}{HANDLE});
 275     }
 276
 277     # Read each file.
 278     # If reading fails, delete that file and all subsequent files.
 279     my ($ok) = 1;
 280     foreach my $get (@gets) {
 281         my ($name) = defined ($get->[1]) ? $get->[1] : $get->[0];
 282         my ($error) = get_scratch_file ($name);
 283         if ($error) {
 284             print STDERR "getting $name failed ($error)\n";
 285             die "$name: unlink: $!\n" if !unlink ($name) && !$!{ENOENT};
 286             $ok = 0;
 287         }
 288     }
 289 }
 290
 291 # mk_ustar_field($number, $size)
 292 #
 293 # Returns $number in a $size-byte numeric field in the format used by
 294 # the standard ustar archive header.
 295 sub mk_ustar_field {
 296     my ($number, $size) = @_;
 297     my ($len) = $size - 1;
 298     my ($out) = sprintf ("%0${len}o", $number) . "\0";
 299     die "$number: too large for $size-byte octal ustar field\n"
 300       if length ($out) != $size;
 301     return $out;
 302 }
 303
 304 # calc_ustar_chksum($s)
 305 #
 306 # Calculates and returns the ustar checksum of 512-byte ustar archive
 307 # header $s.
 308 sub calc_ustar_chksum {
 309     my ($s) = @_;
 310     die if length ($s) != 512;
 311     substr ($s, 148, 8, ' ' x 8);
 312     return unpack ("%32a*", $s);
 313 }
 314
 315 # put_scratch_file($src_file_name, $dst_file_name).
 316 #
 317 # Copies $src_file_name into the scratch disk for extraction as
 318 # $dst_file_name.
 319 sub put_scratch_file {
 320     my ($src_file_name, $dst_file_name) = @_;
 321     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 322
 323     print "Copying $src_file_name to scratch partition...\n";
 324
 325     # ustar format supports up to 100 characters for a file name, and
 326     # even longer names given some common properties, but our code in
 327     # the Pintos kernel only supports at most 99 characters.
 328     die "$dst_file_name: name too long (max 99 characters)\n"
 329       if length ($dst_file_name) > 99;
 330
 331     # Compose and write ustar header.
 332     stat $src_file_name or die "$src_file_name: stat: $!\n";
 333     my ($size) = -s _;
 334     my ($header) = (pack ("a100", $dst_file_name)       # name
 335                     . mk_ustar_field (0644, 8)          # mode
 336                     . mk_ustar_field (0, 8)             # uid
 337                     . mk_ustar_field (0, 8)             # gid
 338                     . mk_ustar_field ($size, 12)        # size
 339                     . mk_ustar_field (1136102400, 12)   # mtime
 340                     . (' ' x 8)                         # chksum
 341                     . '0'                               # typeflag
 342                     . ("\0" x 100)                      # linkname
 343                     . "ustar\0"                         # magic
 344                     . "00"                              # version
 345                     . "root" . ("\0" x 28)              # uname
 346                     . "root" . ("\0" x 28)              # gname
 347                     . "\0" x 8                          # devmajor
 348                     . "\0" x 8                          # devminor
 349                     . ("\0" x 155))                     # prefix
 350                     . "\0" x 12;                        # pad to 512 bytes
 351     substr ($header, 148, 8) = mk_ustar_field (calc_ustar_chksum ($header), 8);
 352     write_fully ($disk_handle, $disk_file_name, $header);
 353
 354     # Copy file data.
 355     my ($put_handle);
 356     sysopen ($put_handle, $src_file_name, O_RDONLY)
 357       or die "$src_file_name: open: $!\n";
 358     copy_file ($put_handle, $src_file_name, $disk_handle, $disk_file_name,
 359                $size);
 360     die "$src_file_name: changed size while being read\n"
 361       if $size != -s $put_handle;
 362     close ($put_handle);
 363
 364     # Round up disk data to beginning of next sector.
 365     write_fully ($disk_handle, $disk_file_name, "\0" x (512 - $size % 512))
 366       if $size % 512;
 367 }
 368
 369 # get_scratch_file($file).
 370 #
 371 # Copies from the scratch disk to $file.
 372 # Returns 1 if successful, 0 on failure.
 373 sub get_scratch_file {
 374     my ($get_file_name) = @_;
 375     my ($disk_handle, $disk_file_name) = open_disk ($disks{SCRATCH});
 376
 377     print "Copying $get_file_name out of $disk_file_name...\n";
 378
 379     # Read ustar header sector.
 380     my ($header) = read_fully ($disk_handle, $disk_file_name, 512);
 381     return "scratch disk tar archive ends unexpectedly"
 382       if $header eq ("\0" x 512);
 383
 384     # Verify magic numbers.
 385     return "corrupt ustar signature" if substr ($header, 257, 6) ne "ustar\0";
 386     return "invalid ustar version" if substr ($header, 263, 2) ne '00';
 387
 388     # Verify checksum.
 389     my ($chksum) = oct (unpack ("Z*", substr ($header, 148, 8)));
 390     my ($correct_chksum) = calc_ustar_chksum ($header);
 391     return "checksum mismatch" if $chksum != $correct_chksum;
 392
 393     # Get type.
 394     my ($typeflag) = substr ($header, 156, 1);
 395     return "not a regular file" if $typeflag ne '0' && $typeflag ne "\0";
 396
 397     # Get size.
 398     my ($size) = oct (unpack ("Z*", substr ($header, 124, 12)));
 399     return "bad size $size\n" if $size < 0;
 400
 401     # Copy file data.
 402     my ($get_handle);
 403     sysopen ($get_handle, $get_file_name, O_WRONLY | O_CREAT, 0666)
 404       or die "$get_file_name: create: $!\n";
 405     copy_file ($disk_handle, $disk_file_name, $get_handle, $get_file_name,
 406                $size);
 407     close ($get_handle);
 408
 409     # Skip forward in disk up to beginning of next sector.
 410     read_fully ($disk_handle, $disk_file_name, 512 - $size % 512)
 411       if $size % 512;
 412
 413     return 0;
 414 }
 415 \f
 416 # Prepares the arguments to pass to the Pintos kernel,
 417 # and then write them into Pintos bootloader.
 418 sub prepare_arguments {
 419     my (@args);
 420     push (@args, shift (@kernel_args))
 421       while @kernel_args && $kernel_args[0] =~ /^-/;
 422     push (@args, 'extract') if @puts;
 423     push (@args, @kernel_args);
 424     push (@args, 'append', $_->[0]) foreach @gets;
 425     write_cmd_line ($disks{OS}, @args);
 426 }
 427
 428 # Writes @args into the Pintos bootloader at the beginning of $disk.
 429 sub write_cmd_line {
 430     my ($disk, @args) = @_;
 431
 432     # Figure out command line to write.
 433     my ($arg_cnt) = pack ("V", scalar (@args));
 434     my ($args) = join ('', map ("$_\0", @args));
 435     die "command line exceeds 128 bytes" if length ($args) > 128;
 436     $args .= "\0" x (128 - length ($args));
 437
 438     # Write command line.
 439     my ($handle, $file_name) = open_disk_copy ($disk);
 440     print "Writing command line to $file_name...\n";
 441     sysseek ($handle, 0x17a, 0) == 0x17a or die "$file_name: seek: $!\n";
 442     syswrite ($handle, "$arg_cnt$args") or die "$file_name: write: $!\n";
 443 }
 444 \f
 445 # Running simulators.
 446
 447 # Runs the selected simulator.
 448 sub run_vm {
 449     if ($sim eq 'bochs') {
 450         run_bochs ();
 451     } elsif ($sim eq 'qemu') {
 452         run_qemu ();
 453     } elsif ($sim eq 'player') {
 454         run_player ();
 455     } else {
 456         die "unknown simulator `$sim'\n";
 457     }
 458 }
 459
 460 # Runs Bochs.
 461 sub run_bochs {
 462     # Select Bochs binary based on the chosen debugger.
 463     my ($bin) = $debug eq 'monitor' ? 'bochs-dbg' : 'bochs';
 464
 465     my ($squish_pty);
 466     if ($serial) {
 467         $squish_pty = find_in_path ("squish-pty");
 468         print "warning: can't find squish-pty, so terminal input will fail\n"
 469           if !defined $squish_pty;
 470     }
 471
 472     # Write bochsrc.txt configuration file.
 473     open (BOCHSRC, ">", "bochsrc.txt") or die "bochsrc.txt: create: $!\n";
 474     print BOCHSRC <<EOF;
 475 romimage: file=\$BXSHARE/BIOS-bochs-latest, address=0xf0000
 476 vgaromimage: file=\$BXSHARE/VGABIOS-lgpl-latest
 477 boot: disk
 478 cpu: ips=1000000
 479 megs: $mem
 480 log: bochsout.txt
 481 panic: action=fatal
 482 EOF
 483     print BOCHSRC "gdbstub: enabled=1\n" if $debug eq 'gdb';
 484     if ($realtime) {
 485         print BOCHSRC "clock: sync=realtime\n";
 486     } else {
 487         print BOCHSRC "clock: sync=none, time0=0\n";
 488     }
 489     print_bochs_disk_line ("ata0-master", 0);
 490     print_bochs_disk_line ("ata0-slave", 1);
 491     if (defined ($disks_by_iface[2]{FILE_NAME})
 492         || defined ($disks_by_iface[3]{FILE_NAME})) {
 493         print BOCHSRC "ata1: enabled=1, ioaddr1=0x170, ",
 494           "ioaddr2=0x370, irq=15\n";
 495         print_bochs_disk_line ("ata1-master", 2);
 496         print_bochs_disk_line ("ata1-slave", 3);
 497     }
 498     if ($vga ne 'terminal') {
 499         if ($serial) {
 500             my $mode = defined ($squish_pty) ? "term" : "file";
 501             print BOCHSRC "com1: enabled=1, mode=$mode, dev=/dev/stdout\n";
 502         }
 503         print BOCHSRC "display_library: nogui\n" if $vga eq 'none';
 504     } else {
 505         print BOCHSRC "display_library: term\n";
 506     }
 507     close (BOCHSRC);
 508
 509     # Compose Bochs command line.
 510     my (@cmd) = ($bin, '-q');
 511     unshift (@cmd, $squish_pty) if defined $squish_pty;
 512     push (@cmd, '-j', $jitter) if defined $jitter;
 513
 514     # Run Bochs.
 515     print join (' ', @cmd), "\n";
 516     my ($exit) = xsystem (@cmd);
 517     if (WIFEXITED ($exit)) {
 518         # Bochs exited normally.
 519         # Ignore the exit code; Bochs normally exits with status 1,
 520         # which is weird.
 521     } elsif (WIFSIGNALED ($exit)) {
 522         die "Bochs died with signal ", WTERMSIG ($exit), "\n";
 523     } else {
 524         die "Bochs died: code $exit\n";
 525     }
 526 }
 527
 528 # print_bochs_disk_line($device, $iface)
 529 #
 530 # If IDE interface $iface has a disk attached, prints a bochsrc.txt
 531 # line for attaching it to $device.
 532 sub print_bochs_disk_line {
 533     my ($device, $iface) = @_;
 534     my ($disk) = $disks_by_iface[$iface];
 535     my ($file) = $disk->{FILE_NAME};
 536     if (defined $file) {
 537         my (%geom) = disk_geometry ($disk);
 538         print BOCHSRC "$device: type=disk, path=$file, mode=flat, ";
 539         print BOCHSRC "cylinders=$geom{C}, heads=$geom{H}, spt=$geom{S}, ";
 540         print BOCHSRC "translation=none\n";
 541     }
 542 }
 543
 544 # Runs QEMU.
 545 sub run_qemu {
 546     print "warning: qemu doesn't support --terminal\n"
 547       if $vga eq 'terminal';
 548     print "warning: qemu doesn't support jitter\n"
 549       if defined $jitter;
 550     my (@cmd) = ('qemu');
 551     for my $iface (0...3) {
 552         my ($option) = ('-hda', '-hdb', '-hdc', '-hdd')[$iface];
 553         push (@cmd, $option, $disks_by_iface[$iface]{FILE_NAME})
 554           if defined $disks_by_iface[$iface]{FILE_NAME};
 555     }
 556     push (@cmd, '-m', $mem);
 557     push (@cmd, '-net', 'none');
 558     push (@cmd, '-nographic') if $vga eq 'none';
 559     push (@cmd, '-serial', 'stdio') if $serial && $vga ne 'none';
 560     push (@cmd, '-S') if $debug eq 'monitor';
 561     push (@cmd, '-s', '-S') if $debug eq 'gdb';
 562     push (@cmd, '-monitor', 'null') if $vga eq 'none' && $debug eq 'none';
 563     run_command (@cmd);
 564 }
 565
 566 # player_unsup($flag)
 567 #
 568 # Prints a message that $flag is unsupported by VMware Player.
 569 sub player_unsup {
 570     my ($flag) = @_;
 571     print "warning: no support for $flag with VMware Player\n";
 572 }
 573
 574 # Runs VMware Player.
 575 sub run_player {
 576     player_unsup ("--$debug") if $debug ne 'none';
 577     player_unsup ("--no-vga") if $vga eq 'none';
 578     player_unsup ("--terminal") if $vga eq 'terminal';
 579     player_unsup ("--jitter") if defined $jitter;
 580     player_unsup ("--timeout"), undef $timeout if defined $timeout;
 581     player_unsup ("--kill-on-failure"), undef $kill_on_failure
 582       if defined $kill_on_failure;
 583
 584     # Memory size must be multiple of 4.
 585     $mem = int (($mem + 3) / 4) * 4;
 586
 587     open (VMX, ">", "pintos.vmx") or die "pintos.vmx: create: $!\n";
 588     chmod 0777 & ~umask, "pintos.vmx";
 589     print VMX <<EOF;
 590 #! /usr/bin/vmware -G
 591 config.version = 8
 592 guestOS = "linux"
 593 memsize = $mem
 594 floppy0.present = FALSE
 595 usb.present = FALSE
 596 sound.present = FALSE
 597 gui.exitAtPowerOff = TRUE
 598 gui.exitOnCLIHLT = TRUE
 599 gui.powerOnAtStartUp = TRUE
 600 EOF
 601
 602
 603
 604     print VMX <<EOF if $serial;
 605 serial0.present = TRUE
 606 serial0.fileType = "pipe"
 607 serial0.fileName = "pintos.socket"
 608 serial0.pipe.endPoint = "client"
 609 serial0.tryNoRxLoss = "TRUE"
 610 EOF
 611
 612     for (my ($i) = 0; $i < 4; $i++) {
 613         my ($disk) = $disks_by_iface[$i];
 614         my ($dsk) = $disk->{FILE_NAME};
 615         next if !defined $dsk;
 616
 617         my ($device) = "ide" . int ($i / 2) . ":" . ($i % 2);
 618         my ($pln) = "$device.pln";
 619         print VMX <<EOF;
 620
 621 $device.present = TRUE
 622 $device.deviceType = "plainDisk"
 623 $device.fileName = "$pln"
 624 EOF
 625
 626         open (URANDOM, '<', '/dev/urandom') or die "/dev/urandom: open: $!\n";
 627         my ($bytes);
 628         sysread (URANDOM, $bytes, 4) == 4 or die "/dev/urandom: read: $!\n";
 629         close (URANDOM);
 630         my ($cid) = unpack ("L", $bytes);
 631
 632         my (%geom) = disk_geometry ($disk);
 633         open (PLN, ">", $pln) or die "$pln: create: $!\n";
 634         print PLN <<EOF;
 635 version=1
 636 CID=$cid
 637 parentCID=ffffffff
 638 createType="monolithicFlat"
 639
 640 RW $geom{CAPACITY} FLAT "$dsk" 0
 641
 642 # The Disk Data Base
 643 #DDB
 644
 645 ddb.adapterType = "ide"
 646 ddb.virtualHWVersion = "4"
 647 ddb.toolsVersion = "2"
 648 ddb.geometry.cylinders = "$geom{C}"
 649 ddb.geometry.heads = "$geom{H}"
 650 ddb.geometry.sectors = "$geom{S}"
 651 EOF
 652         close (PLN);
 653     }
 654     close (VMX);
 655
 656     my ($squish_unix);
 657     if ($serial) {
 658         $squish_unix = find_in_path ("squish-unix");
 659         print "warning: can't find squish-unix, so terminal input ",
 660           "and output will fail\n" if !defined $squish_unix;
 661     }
 662
 663     my ($vmx) = getcwd () . "/pintos.vmx";
 664     my (@cmd) = ("vmplayer", $vmx);
 665     unshift (@cmd, $squish_unix, "pintos.socket") if $squish_unix;
 666     print join (' ', @cmd), "\n";
 667     xsystem (@cmd);
 668 }
 669 \f
 670 # Disk utilities.
 671
 672 # open_disk($disk)
 673 #
 674 # Opens $disk, if it is not already open, and returns its file handle
 675 # and file name.
 676 sub open_disk {
 677     my ($disk) = @_;
 678     if (!defined ($disk->{HANDLE})) {
 679         if ($disk->{FILE_NAME}) {
 680             sysopen ($disk->{HANDLE}, $disk->{FILE_NAME}, O_RDWR)
 681               or die "$disk->{FILE_NAME}: open: $!\n";
 682         } else {
 683             ($disk->{HANDLE}, $disk->{FILE_NAME}) = tempfile (UNLINK => 1,
 684                                                              SUFFIX => '.dsk');
 685         }
 686     }
 687     return ($disk->{HANDLE}, $disk->{FILE_NAME});
 688 }
 689
 690 # open_disk_copy($disk)
 691 #
 692 # Makes a temporary copy of $disk and returns its file handle and file name.
 693 sub open_disk_copy {
 694     my ($disk) = @_;
 695     die if !$disk->{FILE_NAME};
 696
 697     my ($orig_handle, $orig_file_name) = open_disk ($disk);
 698     my ($cp_handle, $cp_file_name) = tempfile (UNLINK => 1, SUFFIX => '.dsk');
 699     copy_file ($orig_handle, $orig_file_name, $cp_handle, $cp_file_name,
 700                -s $orig_handle);
 701     return ($disk->{HANDLE}, $disk->{FILE_NAME}) = ($cp_handle, $cp_file_name);
 702 }
 703
 704 # extend_disk($disk, $size)
 705 #
 706 # Extends $disk, if necessary, so that it is at least $size bytes
 707 # long.
 708 sub extend_disk {
 709     my ($disk, $size) = @_;
 710     my ($handle, $file_name) = open_disk ($disk);
 711     if (-s ($handle) < $size) {
 712         sysseek ($handle, $size - 1, 0) == $size - 1
 713           or die "$file_name: seek: $!\n";
 714         syswrite ($handle, "\0") == 1
 715           or die "$file_name: write: $!\n";
 716     }
 717 }
 718
 719 # disk_geometry($file)
 720 #
 721 # Examines $file and returns a valid IDE disk geometry for it, as a
 722 # hash.
 723 sub disk_geometry {
 724     my ($disk) = @_;
 725     my ($file) = $disk->{FILE_NAME};
 726     my ($size) = -s $file;
 727     die "$file: stat: $!\n" if !defined $size;
 728     die "$file: size not a multiple of 512 bytes\n" if $size % 512;
 729     my ($cyl_size) = 512 * 16 * 63;
 730     my ($cylinders) = ceil ($size / $cyl_size);
 731     extend_disk ($disk, $cylinders * $cyl_size) if $size % $cyl_size;
 732
 733     return (CAPACITY => $size / 512,
 734             C => $cylinders,
 735             H => 16,
 736             S => 63);
 737 }
 738
 739 # copy_file($from_handle, $from_file_name, $to_handle, $to_file_name, $size)
 740 #
 741 # Copies $size bytes from $from_handle to $to_handle.
 742 # $from_file_name and $to_file_name are used in error messages.
 743 sub copy_file {
 744     my ($from_handle, $from_file_name, $to_handle, $to_file_name, $size) = @_;
 745
 746     while ($size > 0) {
 747         my ($chunk_size) = 4096;
 748         $chunk_size = $size if $chunk_size > $size;
 749         $size -= $chunk_size;
 750
 751         my ($data) = read_fully ($from_handle, $from_file_name, $chunk_size);
 752         write_fully ($to_handle, $to_file_name, $data);
 753     }
 754 }
 755
 756 # read_fully($handle, $file_name, $bytes)
 757 #
 758 # Reads exactly $bytes bytes from $handle and returns the data read.
 759 # $file_name is used in error messages.
 760 sub read_fully {
 761     my ($handle, $file_name, $bytes) = @_;
 762     my ($data);
 763     my ($read_bytes) = sysread ($handle, $data, $bytes);
 764     die "$file_name: read: $!\n" if !defined $read_bytes;
 765     die "$file_name: unexpected end of file\n" if $read_bytes != $bytes;
 766     return $data;
 767 }
 768
 769 # write_fully($handle, $file_name, $data)
 770 #
 771 # Write $data to $handle.
 772 # $file_name is used in error messages.
 773 sub write_fully {
 774     my ($handle, $file_name, $data) = @_;
 775     my ($written_bytes) = syswrite ($handle, $data);
 776     die "$file_name: write: $!\n" if !defined $written_bytes;
 777     die "$file_name: short write\n" if $written_bytes != length $data;
 778 }
 779 \f
 780 # Subprocess utilities.
 781
 782 # run_command(@args)
 783 #
 784 # Runs xsystem(@args).
 785 # Also prints the command it's running and checks that it succeeded.
 786 sub run_command {
 787     print join (' ', @_), "\n";
 788     die "command failed\n" if xsystem (@_);
 789 }
 790
 791 # xsystem(@args)
 792 #
 793 # Creates a subprocess via exec(@args) and waits for it to complete.
 794 # Relays common signals to the subprocess.
 795 # If $timeout is set then the subprocess will be killed after that long.
 796 sub xsystem {
 797     # QEMU turns off local echo and does not restore it if killed by a signal.
 798     # We compensate by restoring it ourselves.
 799     my $cleanup = sub {};
 800     if (isatty (0)) {
 801         my $termios = POSIX::Termios->new;
 802         $termios->getattr (0);
 803         $cleanup = sub { $termios->setattr (0, &POSIX::TCSANOW); }
 804     }
 805
 806     # Create pipe for filtering output.
 807     pipe (my $in, my $out) or die "pipe: $!\n" if $kill_on_failure;
 808
 809     my ($pid) = fork;
 810     if (!defined ($pid)) {
 811         # Fork failed.
 812         die "fork: $!\n";
 813     } elsif (!$pid) {
 814         # Running in child process.
 815         dup2 (fileno ($out), STDOUT_FILENO) or die "dup2: $!\n"
 816           if $kill_on_failure;
 817         exec_setitimer (@_);
 818     } else {
 819         # Running in parent process.
 820         close $out if $kill_on_failure;
 821
 822         my ($cause);
 823         local $SIG{ALRM} = sub { timeout ($pid, $cause, $cleanup); };
 824         local $SIG{INT} = sub { relay_signal ($pid, "INT", $cleanup); };
 825         local $SIG{TERM} = sub { relay_signal ($pid, "TERM", $cleanup); };
 826         alarm ($timeout * get_load_average () + 1) if defined ($timeout);
 827
 828         if ($kill_on_failure) {
 829             # Filter output.
 830             my ($buf) = "";
 831             my ($boots) = 0;
 832             local ($|) = 1;
 833             for (;;) {
 834                 if (waitpid ($pid, WNOHANG) != 0) {
 835                     # Subprocess died.  Pass through any remaining data.
 836                     print $buf while sysread ($in, $buf, 4096) > 0;
 837                     last;
 838                 }
 839
 840                 # Read and print out pipe data.
 841                 my ($len) = length ($buf);
 842                 waitpid ($pid, 0), last
 843                   if sysread ($in, $buf, 4096, $len) <= 0;
 844                 print substr ($buf, $len);
 845
 846                 # Remove full lines from $buf and scan them for keywords.
 847                 while ((my $idx = index ($buf, "\n")) >= 0) {
 848                     local $_ = substr ($buf, 0, $idx + 1, '');
 849                     next if defined ($cause);
 850                     if (/(Kernel PANIC|User process ABORT)/ ) {
 851                         $cause = "\L$1\E";
 852                         alarm (5);
 853                     } elsif (/Pintos booting/ && ++$boots > 1) {
 854                         $cause = "triple fault";
 855                         alarm (5);
 856                     } elsif (/FAILED/) {
 857                         $cause = "test failure";
 858                         alarm (5);
 859                     }
 860                 }
 861             }
 862         } else {
 863             waitpid ($pid, 0);
 864         }
 865         alarm (0);
 866         &$cleanup ();
 867
 868         if (WIFSIGNALED ($?) && WTERMSIG ($?) == SIGVTALRM ()) {
 869             seek (STDOUT, 0, 2);
 870             print "\nTIMEOUT after $timeout seconds of host CPU time\n";
 871             exit 0;
 872         }
 873
 874         return $?;
 875     }
 876 }
 877
 878 # relay_signal($pid, $signal, &$cleanup)
 879 #
 880 # Relays $signal to $pid and then reinvokes it for us with the default
 881 # handler.  Also cleans up temporary files and invokes $cleanup.
 882 sub relay_signal {
 883     my ($pid, $signal, $cleanup) = @_;
 884     kill $signal, $pid;
 885     eval { File::Temp::cleanup() };     # Not defined in old File::Temp.
 886     &$cleanup ();
 887     $SIG{$signal} = 'DEFAULT';
 888     kill $signal, getpid ();
 889 }
 890
 891 # timeout($pid, $cause, &$cleanup)
 892 #
 893 # Interrupts $pid and dies with a timeout error message,
 894 # after invoking $cleanup.
 895 sub timeout {
 896     my ($pid, $cause, $cleanup) = @_;
 897     kill "INT", $pid;
 898     waitpid ($pid, 0);
 899     &$cleanup ();
 900     seek (STDOUT, 0, 2);
 901     if (!defined ($cause)) {
 902         my ($load_avg) = `uptime` =~ /(load average:.*)$/i;
 903         print "\nTIMEOUT after ", time () - $start_time,
 904           " seconds of wall-clock time";
 905         print  " - $load_avg" if defined $load_avg;
 906         print "\n";
 907     } else {
 908         print "Simulation terminated due to $cause.\n";
 909     }
 910     exit 0;
 911 }
 912
 913 # Returns the system load average over the last minute.
 914 # If the load average is less than 1.0 or cannot be determined, returns 1.0.
 915 sub get_load_average {
 916     my ($avg) = `uptime` =~ /load average:\s*([^,]+),/;
 917     return $avg >= 1.0 ? $avg : 1.0;
 918 }
 919
 920 # Calls setitimer to set a timeout, then execs what was passed to us.
 921 sub exec_setitimer {
 922     if (defined $timeout) {
 923         if ($\16 ge 5.8.0) {
 924             eval "
 925               use Time::HiRes qw(setitimer ITIMER_VIRTUAL);
 926               setitimer (ITIMER_VIRTUAL, $timeout, 0);
 927             ";
 928         } else {
 929             { exec ("setitimer-helper", $timeout, @_); };
 930             exit 1 if !$!{ENOENT};
 931             print STDERR "warning: setitimer-helper is not installed, so ",
 932               "CPU time limit will not be enforced\n";
 933         }
 934     }
 935     exec (@_);
 936     exit (1);
 937 }
 938
 939 sub SIGVTALRM {
 940     use Config;
 941     my $i = 0;
 942     foreach my $name (split(' ', $Config{sig_name})) {
 943         return $i if $name eq 'VTALRM';
 944         $i++;
 945     }
 946     return 0;
 947 }
 948
 949 # find_in_path ($program)
 950 #
 951 # Searches for $program in $ENV{PATH}.
 952 # Returns $program if found, otherwise undef.
 953 sub find_in_path {
 954     my ($program) = @_;
 955     -x "$_/$program" and return $program foreach split (':', $ENV{PATH});
 956     return;
 957 }