pintos-os.org Git - pintos-anon/blob - src/threads/switch.S

   1 #include "threads/switch.h"
   2
   3 #### struct thread *switch_threads (struct thread *cur, struct thread *next);
   4 ####
   5 #### Switches from CUR, which must be the running thread, to NEXT,
   6 #### which must also be running switch_threads(), returning CUR in
   7 #### NEXT's context.
   8 ####
   9 #### This function works by assuming that the thread we're switching
  10 #### into is also running switch_threads().  Thus, all it has to do is
  11 #### preserve a few registers on the stack, then switch stacks and
  12 #### restore the registers.  As part of switching stacks we record the
  13 #### current stack pointer in CUR's thread structure.
  14
  15 .globl switch_threads
  16 .func switch_threads
  17 switch_threads:
  18         # Save caller's register state.
  19         #
  20         # Note that the SVR4 ABI allows us to destroy %eax, %ecx, %edx,
  21         # but requires us to preserve %ebx, %ebp, %esi, %edi.  See
  22         # [SysV-ABI-386] pages 3-11 and 3-12 for details.
  23         #
  24         # This stack frame must match the one set up by thread_create().
  25         pushl %ebx
  26         pushl %ebp
  27         pushl %esi
  28         pushl %edi
  29
  30         # Get offsetof (struct thread, stack).
  31 .globl thread_stack_ofs
  32         mov thread_stack_ofs, %edx
  33
  34         # Save current stack pointer to old thread's stack, if any.
  35         movl SWITCH_CUR(%esp), %eax
  36         movl %esp, (%eax,%edx,1)
  37
  38         # Restore stack pointer from new thread's stack.
  39         movl SWITCH_NEXT(%esp), %ecx
  40         movl (%ecx,%edx,1), %esp
  41
  42         # Restore caller's register state.
  43         popl %edi
  44         popl %esi
  45         popl %ebp
  46         popl %ebx
  47         ret
  48 .endfunc
  49
  50 .globl switch_entry
  51 .func switch_entry
  52 switch_entry:
  53         # Discard switch_threads() arguments.
  54         addl $8, %esp
  55
  56         # Call schedule_tail(prev).
  57         pushl %eax
  58 .globl schedule_tail
  59         call schedule_tail
  60         addl $4, %esp
  61
  62         # Start thread proper.
  63         ret
  64 .endfunc